git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/account_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.AccountView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.FollowingRelationship
   9   alias Pleroma.User
  10   alias Pleroma.UserRelationship
  11   alias Pleroma.Web.CommonAPI.Utils
  12   alias Pleroma.Web.MastodonAPI.AccountView
  13   alias Pleroma.Web.MediaProxy
  14
  15   def render("index.json", %{users: users} = opts) do
  16     reading_user = opts[:for]
  17
  18     relationships_opt =
  19       cond do
  20         Map.has_key?(opts, :relationships) ->
  21           opts[:relationships]
  22
  23         is_nil(reading_user) || !opts[:embed_relationships] ->
  24           UserRelationship.view_relationships_option(nil, [])
  25
  26         true ->
  27           UserRelationship.view_relationships_option(reading_user, users)
  28       end
  29
  30     opts =
  31       opts
  32       |> Map.merge(%{relationships: relationships_opt, as: :user})
  33       |> Map.delete(:users)
  34
  35     users
  36     |> render_many(AccountView, "show.json", opts)
  37     |> Enum.filter(&Enum.any?/1)
  38   end
  39
  40   @doc """
  41   Renders specified user account.
  42     :skip_visibility_check option skips visibility check and renders any user (local or remote)
  43       regardless of [:pleroma, :restrict_unauthenticated] setting.
  44     :for option specifies the requester and can be a User record or nil.
  45       Only use `user: user, for: user` when `user` is the actual requester of own profile.
  46   """
  47   def render("show.json", %{user: _user, skip_visibility_check: true} = opts) do
  48     do_render("show.json", opts)
  49   end
  50
  51   def render("show.json", %{user: user, for: for_user_or_nil} = opts) do
  52     if User.visible_for(user, for_user_or_nil) == :visible do
  53       do_render("show.json", opts)
  54     else
  55       %{}
  56     end
  57   end
  58
  59   def render("show.json", _) do
  60     raise "In order to prevent account accessibility issues, " <>
  61             ":skip_visibility_check or :for option is required."
  62   end
  63
  64   def render("mention.json", %{user: user}) do
  65     %{
  66       id: to_string(user.id),
  67       acct: user.nickname,
  68       username: username_from_nickname(user.nickname),
  69       url: user.uri || user.ap_id
  70     }
  71   end
  72
  73   def render("relationship.json", %{user: nil, target: _target}) do
  74     %{}
  75   end
  76
  77   def render(
  78         "relationship.json",
  79         %{user: %User{} = reading_user, target: %User{} = target} = opts
  80       ) do
  81     user_relationships = get_in(opts, [:relationships, :user_relationships])
  82     following_relationships = get_in(opts, [:relationships, :following_relationships])
  83
  84     follow_state =
  85       if following_relationships do
  86         user_to_target_following_relation =
  87           FollowingRelationship.find(following_relationships, reading_user, target)
  88
  89         User.get_follow_state(reading_user, target, user_to_target_following_relation)
  90       else
  91         User.get_follow_state(reading_user, target)
  92       end
  93
  94     followed_by =
  95       if following_relationships do
  96         case FollowingRelationship.find(following_relationships, target, reading_user) do
  97           %{state: :follow_accept} -> true
  98           _ -> false
  99         end
 100       else
 101         User.following?(target, reading_user)
 102       end
 103
 104     subscribing =
 105       UserRelationship.exists?(
 106         user_relationships,
 107         :inverse_subscription,
 108         target,
 109         reading_user,
 110         &User.subscribed_to?(&2, &1)
 111       )
 112
 113     # NOTE: adjust UserRelationship.view_relationships_option/2 on new relation-related flags
 114     %{
 115       id: to_string(target.id),
 116       following: follow_state == :follow_accept,
 117       followed_by: followed_by,
 118       blocking:
 119         UserRelationship.exists?(
 120           user_relationships,
 121           :block,
 122           reading_user,
 123           target,
 124           &User.blocks_user?(&1, &2)
 125         ),
 126       blocked_by:
 127         UserRelationship.exists?(
 128           user_relationships,
 129           :block,
 130           target,
 131           reading_user,
 132           &User.blocks_user?(&1, &2)
 133         ),
 134       muting:
 135         UserRelationship.exists?(
 136           user_relationships,
 137           :mute,
 138           reading_user,
 139           target,
 140           &User.mutes?(&1, &2)
 141         ),
 142       muting_notifications:
 143         UserRelationship.exists?(
 144           user_relationships,
 145           :notification_mute,
 146           reading_user,
 147           target,
 148           &User.muted_notifications?(&1, &2)
 149         ),
 150       subscribing: subscribing,
 151       notifying: subscribing,
 152       requested: follow_state == :follow_pending,
 153       domain_blocking: User.blocks_domain?(reading_user, target),
 154       showing_reblogs:
 155         not UserRelationship.exists?(
 156           user_relationships,
 157           :reblog_mute,
 158           reading_user,
 159           target,
 160           &User.muting_reblogs?(&1, &2)
 161         ),
 162       endorsed: false
 163     }
 164   end
 165
 166   def render("relationships.json", %{user: user, targets: targets} = opts) do
 167     relationships_opt =
 168       cond do
 169         Map.has_key?(opts, :relationships) ->
 170           opts[:relationships]
 171
 172         is_nil(user) ->
 173           UserRelationship.view_relationships_option(nil, [])
 174
 175         true ->
 176           UserRelationship.view_relationships_option(user, targets)
 177       end
 178
 179     render_opts = %{as: :target, user: user, relationships: relationships_opt}
 180     render_many(targets, AccountView, "relationship.json", render_opts)
 181   end
 182
 183   defp do_render("show.json", %{user: user} = opts) do
 184     user = User.sanitize_html(user, User.html_filter_policy(opts[:for]))
 185     display_name = user.name || user.nickname
 186
 187     avatar = User.avatar_url(user) |> MediaProxy.url()
 188     avatar_static = User.avatar_url(user) |> MediaProxy.preview_url(static: true)
 189     header = User.banner_url(user) |> MediaProxy.url()
 190     header_static = User.banner_url(user) |> MediaProxy.preview_url(static: true)
 191
 192     following_count =
 193       if !user.hide_follows_count or !user.hide_follows or opts[:for] == user,
 194         do: user.following_count,
 195         else: 0
 196
 197     followers_count =
 198       if !user.hide_followers_count or !user.hide_followers or opts[:for] == user,
 199         do: user.follower_count,
 200         else: 0
 201
 202     bot = user.actor_type == "Service"
 203
 204     emojis =
 205       Enum.map(user.emoji, fn {shortcode, raw_url} ->
 206         url = MediaProxy.url(raw_url)
 207
 208         %{
 209           shortcode: shortcode,
 210           url: url,
 211           static_url: url,
 212           visible_in_picker: false
 213         }
 214       end)
 215
 216     relationship =
 217       if opts[:embed_relationships] do
 218         render("relationship.json", %{
 219           user: opts[:for],
 220           target: user,
 221           relationships: opts[:relationships]
 222         })
 223       else
 224         %{}
 225       end
 226
 227     favicon =
 228       if Pleroma.Config.get([:instances_favicons, :enabled]) do
 229         user
 230         |> Map.get(:ap_id, "")
 231         |> URI.parse()
 232         |> URI.merge("/")
 233         |> Pleroma.Instances.Instance.get_or_update_favicon()
 234         |> MediaProxy.url()
 235       else
 236         nil
 237       end
 238
 239     %{
 240       id: to_string(user.id),
 241       username: username_from_nickname(user.nickname),
 242       acct: user.nickname,
 243       display_name: display_name,
 244       locked: user.is_locked,
 245       created_at: Utils.to_masto_date(user.inserted_at),
 246       followers_count: followers_count,
 247       following_count: following_count,
 248       statuses_count: user.note_count,
 249       note: user.bio,
 250       url: user.uri || user.ap_id,
 251       avatar: avatar,
 252       avatar_static: avatar_static,
 253       header: header,
 254       header_static: header_static,
 255       emojis: emojis,
 256       fields: user.fields,
 257       bot: bot,
 258       source: %{
 259         note: user.raw_bio || "",
 260         sensitive: false,
 261         fields: user.raw_fields,
 262         pleroma: %{
 263           discoverable: user.is_discoverable,
 264           actor_type: user.actor_type
 265         }
 266       },
 267
 268       # Pleroma extensions
 269       # Note: it's insecure to output :email but fully-qualified nickname may serve as safe stub
 270       fqn: User.full_nickname(user),
 271       pleroma: %{
 272         ap_id: user.ap_id,
 273         also_known_as: user.also_known_as,
 274         is_confirmed: user.is_confirmed,
 275         is_suggested: user.is_suggested,
 276         tags: user.tags,
 277         hide_followers_count: user.hide_followers_count,
 278         hide_follows_count: user.hide_follows_count,
 279         hide_followers: user.hide_followers,
 280         hide_follows: user.hide_follows,
 281         hide_favorites: user.hide_favorites,
 282         relationship: relationship,
 283         skip_thread_containment: user.skip_thread_containment,
 284         background_image: image_url(user.background) |> MediaProxy.url(),
 285         accepts_chat_messages: user.accepts_chat_messages,
 286         favicon: favicon
 287       }
 288     }
 289     |> maybe_put_role(user, opts[:for])
 290     |> maybe_put_settings(user, opts[:for], opts)
 291     |> maybe_put_notification_settings(user, opts[:for])
 292     |> maybe_put_settings_store(user, opts[:for], opts)
 293     |> maybe_put_chat_token(user, opts[:for], opts)
 294     |> maybe_put_activation_status(user, opts[:for])
 295     |> maybe_put_follow_requests_count(user, opts[:for])
 296     |> maybe_put_allow_following_move(user, opts[:for])
 297     |> maybe_put_unread_conversation_count(user, opts[:for])
 298     |> maybe_put_unread_notification_count(user, opts[:for])
 299     |> maybe_put_email_address(user, opts[:for])
 300   end
 301
 302   defp username_from_nickname(string) when is_binary(string) do
 303     hd(String.split(string, "@"))
 304   end
 305
 306   defp username_from_nickname(_), do: nil
 307
 308   defp maybe_put_follow_requests_count(
 309          data,
 310          %User{id: user_id} = user,
 311          %User{id: user_id}
 312        ) do
 313     count =
 314       User.get_follow_requests(user)
 315       |> length()
 316
 317     data
 318     |> Kernel.put_in([:follow_requests_count], count)
 319   end
 320
 321   defp maybe_put_follow_requests_count(data, _, _), do: data
 322
 323   defp maybe_put_settings(
 324          data,
 325          %User{id: user_id} = user,
 326          %User{id: user_id},
 327          _opts
 328        ) do
 329     data
 330     |> Kernel.put_in([:source, :privacy], user.default_scope)
 331     |> Kernel.put_in([:source, :pleroma, :show_role], user.show_role)
 332     |> Kernel.put_in([:source, :pleroma, :no_rich_text], user.no_rich_text)
 333   end
 334
 335   defp maybe_put_settings(data, _, _, _), do: data
 336
 337   defp maybe_put_settings_store(data, %User{} = user, %User{}, %{
 338          with_pleroma_settings: true
 339        }) do
 340     data
 341     |> Kernel.put_in([:pleroma, :settings_store], user.pleroma_settings_store)
 342   end
 343
 344   defp maybe_put_settings_store(data, _, _, _), do: data
 345
 346   defp maybe_put_chat_token(data, %User{id: id}, %User{id: id}, %{
 347          with_chat_token: token
 348        }) do
 349     data
 350     |> Kernel.put_in([:pleroma, :chat_token], token)
 351   end
 352
 353   defp maybe_put_chat_token(data, _, _, _), do: data
 354
 355   defp maybe_put_role(data, %User{show_role: true} = user, _) do
 356     data
 357     |> Kernel.put_in([:pleroma, :is_admin], user.is_admin)
 358     |> Kernel.put_in([:pleroma, :is_moderator], user.is_moderator)
 359   end
 360
 361   defp maybe_put_role(data, %User{id: user_id} = user, %User{id: user_id}) do
 362     data
 363     |> Kernel.put_in([:pleroma, :is_admin], user.is_admin)
 364     |> Kernel.put_in([:pleroma, :is_moderator], user.is_moderator)
 365   end
 366
 367   defp maybe_put_role(data, _, _), do: data
 368
 369   defp maybe_put_notification_settings(data, %User{id: user_id} = user, %User{id: user_id}) do
 370     Kernel.put_in(
 371       data,
 372       [:pleroma, :notification_settings],
 373       Map.from_struct(user.notification_settings)
 374     )
 375   end
 376
 377   defp maybe_put_notification_settings(data, _, _), do: data
 378
 379   defp maybe_put_allow_following_move(data, %User{id: user_id} = user, %User{id: user_id}) do
 380     Kernel.put_in(data, [:pleroma, :allow_following_move], user.allow_following_move)
 381   end
 382
 383   defp maybe_put_allow_following_move(data, _, _), do: data
 384
 385   defp maybe_put_activation_status(data, user, %User{is_admin: true}) do
 386     Kernel.put_in(data, [:pleroma, :deactivated], !user.is_active)
 387   end
 388
 389   defp maybe_put_activation_status(data, _, _), do: data
 390
 391   defp maybe_put_unread_conversation_count(data, %User{id: user_id} = user, %User{id: user_id}) do
 392     data
 393     |> Kernel.put_in(
 394       [:pleroma, :unread_conversation_count],
 395       Pleroma.Conversation.Participation.unread_count(user)
 396     )
 397   end
 398
 399   defp maybe_put_unread_conversation_count(data, _, _), do: data
 400
 401   defp maybe_put_unread_notification_count(data, %User{id: user_id}, %User{id: user_id} = user) do
 402     Kernel.put_in(
 403       data,
 404       [:pleroma, :unread_notifications_count],
 405       Pleroma.Notification.unread_notifications_count(user)
 406     )
 407   end
 408
 409   defp maybe_put_unread_notification_count(data, _, _), do: data
 410
 411   defp maybe_put_email_address(data, %User{id: user_id}, %User{id: user_id} = user) do
 412     Kernel.put_in(
 413       data,
 414       [:pleroma, :email],
 415       user.email
 416     )
 417   end
 418
 419   defp maybe_put_email_address(data, _, _), do: data
 420
 421   defp image_url(%{"url" => [%{"href" => href} | _]}), do: href
 422   defp image_url(_), do: nil
 423 end