git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/instance_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.InstanceView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.Config
   9   alias Pleroma.Web.ActivityPub.MRF
  10
  11   @mastodon_api_level "2.7.2"
  12
  13   def render("show.json", _) do
  14     instance = Config.get(:instance)
  15
  16     %{
  17       uri: Pleroma.Web.base_url(),
  18       title: Keyword.get(instance, :name),
  19       description: Keyword.get(instance, :description),
  20       version: "#{@mastodon_api_level} (compatible; #{Pleroma.Application.named_version()})",
  21       email: Keyword.get(instance, :email),
  22       urls: %{
  23         streaming_api: Pleroma.Web.Endpoint.websocket_url()
  24       },
  25       stats: Pleroma.Stats.get_stats(),
  26       thumbnail: Keyword.get(instance, :instance_thumbnail),
  27       languages: ["en"],
  28       registrations: Keyword.get(instance, :registrations_open),
  29       approval_required: Keyword.get(instance, :account_approval_required),
  30       # Extra (not present in Mastodon):
  31       max_toot_chars: Keyword.get(instance, :limit),
  32       poll_limits: Keyword.get(instance, :poll_limits),
  33       upload_limit: Keyword.get(instance, :upload_limit),
  34       avatar_upload_limit: Keyword.get(instance, :avatar_upload_limit),
  35       background_upload_limit: Keyword.get(instance, :background_upload_limit),
  36       banner_upload_limit: Keyword.get(instance, :banner_upload_limit),
  37       background_image: Keyword.get(instance, :background_image),
  38       chat_limit: Keyword.get(instance, :chat_limit),
  39       description_limit: Keyword.get(instance, :description_limit),
  40       pleroma: %{
  41         metadata: %{
  42           account_activation_required: Keyword.get(instance, :account_activation_required),
  43           features: features(),
  44           federation: federation(),
  45           fields_limits: fields_limits(),
  46           post_formats: Config.get([:instance, :allowed_post_formats])
  47         },
  48         vapid_public_key: Keyword.get(Pleroma.Web.Push.vapid_config(), :public_key)
  49       }
  50     }
  51   end
  52
  53   def features do
  54     [
  55       "pleroma_api",
  56       "mastodon_api",
  57       "mastodon_api_streaming",
  58       "polls",
  59       "pleroma_explicit_addressing",
  60       "shareable_emoji_packs",
  61       "multifetch",
  62       "pleroma:api/v1/notifications:include_types_filter",
  63       if Config.get([:media_proxy, :enabled]) do
  64         "media_proxy"
  65       end,
  66       if Config.get([:gopher, :enabled]) do
  67         "gopher"
  68       end,
  69       if Config.get([:chat, :enabled]) do
  70         "chat"
  71       end,
  72       if Config.get([:instance, :allow_relay]) do
  73         "relay"
  74       end,
  75       if Config.get([:instance, :safe_dm_mentions]) do
  76         "safe_dm_mentions"
  77       end,
  78       "pleroma_emoji_reactions",
  79       "pleroma_chat_messages"
  80     ]
  81     |> Enum.filter(& &1)
  82   end
  83
  84   def federation do
  85     quarantined = Config.get([:instance, :quarantined_instances], [])
  86
  87     if Config.get([:mrf, :transparency]) do
  88       {:ok, data} = MRF.describe()
  89
  90       data
  91       |> Map.merge(%{quarantined_instances: quarantined})
  92     else
  93       %{}
  94     end
  95     |> Map.put(:enabled, Config.get([:instance, :federating]))
  96   end
  97
  98   def fields_limits do
  99     %{
 100       max_fields: Config.get([:instance, :max_account_fields]),
 101       max_remote_fields: Config.get([:instance, :max_remote_account_fields]),
 102       name_length: Config.get([:instance, :account_field_name_length]),
 103       value_length: Config.get([:instance, :account_field_value_length])
 104     }
 105   end
 106 end