git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/websocket_handler.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.WebsocketHandler do
   6   require Logger
   7
   8   alias Pleroma.Repo
   9   alias Pleroma.User
  10   alias Pleroma.Web.OAuth.Token
  11   alias Pleroma.Web.Streamer
  12
  13   @behaviour :cowboy_websocket
  14
  15   # Client ping period.
  16   @tick :timer.seconds(30)
  17   # Cowboy timeout period.
  18   @timeout :timer.seconds(60)
  19   # Hibernate every X messages
  20   @hibernate_every 100
  21
  22   @streams [
  23     "public",
  24     "public:local",
  25     "public:media",
  26     "public:local:media",
  27     "user",
  28     "user:notification",
  29     "direct",
  30     "list",
  31     "hashtag"
  32   ]
  33   @anonymous_streams ["public", "public:local", "hashtag"]
  34
  35   def init(%{qs: qs} = req, state) do
  36     with params <- :cow_qs.parse_qs(qs),
  37          sec_websocket <- :cowboy_req.header("sec-websocket-protocol", req, nil),
  38          access_token <- List.keyfind(params, "access_token", 0),
  39          {_, stream} <- List.keyfind(params, "stream", 0),
  40          {:ok, user} <- allow_request(stream, [access_token, sec_websocket]),
  41          topic when is_binary(topic) <- expand_topic(stream, params) do
  42       req =
  43         if sec_websocket do
  44           :cowboy_req.set_resp_header("sec-websocket-protocol", sec_websocket, req)
  45         else
  46           req
  47         end
  48
  49       {:cowboy_websocket, req, %{user: user, topic: topic, count: 0, timer: nil},
  50        %{idle_timeout: @timeout}}
  51     else
  52       {:error, code} ->
  53         Logger.debug("#{__MODULE__} denied connection: #{inspect(code)} - #{inspect(req)}")
  54         {:ok, req} = :cowboy_req.reply(code, req)
  55         {:ok, req, state}
  56
  57       error ->
  58         Logger.debug("#{__MODULE__} denied connection: #{inspect(error)} - #{inspect(req)}")
  59         {:ok, req} = :cowboy_req.reply(400, req)
  60         {:ok, req, state}
  61     end
  62   end
  63
  64   def websocket_init(state) do
  65     Logger.debug(
  66       "#{__MODULE__} accepted websocket connection for user #{
  67         (state.user || %{id: "anonymous"}).id
  68       }, topic #{state.topic}"
  69     )
  70
  71     Streamer.add_socket(state.topic, state.user)
  72     {:ok, %{state | timer: timer()}}
  73   end
  74
  75   # Client's Pong frame.
  76   def websocket_handle(:pong, state) do
  77     if state.timer, do: Process.cancel_timer(state.timer)
  78     {:ok, %{state | timer: timer()}}
  79   end
  80
  81   # We never receive messages.
  82   def websocket_handle(frame, state) do
  83     Logger.error("#{__MODULE__} received frame: #{inspect(frame)}")
  84     {:ok, state}
  85   end
  86
  87   def websocket_info({:render_with_user, view, template, item}, state) do
  88     user = %User{} = User.get_cached_by_ap_id(state.user.ap_id)
  89
  90     unless Streamer.filtered_by_user?(user, item) do
  91       websocket_info({:text, view.render(template, item, user)}, %{state | user: user})
  92     else
  93       {:ok, state}
  94     end
  95   end
  96
  97   def websocket_info({:text, message}, state) do
  98     # If the websocket processed X messages, force an hibernate/GC.
  99     # We don't hibernate at every message to balance CPU usage/latency with RAM usage.
 100     if state.count > @hibernate_every do
 101       {:reply, {:text, message}, %{state | count: 0}, :hibernate}
 102     else
 103       {:reply, {:text, message}, %{state | count: state.count + 1}}
 104     end
 105   end
 106
 107   # Ping tick. We don't re-queue a timer there, it is instead queued when :pong is received.
 108   # As we hibernate there, reset the count to 0.
 109   # If the client misses :pong, Cowboy will automatically timeout the connection after
 110   # `@idle_timeout`.
 111   def websocket_info(:tick, state) do
 112     {:reply, :ping, %{state | timer: nil, count: 0}, :hibernate}
 113   end
 114
 115   def terminate(reason, _req, state) do
 116     Logger.debug(
 117       "#{__MODULE__} terminating websocket connection for user #{
 118         (state.user || %{id: "anonymous"}).id
 119       }, topic #{state.topic || "?"}: #{inspect(reason)}"
 120     )
 121
 122     Streamer.remove_socket(state.topic)
 123     :ok
 124   end
 125
 126   # Public streams without authentication.
 127   defp allow_request(stream, [nil, nil]) when stream in @anonymous_streams do
 128     {:ok, nil}
 129   end
 130
 131   # Authenticated streams.
 132   defp allow_request(stream, [access_token, sec_websocket]) when stream in @streams do
 133     token =
 134       with {"access_token", token} <- access_token do
 135         token
 136       else
 137         _ -> sec_websocket
 138       end
 139
 140     with true <- is_bitstring(token),
 141          %Token{user_id: user_id} <- Repo.get_by(Token, token: token),
 142          user = %User{} <- User.get_cached_by_id(user_id) do
 143       {:ok, user}
 144     else
 145       _ -> {:error, 403}
 146     end
 147   end
 148
 149   # Not authenticated.
 150   defp allow_request(stream, _) when stream in @streams, do: {:error, 403}
 151
 152   # No matching stream.
 153   defp allow_request(_, _), do: {:error, 404}
 154
 155   defp expand_topic("hashtag", params) do
 156     case List.keyfind(params, "tag", 0) do
 157       {_, tag} -> "hashtag:#{tag}"
 158       _ -> nil
 159     end
 160   end
 161
 162   defp expand_topic("list", params) do
 163     case List.keyfind(params, "list", 0) do
 164       {_, list} -> "list:#{list}"
 165       _ -> nil
 166     end
 167   end
 168
 169   defp expand_topic(topic, _), do: topic
 170
 171   defp timer do
 172     Process.send_after(self(), :tick, @tick)
 173   end
 174 end