git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/instance_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.InstanceView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.Config
   9   alias Pleroma.Web.ActivityPub.MRF
  10
  11   @mastodon_api_level "2.7.2"
  12
  13   def render("show.json", _) do
  14     instance = Config.get(:instance)
  15
  16     %{
  17       uri: Pleroma.Web.Endpoint.url(),
  18       title: Keyword.get(instance, :name),
  19       description: Keyword.get(instance, :description),
  20       version: "#{@mastodon_api_level} (compatible; #{Pleroma.Application.named_version()})",
  21       email: Keyword.get(instance, :email),
  22       urls: %{
  23         streaming_api: Pleroma.Web.Endpoint.websocket_url()
  24       },
  25       stats: Pleroma.Stats.get_stats(),
  26       thumbnail:
  27         URI.merge(Pleroma.Web.Endpoint.url(), Keyword.get(instance, :instance_thumbnail))
  28         |> to_string,
  29       languages: ["en"],
  30       registrations: Keyword.get(instance, :registrations_open),
  31       approval_required: Keyword.get(instance, :account_approval_required),
  32       # Extra (not present in Mastodon):
  33       max_toot_chars: Keyword.get(instance, :limit),
  34       poll_limits: Keyword.get(instance, :poll_limits),
  35       upload_limit: Keyword.get(instance, :upload_limit),
  36       avatar_upload_limit: Keyword.get(instance, :avatar_upload_limit),
  37       background_upload_limit: Keyword.get(instance, :background_upload_limit),
  38       banner_upload_limit: Keyword.get(instance, :banner_upload_limit),
  39       background_image: Pleroma.Web.Endpoint.url() <> Keyword.get(instance, :background_image),
  40       shout_limit: Config.get([:shout, :limit]),
  41       description_limit: Keyword.get(instance, :description_limit),
  42       pleroma: %{
  43         metadata: %{
  44           account_activation_required: Keyword.get(instance, :account_activation_required),
  45           features: features(),
  46           federation: federation(),
  47           fields_limits: fields_limits(),
  48           post_formats: Config.get([:instance, :allowed_post_formats]),
  49           privileged_staff: Config.get([:instance, :privileged_staff])
  50         },
  51         stats: %{mau: Pleroma.User.active_user_count()},
  52         vapid_public_key: Keyword.get(Pleroma.Web.Push.vapid_config(), :public_key)
  53       }
  54     }
  55   end
  56
  57   def features do
  58     [
  59       "pleroma_api",
  60       "mastodon_api",
  61       "mastodon_api_streaming",
  62       "polls",
  63       "v2_suggestions",
  64       "pleroma_explicit_addressing",
  65       "shareable_emoji_packs",
  66       "multifetch",
  67       "pleroma:api/v1/notifications:include_types_filter",
  68       if Config.get([:media_proxy, :enabled]) do
  69         "media_proxy"
  70       end,
  71       # backwards compat
  72       if Config.get([:shout, :enabled]) do
  73         "chat"
  74       end,
  75       if Config.get([:shout, :enabled]) do
  76         "shout"
  77       end,
  78       if Config.get([:instance, :allow_relay]) do
  79         "relay"
  80       end,
  81       if Config.get([:instance, :safe_dm_mentions]) do
  82         "safe_dm_mentions"
  83       end,
  84       "pleroma_emoji_reactions",
  85       "pleroma_chat_messages",
  86       if Config.get([:instance, :show_reactions]) do
  87         "exposable_reactions"
  88       end,
  89       if Config.get([:instance, :profile_directory]) do
  90         "profile_directory"
  91       end,
  92       "custom_emoji_reactions"
  93     ]
  94     |> Enum.filter(& &1)
  95   end
  96
  97   def federation do
  98     quarantined = Config.get([:instance, :quarantined_instances], [])
  99
 100     if Config.get([:mrf, :transparency]) do
 101       {:ok, data} = MRF.describe()
 102
 103       data
 104       |> Map.put(
 105         :quarantined_instances,
 106         Enum.map(quarantined, fn {instance, _reason} -> instance end)
 107       )
 108       # This is for backwards compatibility. We originally didn't sent
 109       # extra info like a reason why an instance was rejected/quarantined/etc.
 110       # Because we didn't want to break backwards compatibility it was decided
 111       # to add an extra "info" key.
 112       |> Map.put(:quarantined_instances_info, %{
 113         "quarantined_instances" =>
 114           quarantined
 115           |> Enum.map(fn {instance, reason} -> {instance, %{"reason" => reason}} end)
 116           |> Map.new()
 117       })
 118     else
 119       %{}
 120     end
 121     |> Map.put(:enabled, Config.get([:instance, :federating]))
 122   end
 123
 124   def fields_limits do
 125     %{
 126       max_fields: Config.get([:instance, :max_account_fields]),
 127       max_remote_fields: Config.get([:instance, :max_remote_account_fields]),
 128       name_length: Config.get([:instance, :account_field_name_length]),
 129       value_length: Config.get([:instance, :account_field_value_length])
 130     }
 131   end
 132 end