git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/status_view.ex

   1 defmodule Pleroma.Web.MastodonAPI.StatusView do
   2   use Pleroma.Web, :view
   3   alias Pleroma.Web.MastodonAPI.{AccountView, StatusView}
   4   alias Pleroma.{User, Activity}
   5   alias Pleroma.Web.CommonAPI.Utils
   6   alias Pleroma.Web.MediaProxy
   7   alias Pleroma.Repo
   8
   9   # TODO: Add cached version.
  10   defp get_replied_to_activities(activities) do
  11     activities
  12     |> Enum.map(fn
  13       %{data: %{"type" => "Create", "object" => %{"inReplyTo" => inReplyTo}}} ->
  14         inReplyTo != "" && inReplyTo
  15
  16       _ ->
  17         nil
  18     end)
  19     |> Enum.filter(& &1)
  20     |> Activity.create_activity_by_object_id_query()
  21     |> Repo.all()
  22     |> Enum.reduce(%{}, fn activity, acc ->
  23       Map.put(acc, activity.data["object"]["id"], activity)
  24     end)
  25   end
  26
  27   def render("index.json", opts) do
  28     replied_to_activities = get_replied_to_activities(opts.activities)
  29
  30     render_many(
  31       opts.activities,
  32       StatusView,
  33       "status.json",
  34       Map.put(opts, :replied_to_activities, replied_to_activities)
  35     )
  36   end
  37
  38   def render(
  39         "status.json",
  40         %{activity: %{data: %{"type" => "Announce", "object" => object}} = activity} = opts
  41       ) do
  42     user = User.get_cached_by_ap_id(activity.data["actor"])
  43     created_at = Utils.to_masto_date(activity.data["published"])
  44
  45     reblogged = Activity.get_create_activity_by_object_ap_id(object)
  46     reblogged = render("status.json", Map.put(opts, :activity, reblogged))
  47
  48     mentions =
  49       activity.recipients
  50       |> Enum.map(fn ap_id -> User.get_cached_by_ap_id(ap_id) end)
  51       |> Enum.filter(& &1)
  52       |> Enum.map(fn user -> AccountView.render("mention.json", %{user: user}) end)
  53
  54     %{
  55       id: to_string(activity.id),
  56       uri: object,
  57       url: object,
  58       account: AccountView.render("account.json", %{user: user}),
  59       in_reply_to_id: nil,
  60       in_reply_to_account_id: nil,
  61       reblog: reblogged,
  62       content: reblogged[:content],
  63       created_at: created_at,
  64       reblogs_count: 0,
  65       favourites_count: 0,
  66       reblogged: false,
  67       favourited: false,
  68       muted: false,
  69       sensitive: false,
  70       spoiler_text: "",
  71       visibility: "public",
  72       media_attachments: [],
  73       mentions: mentions,
  74       tags: [],
  75       application: %{
  76         name: "Web",
  77         website: nil
  78       },
  79       language: nil,
  80       emojis: []
  81     }
  82   end
  83
  84   def render("status.json", %{activity: %{data: %{"object" => object}} = activity} = opts) do
  85     user = User.get_cached_by_ap_id(activity.data["actor"])
  86
  87     like_count = object["like_count"] || 0
  88     announcement_count = object["announcement_count"] || 0
  89
  90     tags = object["tag"] || []
  91     sensitive = object["sensitive"] || Enum.member?(tags, "nsfw")
  92
  93     mentions =
  94       activity.recipients
  95       |> Enum.map(fn ap_id -> User.get_cached_by_ap_id(ap_id) end)
  96       |> Enum.filter(& &1)
  97       |> Enum.map(fn user -> AccountView.render("mention.json", %{user: user}) end)
  98
  99     repeated = opts[:for] && opts[:for].ap_id in (object["announcements"] || [])
 100     favorited = opts[:for] && opts[:for].ap_id in (object["likes"] || [])
 101
 102     attachments =
 103       render_many(object["attachment"] || [], StatusView, "attachment.json", as: :attachment)
 104
 105     created_at = Utils.to_masto_date(object["published"])
 106
 107     reply_to = get_reply_to(activity, opts)
 108     reply_to_user = reply_to && User.get_cached_by_ap_id(reply_to.data["actor"])
 109
 110     emojis =
 111       (activity.data["object"]["emoji"] || [])
 112       |> Enum.map(fn {name, url} ->
 113         name = HtmlSanitizeEx.strip_tags(name)
 114
 115         url =
 116           HtmlSanitizeEx.strip_tags(url)
 117           |> MediaProxy.url()
 118
 119         %{shortcode: name, url: url, static_url: url}
 120       end)
 121
 122     %{
 123       id: to_string(activity.id),
 124       uri: object["id"],
 125       url: object["external_url"] || object["id"],
 126       account: AccountView.render("account.json", %{user: user}),
 127       in_reply_to_id: reply_to && to_string(reply_to.id),
 128       in_reply_to_account_id: reply_to_user && to_string(reply_to_user.id),
 129       reblog: nil,
 130       content: render_content(object),
 131       created_at: created_at,
 132       reblogs_count: announcement_count,
 133       favourites_count: like_count,
 134       reblogged: !!repeated,
 135       favourited: !!favorited,
 136       muted: false,
 137       sensitive: sensitive,
 138       spoiler_text: object["summary"] || "",
 139       visibility: get_visibility(object),
 140       media_attachments: attachments |> Enum.take(4),
 141       mentions: mentions,
 142       # fix,
 143       tags: [],
 144       application: %{
 145         name: "Web",
 146         website: nil
 147       },
 148       language: nil,
 149       emojis: emojis
 150     }
 151   end
 152
 153   def render("attachment.json", %{attachment: attachment}) do
 154     [%{"mediaType" => media_type, "href" => href} | _] = attachment["url"]
 155
 156     type =
 157       cond do
 158         String.contains?(media_type, "image") -> "image"
 159         String.contains?(media_type, "video") -> "video"
 160         String.contains?(media_type, "audio") -> "audio"
 161         true -> "unknown"
 162       end
 163
 164     <<hash_id::signed-32, _rest::binary>> = :crypto.hash(:md5, href)
 165
 166     %{
 167       id: to_string(attachment["id"] || hash_id),
 168       url: MediaProxy.url(href),
 169       remote_url: href,
 170       preview_url: MediaProxy.url(href),
 171       text_url: href,
 172       type: type,
 173       description: attachment["name"]
 174     }
 175   end
 176
 177   def get_reply_to(activity, %{replied_to_activities: replied_to_activities}) do
 178     _id = activity.data["object"]["inReplyTo"]
 179     replied_to_activities[activity.data["object"]["inReplyTo"]]
 180   end
 181
 182   def get_reply_to(%{data: %{"object" => object}}, _) do
 183     if object["inReplyTo"] && object["inReplyTo"] != "" do
 184       Activity.get_create_activity_by_object_ap_id(object["inReplyTo"])
 185     else
 186       nil
 187     end
 188   end
 189
 190   def get_visibility(object) do
 191     public = "https://www.w3.org/ns/activitystreams#Public"
 192     to = object["to"] || []
 193     cc = object["cc"] || []
 194
 195     cond do
 196       public in to ->
 197         "public"
 198
 199       public in cc ->
 200         "unlisted"
 201
 202       # this should use the sql for the object's activity
 203       Enum.any?(to, &String.contains?(&1, "/followers")) ->
 204         "private"
 205
 206       true ->
 207         "direct"
 208     end
 209   end
 210
 211   def render_content(%{"type" => "Article"} = object) do
 212     summary = object["name"]
 213
 214     content =
 215       if !!summary and summary != "" do
 216         "<p><a href=\"#{object["url"]}\">#{summary}</a></p>#{object["content"]}"
 217       else
 218         object["content"]
 219       end
 220
 221     HtmlSanitizeEx.basic_html(content)
 222   end
 223
 224   def render_content(object) do
 225     HtmlSanitizeEx.basic_html(object["content"])
 226   end
 227 end