git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/websocket_handler.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.WebsocketHandler do
   6   require Logger
   7
   8   alias Pleroma.Repo
   9   alias Pleroma.User
  10   alias Pleroma.Web.OAuth.Token
  11   alias Pleroma.Web.Streamer
  12
  13   @behaviour :cowboy_websocket
  14
  15   @streams [
  16     "public",
  17     "public:local",
  18     "public:media",
  19     "public:local:media",
  20     "user",
  21     "user:notification",
  22     "direct",
  23     "list",
  24     "hashtag"
  25   ]
  26   @anonymous_streams ["public", "public:local", "hashtag"]
  27
  28   # Handled by periodic keepalive in Pleroma.Web.Streamer.Ping.
  29   @timeout :infinity
  30
  31   def init(%{qs: qs} = req, state) do
  32     with params <- :cow_qs.parse_qs(qs),
  33          sec_websocket <- :cowboy_req.header("sec-websocket-protocol", req, nil),
  34          access_token <- List.keyfind(params, "access_token", 0),
  35          {_, stream} <- List.keyfind(params, "stream", 0),
  36          {:ok, user} <- allow_request(stream, [access_token, sec_websocket]),
  37          topic when is_binary(topic) <- expand_topic(stream, params) do
  38       req =
  39         if sec_websocket do
  40           :cowboy_req.set_resp_header("sec-websocket-protocol", sec_websocket, req)
  41         else
  42           req
  43         end
  44
  45       {:cowboy_websocket, req, %{user: user, topic: topic}, %{idle_timeout: @timeout}}
  46     else
  47       {:error, code} ->
  48         Logger.debug("#{__MODULE__} denied connection: #{inspect(code)} - #{inspect(req)}")
  49         {:ok, req} = :cowboy_req.reply(code, req)
  50         {:ok, req, state}
  51
  52       error ->
  53         Logger.debug("#{__MODULE__} denied connection: #{inspect(error)} - #{inspect(req)}")
  54         {:ok, req} = :cowboy_req.reply(400, req)
  55         {:ok, req, state}
  56     end
  57   end
  58
  59   def websocket_init(state) do
  60     send(self(), :subscribe)
  61     {:ok, state}
  62   end
  63
  64   # We never receive messages.
  65   def websocket_handle(_frame, state) do
  66     {:ok, state}
  67   end
  68
  69   def websocket_info(:subscribe, state) do
  70     Logger.debug(
  71       "#{__MODULE__} accepted websocket connection for user #{
  72         (state.user || %{id: "anonymous"}).id
  73       }, topic #{state.topic}"
  74     )
  75
  76     Streamer.add_socket(state.topic, streamer_socket(state))
  77     {:ok, state}
  78   end
  79
  80   def websocket_info({:text, message}, state) do
  81     {:reply, {:text, message}, state}
  82   end
  83
  84   def terminate(reason, _req, state) do
  85     Logger.debug(
  86       "#{__MODULE__} terminating websocket connection for user #{
  87         (state.user || %{id: "anonymous"}).id
  88       }, topic #{state.topic || "?"}: #{inspect(reason)}"
  89     )
  90
  91     Streamer.remove_socket(state.topic, streamer_socket(state))
  92     :ok
  93   end
  94
  95   # Public streams without authentication.
  96   defp allow_request(stream, [nil, nil]) when stream in @anonymous_streams do
  97     {:ok, nil}
  98   end
  99
 100   # Authenticated streams.
 101   defp allow_request(stream, [access_token, sec_websocket]) when stream in @streams do
 102     token =
 103       with {"access_token", token} <- access_token do
 104         token
 105       else
 106         _ -> sec_websocket
 107       end
 108
 109     with true <- is_bitstring(token),
 110          %Token{user_id: user_id} <- Repo.get_by(Token, token: token),
 111          user = %User{} <- User.get_cached_by_id(user_id) do
 112       {:ok, user}
 113     else
 114       _ -> {:error, 403}
 115     end
 116   end
 117
 118   # Not authenticated.
 119   defp allow_request(stream, _) when stream in @streams, do: {:error, 403}
 120
 121   # No matching stream.
 122   defp allow_request(_, _), do: {:error, 404}
 123
 124   defp expand_topic("hashtag", params) do
 125     case List.keyfind(params, "tag", 0) do
 126       {_, tag} -> "hashtag:#{tag}"
 127       _ -> nil
 128     end
 129   end
 130
 131   defp expand_topic("list", params) do
 132     case List.keyfind(params, "list", 0) do
 133       {_, list} -> "list:#{list}"
 134       _ -> nil
 135     end
 136   end
 137
 138   defp expand_topic(topic, _), do: topic
 139
 140   defp streamer_socket(state) do
 141     %{transport_pid: self(), assigns: state}
 142   end
 143 end