git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/status_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.StatusView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.Activity
   9   alias Pleroma.HTML
  10   alias Pleroma.Repo
  11   alias Pleroma.User
  12   alias Pleroma.Web.CommonAPI.Utils
  13   alias Pleroma.Web.MediaProxy
  14   alias Pleroma.Web.MastodonAPI.AccountView
  15   alias Pleroma.Web.MastodonAPI.StatusView
  16
  17   # TODO: Add cached version.
  18   defp get_replied_to_activities(activities) do
  19     activities
  20     |> Enum.map(fn
  21       %{data: %{"type" => "Create", "object" => %{"inReplyTo" => in_reply_to}}} ->
  22         in_reply_to != "" && in_reply_to
  23
  24       _ ->
  25         nil
  26     end)
  27     |> Enum.filter(& &1)
  28     |> Activity.create_by_object_ap_id()
  29     |> Repo.all()
  30     |> Enum.reduce(%{}, fn activity, acc ->
  31       Map.put(acc, activity.data["object"]["id"], activity)
  32     end)
  33   end
  34
  35   defp get_user(ap_id) do
  36     cond do
  37       user = User.get_cached_by_ap_id(ap_id) ->
  38         user
  39
  40       user = User.get_by_guessed_nickname(ap_id) ->
  41         user
  42
  43       true ->
  44         User.error_user(ap_id)
  45     end
  46   end
  47
  48   def render("index.json", opts) do
  49     replied_to_activities = get_replied_to_activities(opts.activities)
  50
  51     opts.activities
  52     |> safe_render_many(
  53       StatusView,
  54       "status.json",
  55       Map.put(opts, :replied_to_activities, replied_to_activities)
  56     )
  57     |> Enum.filter(fn x -> not is_nil(x) end)
  58   end
  59
  60   def render(
  61         "status.json",
  62         %{activity: %{data: %{"type" => "Announce", "object" => object}} = activity} = opts
  63       ) do
  64     user = get_user(activity.data["actor"])
  65     created_at = Utils.to_masto_date(activity.data["published"])
  66
  67     reblogged = Activity.get_create_by_object_ap_id(object)
  68     reblogged = render("status.json", Map.put(opts, :activity, reblogged))
  69
  70     mentions =
  71       activity.recipients
  72       |> Enum.map(fn ap_id -> User.get_cached_by_ap_id(ap_id) end)
  73       |> Enum.filter(& &1)
  74       |> Enum.map(fn user -> AccountView.render("mention.json", %{user: user}) end)
  75
  76     %{
  77       id: to_string(activity.id),
  78       uri: object,
  79       url: object,
  80       account: AccountView.render("account.json", %{user: user}),
  81       in_reply_to_id: nil,
  82       in_reply_to_account_id: nil,
  83       reblog: reblogged,
  84       content: reblogged[:content] || "",
  85       created_at: created_at,
  86       reblogs_count: 0,
  87       replies_count: 0,
  88       favourites_count: 0,
  89       reblogged: false,
  90       favourited: false,
  91       muted: false,
  92       pinned: pinned?(activity, user),
  93       sensitive: false,
  94       spoiler_text: "",
  95       visibility: "public",
  96       media_attachments: reblogged[:media_attachments] || [],
  97       mentions: mentions,
  98       tags: reblogged[:tags] || [],
  99       application: %{
 100         name: "Web",
 101         website: nil
 102       },
 103       language: nil,
 104       emojis: []
 105     }
 106   end
 107
 108   def render("status.json", %{activity: %{data: %{"object" => object}} = activity} = opts) do
 109     user = get_user(activity.data["actor"])
 110
 111     like_count = object["like_count"] || 0
 112     announcement_count = object["announcement_count"] || 0
 113
 114     tags = object["tag"] || []
 115     sensitive = object["sensitive"] || Enum.member?(tags, "nsfw")
 116
 117     mentions =
 118       activity.recipients
 119       |> Enum.map(fn ap_id -> User.get_cached_by_ap_id(ap_id) end)
 120       |> Enum.filter(& &1)
 121       |> Enum.map(fn user -> AccountView.render("mention.json", %{user: user}) end)
 122
 123     repeated = opts[:for] && opts[:for].ap_id in (object["announcements"] || [])
 124     favorited = opts[:for] && opts[:for].ap_id in (object["likes"] || [])
 125
 126     attachment_data = object["attachment"] || []
 127     attachments = render_many(attachment_data, StatusView, "attachment.json", as: :attachment)
 128
 129     created_at = Utils.to_masto_date(object["published"])
 130
 131     reply_to = get_reply_to(activity, opts)
 132     reply_to_user = reply_to && get_user(reply_to.data["actor"])
 133
 134     content =
 135       object
 136       |> render_content()
 137       |> HTML.get_cached_scrubbed_html_for_object(
 138         User.html_filter_policy(opts[:for]),
 139         activity,
 140         __MODULE__
 141       )
 142
 143     card = render("card.json", Pleroma.Web.RichMedia.Helpers.fetch_data_for_activity(activity))
 144
 145     %{
 146       id: to_string(activity.id),
 147       uri: object["id"],
 148       url: object["external_url"] || object["id"],
 149       account: AccountView.render("account.json", %{user: user}),
 150       in_reply_to_id: reply_to && to_string(reply_to.id),
 151       in_reply_to_account_id: reply_to_user && to_string(reply_to_user.id),
 152       reblog: nil,
 153       card: card,
 154       content: content,
 155       created_at: created_at,
 156       reblogs_count: announcement_count,
 157       replies_count: 0,
 158       favourites_count: like_count,
 159       reblogged: present?(repeated),
 160       favourited: present?(favorited),
 161       muted: false,
 162       pinned: pinned?(activity, user),
 163       sensitive: sensitive,
 164       spoiler_text: object["summary"] || "",
 165       visibility: get_visibility(object),
 166       media_attachments: attachments |> Enum.take(4),
 167       mentions: mentions,
 168       tags: build_tags(tags),
 169       application: %{
 170         name: "Web",
 171         website: nil
 172       },
 173       language: nil,
 174       emojis: build_emojis(activity.data["object"]["emoji"])
 175     }
 176   end
 177
 178   def render("status.json", _) do
 179     nil
 180   end
 181
 182   def render("card.json", %{rich_media: rich_media, page_url: page_url}) do
 183     page_url = rich_media[:url] || page_url
 184     page_url_data = URI.parse(page_url)
 185     site_name = rich_media[:site_name] || page_url_data.host
 186
 187     %{
 188       type: "link",
 189       provider_name: site_name,
 190       provider_url: page_url_data.scheme <> "://" <> page_url_data.host,
 191       url: page_url,
 192       image: rich_media[:image] |> MediaProxy.url(),
 193       title: rich_media[:title],
 194       description: rich_media[:description],
 195       pleroma: %{
 196         opengraph: rich_media
 197       }
 198     }
 199   end
 200
 201   def render("card.json", _) do
 202     nil
 203   end
 204
 205   def render("attachment.json", %{attachment: attachment}) do
 206     [attachment_url | _] = attachment["url"]
 207     media_type = attachment_url["mediaType"] || attachment_url["mimeType"] || "image"
 208     href = attachment_url["href"] |> MediaProxy.url()
 209
 210     type =
 211       cond do
 212         String.contains?(media_type, "image") -> "image"
 213         String.contains?(media_type, "video") -> "video"
 214         String.contains?(media_type, "audio") -> "audio"
 215         true -> "unknown"
 216       end
 217
 218     <<hash_id::signed-32, _rest::binary>> = :crypto.hash(:md5, href)
 219
 220     %{
 221       id: to_string(attachment["id"] || hash_id),
 222       url: href,
 223       remote_url: href,
 224       preview_url: href,
 225       text_url: href,
 226       type: type,
 227       description: attachment["name"]
 228     }
 229   end
 230
 231   def get_reply_to(activity, %{replied_to_activities: replied_to_activities}) do
 232     _id = activity.data["object"]["inReplyTo"]
 233     replied_to_activities[activity.data["object"]["inReplyTo"]]
 234   end
 235
 236   def get_reply_to(%{data: %{"object" => object}}, _) do
 237     if object["inReplyTo"] && object["inReplyTo"] != "" do
 238       Activity.get_create_by_object_ap_id(object["inReplyTo"])
 239     else
 240       nil
 241     end
 242   end
 243
 244   def get_visibility(object) do
 245     public = "https://www.w3.org/ns/activitystreams#Public"
 246     to = object["to"] || []
 247     cc = object["cc"] || []
 248
 249     cond do
 250       public in to ->
 251         "public"
 252
 253       public in cc ->
 254         "unlisted"
 255
 256       # this should use the sql for the object's activity
 257       Enum.any?(to, &String.contains?(&1, "/followers")) ->
 258         "private"
 259
 260       length(cc) > 0 ->
 261         "private"
 262
 263       true ->
 264         "direct"
 265     end
 266   end
 267
 268   def render_content(%{"type" => "Video"} = object) do
 269     with name when not is_nil(name) and name != "" <- object["name"] do
 270       "<p><a href=\"#{object["id"]}\">#{name}</a></p>#{object["content"]}"
 271     else
 272       _ -> object["content"] || ""
 273     end
 274   end
 275
 276   def render_content(%{"type" => object_type} = object)
 277       when object_type in ["Article", "Page"] do
 278     with summary when not is_nil(summary) and summary != "" <- object["name"],
 279          url when is_bitstring(url) <- object["url"] do
 280       "<p><a href=\"#{url}\">#{summary}</a></p>#{object["content"]}"
 281     else
 282       _ -> object["content"] || ""
 283     end
 284   end
 285
 286   def render_content(object), do: object["content"] || ""
 287
 288   @doc """
 289   Builds a dictionary tags.
 290
 291   ## Examples
 292
 293   iex> Pleroma.Web.MastodonAPI.StatusView.build_tags(["fediverse", "nextcloud"])
 294   [{"name": "fediverse", "url": "/tag/fediverse"},
 295    {"name": "nextcloud", "url": "/tag/nextcloud"}]
 296
 297   """
 298   @spec build_tags(list(any())) :: list(map())
 299   def build_tags(object_tags) when is_list(object_tags) do
 300     object_tags = for tag when is_binary(tag) <- object_tags, do: tag
 301
 302     Enum.reduce(object_tags, [], fn tag, tags ->
 303       tags ++ [%{name: tag, url: "/tag/#{tag}"}]
 304     end)
 305   end
 306
 307   def build_tags(_), do: []
 308
 309   @doc """
 310   Builds list emojis.
 311
 312   Arguments: `nil` or list tuple of name and url.
 313
 314   Returns list emojis.
 315
 316   ## Examples
 317
 318   iex> Pleroma.Web.MastodonAPI.StatusView.build_emojis([{"2hu", "corndog.png"}])
 319   [%{shortcode: "2hu", static_url: "corndog.png", url: "corndog.png", visible_in_picker: false}]
 320
 321   """
 322   @spec build_emojis(nil | list(tuple())) :: list(map())
 323   def build_emojis(nil), do: []
 324
 325   def build_emojis(emojis) do
 326     emojis
 327     |> Enum.map(fn {name, url} ->
 328       name = HTML.strip_tags(name)
 329
 330       url =
 331         url
 332         |> HTML.strip_tags()
 333         |> MediaProxy.url()
 334
 335       %{shortcode: name, url: url, static_url: url, visible_in_picker: false}
 336     end)
 337   end
 338
 339   defp present?(nil), do: false
 340   defp present?(false), do: false
 341   defp present?(_), do: true
 342
 343   defp pinned?(%Activity{id: id}, %User{info: %{pinned_activities: pinned_activities}}),
 344     do: id in pinned_activities
 345 end