git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/status_view.ex

   1 defmodule Pleroma.Web.MastodonAPI.StatusView do
   2   use Pleroma.Web, :view
   3   alias Pleroma.Web.MastodonAPI.{AccountView, StatusView}
   4   alias Pleroma.User
   5
   6   def render("index.json", opts) do
   7     render_many(opts.activities, StatusView, "status.json", opts)
   8   end
   9
  10   def render("status.json", %{activity: %{data: %{"object" => object}} = activity} = opts) do
  11     user = User.get_cached_by_ap_id(activity.data["actor"])
  12
  13     like_count = object["like_count"] || 0
  14     announcement_count = object["announcement_count"] || 0
  15
  16     tags = object["tag"] || []
  17     sensitive = Enum.member?(tags, "nsfw")
  18
  19     mentions = activity.data["to"]
  20     |> Enum.map(fn (ap_id) -> User.get_cached_by_ap_id(ap_id) end)
  21     |> Enum.filter(&(&1))
  22     |> Enum.map(fn (user) -> AccountView.render("mention.json", %{user: user}) end)
  23
  24     repeated = opts[:for] && opts[:for].ap_id in (object["announcements"] || [])
  25     favorited = opts[:for] && opts[:for].ap_id in (object["likes"] || [])
  26
  27     attachments = render_many(object["attachment"] || [], StatusView, "attachment.json", as: :attachment)
  28
  29     created_at = (object["published"] || "")
  30     |> NaiveDateTime.from_iso8601!
  31     |> NaiveDateTime.to_iso8601
  32     |> String.replace(~r/(\.\d+)?$/, ".000Z", global: false)
  33
  34     %{
  35       id: activity.id,
  36       uri: object["id"],
  37       url: object["external_url"],
  38       account: AccountView.render("account.json", %{user: user}),
  39       in_reply_to_id: object["inReplyToStatusId"],
  40       in_reply_to_account_id: nil,
  41       reblog: nil,
  42       content: HtmlSanitizeEx.basic_html(object["content"]),
  43       created_at: created_at,
  44       reblogs_count: announcement_count,
  45       favourites_count: like_count,
  46       reblogged: !!repeated,
  47       favourited: !!favorited,
  48       muted: false,
  49       sensitive: sensitive,
  50       spoiler_text: "",
  51       visibility: "public",
  52       media_attachments: attachments,
  53       mentions: mentions,
  54       tags: [], # fix,
  55       application: %{
  56         name: "Web",
  57         website: nil
  58       },
  59       language: nil
  60     }
  61   end
  62
  63   def render("attachment.json", %{attachment: attachment}) do
  64     [%{"mediaType" => media_type, "href" => href} | _] = attachment["url"]
  65
  66     type = cond do
  67       String.contains?(media_type, "image") -> "image"
  68       String.contains?(media_type, "video") -> "video"
  69       true -> "unknown"
  70     end
  71
  72     << hash_id::signed-32, _rest::binary >> = :crypto.hash(:md5, href)
  73
  74     %{
  75       id: attachment["id"] || hash_id,
  76       url: href,
  77       remote_url: href,
  78       preview_url: href,
  79       text_url: href,
  80       type: type
  81     }
  82   end
  83 end