git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/account_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.AccountView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.FollowingRelationship
   9   alias Pleroma.User
  10   alias Pleroma.UserNote
  11   alias Pleroma.UserRelationship
  12   alias Pleroma.Web.CommonAPI.Utils
  13   alias Pleroma.Web.MastodonAPI.AccountView
  14   alias Pleroma.Web.MediaProxy
  15
  16   def render("index.json", %{users: users} = opts) do
  17     reading_user = opts[:for]
  18
  19     relationships_opt =
  20       cond do
  21         Map.has_key?(opts, :relationships) ->
  22           opts[:relationships]
  23
  24         is_nil(reading_user) || !opts[:embed_relationships] ->
  25           UserRelationship.view_relationships_option(nil, [])
  26
  27         true ->
  28           UserRelationship.view_relationships_option(reading_user, users)
  29       end
  30
  31     opts =
  32       opts
  33       |> Map.merge(%{relationships: relationships_opt, as: :user})
  34       |> Map.delete(:users)
  35
  36     users
  37     |> render_many(AccountView, "show.json", opts)
  38     |> Enum.filter(&Enum.any?/1)
  39   end
  40
  41   @doc """
  42   Renders specified user account.
  43     :skip_visibility_check option skips visibility check and renders any user (local or remote)
  44       regardless of [:pleroma, :restrict_unauthenticated] setting.
  45     :for option specifies the requester and can be a User record or nil.
  46       Only use `user: user, for: user` when `user` is the actual requester of own profile.
  47   """
  48   def render("show.json", %{user: _user, skip_visibility_check: true} = opts) do
  49     do_render("show.json", opts)
  50   end
  51
  52   def render("show.json", %{user: user, for: for_user_or_nil} = opts) do
  53     if User.visible_for(user, for_user_or_nil) == :visible do
  54       do_render("show.json", opts)
  55     else
  56       %{}
  57     end
  58   end
  59
  60   def render("show.json", _) do
  61     raise "In order to prevent account accessibility issues, " <>
  62             ":skip_visibility_check or :for option is required."
  63   end
  64
  65   def render("mention.json", %{user: user}) do
  66     %{
  67       id: to_string(user.id),
  68       acct: user.nickname,
  69       username: username_from_nickname(user.nickname),
  70       url: user.uri || user.ap_id
  71     }
  72   end
  73
  74   def render("relationship.json", %{user: nil, target: _target}) do
  75     %{}
  76   end
  77
  78   def render(
  79         "relationship.json",
  80         %{user: %User{} = reading_user, target: %User{} = target} = opts
  81       ) do
  82     user_relationships = get_in(opts, [:relationships, :user_relationships])
  83     following_relationships = get_in(opts, [:relationships, :following_relationships])
  84
  85     follow_state =
  86       if following_relationships do
  87         user_to_target_following_relation =
  88           FollowingRelationship.find(following_relationships, reading_user, target)
  89
  90         User.get_follow_state(reading_user, target, user_to_target_following_relation)
  91       else
  92         User.get_follow_state(reading_user, target)
  93       end
  94
  95     followed_by =
  96       if following_relationships do
  97         case FollowingRelationship.find(following_relationships, target, reading_user) do
  98           %{state: :follow_accept} -> true
  99           _ -> false
 100         end
 101       else
 102         User.following?(target, reading_user)
 103       end
 104
 105     # NOTE: adjust UserRelationship.view_relationships_option/2 on new relation-related flags
 106     %{
 107       id: to_string(target.id),
 108       following: follow_state == :follow_accept,
 109       followed_by: followed_by,
 110       blocking:
 111         UserRelationship.exists?(
 112           user_relationships,
 113           :block,
 114           reading_user,
 115           target,
 116           &User.blocks_user?(&1, &2)
 117         ),
 118       blocked_by:
 119         UserRelationship.exists?(
 120           user_relationships,
 121           :block,
 122           target,
 123           reading_user,
 124           &User.blocks_user?(&1, &2)
 125         ),
 126       muting:
 127         UserRelationship.exists?(
 128           user_relationships,
 129           :mute,
 130           reading_user,
 131           target,
 132           &User.mutes?(&1, &2)
 133         ),
 134       muting_notifications:
 135         UserRelationship.exists?(
 136           user_relationships,
 137           :notification_mute,
 138           reading_user,
 139           target,
 140           &User.muted_notifications?(&1, &2)
 141         ),
 142       subscribing:
 143         UserRelationship.exists?(
 144           user_relationships,
 145           :inverse_subscription,
 146           target,
 147           reading_user,
 148           &User.subscribed_to?(&2, &1)
 149         ),
 150       requested: follow_state == :follow_pending,
 151       domain_blocking: User.blocks_domain?(reading_user, target),
 152       showing_reblogs:
 153         not UserRelationship.exists?(
 154           user_relationships,
 155           :reblog_mute,
 156           reading_user,
 157           target,
 158           &User.muting_reblogs?(&1, &2)
 159         ),
 160       endorsed: false,
 161       note:
 162         UserNote.show(
 163           reading_user,
 164           target
 165         )
 166     }
 167   end
 168
 169   def render("relationships.json", %{user: user, targets: targets} = opts) do
 170     relationships_opt =
 171       cond do
 172         Map.has_key?(opts, :relationships) ->
 173           opts[:relationships]
 174
 175         is_nil(user) ->
 176           UserRelationship.view_relationships_option(nil, [])
 177
 178         true ->
 179           UserRelationship.view_relationships_option(user, targets)
 180       end
 181
 182     render_opts = %{as: :target, user: user, relationships: relationships_opt}
 183     render_many(targets, AccountView, "relationship.json", render_opts)
 184   end
 185
 186   defp do_render("show.json", %{user: user} = opts) do
 187     user = User.sanitize_html(user, User.html_filter_policy(opts[:for]))
 188     display_name = user.name || user.nickname
 189
 190     avatar = User.avatar_url(user) |> MediaProxy.url()
 191     avatar_static = User.avatar_url(user) |> MediaProxy.preview_url(static: true)
 192     header = User.banner_url(user) |> MediaProxy.url()
 193     header_static = User.banner_url(user) |> MediaProxy.preview_url(static: true)
 194
 195     following_count =
 196       if !user.hide_follows_count or !user.hide_follows or opts[:for] == user,
 197         do: user.following_count,
 198         else: 0
 199
 200     followers_count =
 201       if !user.hide_followers_count or !user.hide_followers or opts[:for] == user,
 202         do: user.follower_count,
 203         else: 0
 204
 205     bot = user.actor_type == "Service"
 206
 207     emojis =
 208       Enum.map(user.emoji, fn {shortcode, raw_url} ->
 209         url = MediaProxy.url(raw_url)
 210
 211         %{
 212           shortcode: shortcode,
 213           url: url,
 214           static_url: url,
 215           visible_in_picker: false
 216         }
 217       end)
 218
 219     relationship =
 220       if opts[:embed_relationships] do
 221         render("relationship.json", %{
 222           user: opts[:for],
 223           target: user,
 224           relationships: opts[:relationships]
 225         })
 226       else
 227         %{}
 228       end
 229
 230     favicon =
 231       if Pleroma.Config.get([:instances_favicons, :enabled]) do
 232         user
 233         |> Map.get(:ap_id, "")
 234         |> URI.parse()
 235         |> URI.merge("/")
 236         |> Pleroma.Instances.Instance.get_or_update_favicon()
 237         |> MediaProxy.url()
 238       else
 239         nil
 240       end
 241
 242     %{
 243       id: to_string(user.id),
 244       username: username_from_nickname(user.nickname),
 245       acct: user.nickname,
 246       display_name: display_name,
 247       locked: user.is_locked,
 248       created_at: Utils.to_masto_date(user.inserted_at),
 249       followers_count: followers_count,
 250       following_count: following_count,
 251       statuses_count: user.note_count,
 252       note: user.bio,
 253       url: user.uri || user.ap_id,
 254       avatar: avatar,
 255       avatar_static: avatar_static,
 256       header: header,
 257       header_static: header_static,
 258       emojis: emojis,
 259       fields: user.fields,
 260       bot: bot,
 261       source: %{
 262         note: user.raw_bio || "",
 263         sensitive: false,
 264         fields: user.raw_fields,
 265         pleroma: %{
 266           discoverable: user.is_discoverable,
 267           actor_type: user.actor_type
 268         }
 269       },
 270
 271       # Pleroma extensions
 272       # Note: it's insecure to output :email but fully-qualified nickname may serve as safe stub
 273       fqn: User.full_nickname(user),
 274       pleroma: %{
 275         ap_id: user.ap_id,
 276         also_known_as: user.also_known_as,
 277         is_confirmed: user.is_confirmed,
 278         tags: user.tags,
 279         hide_followers_count: user.hide_followers_count,
 280         hide_follows_count: user.hide_follows_count,
 281         hide_followers: user.hide_followers,
 282         hide_follows: user.hide_follows,
 283         hide_favorites: user.hide_favorites,
 284         relationship: relationship,
 285         skip_thread_containment: user.skip_thread_containment,
 286         background_image: image_url(user.background) |> MediaProxy.url(),
 287         accepts_chat_messages: user.accepts_chat_messages,
 288         favicon: favicon
 289       }
 290     }
 291     |> maybe_put_role(user, opts[:for])
 292     |> maybe_put_settings(user, opts[:for], opts)
 293     |> maybe_put_notification_settings(user, opts[:for])
 294     |> maybe_put_settings_store(user, opts[:for], opts)
 295     |> maybe_put_chat_token(user, opts[:for], opts)
 296     |> maybe_put_activation_status(user, opts[:for])
 297     |> maybe_put_follow_requests_count(user, opts[:for])
 298     |> maybe_put_allow_following_move(user, opts[:for])
 299     |> maybe_put_unread_conversation_count(user, opts[:for])
 300     |> maybe_put_unread_notification_count(user, opts[:for])
 301     |> maybe_put_email_address(user, opts[:for])
 302   end
 303
 304   defp username_from_nickname(string) when is_binary(string) do
 305     hd(String.split(string, "@"))
 306   end
 307
 308   defp username_from_nickname(_), do: nil
 309
 310   defp maybe_put_follow_requests_count(
 311          data,
 312          %User{id: user_id} = user,
 313          %User{id: user_id}
 314        ) do
 315     count =
 316       User.get_follow_requests(user)
 317       |> length()
 318
 319     data
 320     |> Kernel.put_in([:follow_requests_count], count)
 321   end
 322
 323   defp maybe_put_follow_requests_count(data, _, _), do: data
 324
 325   defp maybe_put_settings(
 326          data,
 327          %User{id: user_id} = user,
 328          %User{id: user_id},
 329          _opts
 330        ) do
 331     data
 332     |> Kernel.put_in([:source, :privacy], user.default_scope)
 333     |> Kernel.put_in([:source, :pleroma, :show_role], user.show_role)
 334     |> Kernel.put_in([:source, :pleroma, :no_rich_text], user.no_rich_text)
 335   end
 336
 337   defp maybe_put_settings(data, _, _, _), do: data
 338
 339   defp maybe_put_settings_store(data, %User{} = user, %User{}, %{
 340          with_pleroma_settings: true
 341        }) do
 342     data
 343     |> Kernel.put_in([:pleroma, :settings_store], user.pleroma_settings_store)
 344   end
 345
 346   defp maybe_put_settings_store(data, _, _, _), do: data
 347
 348   defp maybe_put_chat_token(data, %User{id: id}, %User{id: id}, %{
 349          with_chat_token: token
 350        }) do
 351     data
 352     |> Kernel.put_in([:pleroma, :chat_token], token)
 353   end
 354
 355   defp maybe_put_chat_token(data, _, _, _), do: data
 356
 357   defp maybe_put_role(data, %User{show_role: true} = user, _) do
 358     data
 359     |> Kernel.put_in([:pleroma, :is_admin], user.is_admin)
 360     |> Kernel.put_in([:pleroma, :is_moderator], user.is_moderator)
 361   end
 362
 363   defp maybe_put_role(data, %User{id: user_id} = user, %User{id: user_id}) do
 364     data
 365     |> Kernel.put_in([:pleroma, :is_admin], user.is_admin)
 366     |> Kernel.put_in([:pleroma, :is_moderator], user.is_moderator)
 367   end
 368
 369   defp maybe_put_role(data, _, _), do: data
 370
 371   defp maybe_put_notification_settings(data, %User{id: user_id} = user, %User{id: user_id}) do
 372     Kernel.put_in(
 373       data,
 374       [:pleroma, :notification_settings],
 375       Map.from_struct(user.notification_settings)
 376     )
 377   end
 378
 379   defp maybe_put_notification_settings(data, _, _), do: data
 380
 381   defp maybe_put_allow_following_move(data, %User{id: user_id} = user, %User{id: user_id}) do
 382     Kernel.put_in(data, [:pleroma, :allow_following_move], user.allow_following_move)
 383   end
 384
 385   defp maybe_put_allow_following_move(data, _, _), do: data
 386
 387   defp maybe_put_activation_status(data, user, %User{is_admin: true}) do
 388     Kernel.put_in(data, [:pleroma, :deactivated], !user.is_active)
 389   end
 390
 391   defp maybe_put_activation_status(data, _, _), do: data
 392
 393   defp maybe_put_unread_conversation_count(data, %User{id: user_id} = user, %User{id: user_id}) do
 394     data
 395     |> Kernel.put_in(
 396       [:pleroma, :unread_conversation_count],
 397       Pleroma.Conversation.Participation.unread_count(user)
 398     )
 399   end
 400
 401   defp maybe_put_unread_conversation_count(data, _, _), do: data
 402
 403   defp maybe_put_unread_notification_count(data, %User{id: user_id}, %User{id: user_id} = user) do
 404     Kernel.put_in(
 405       data,
 406       [:pleroma, :unread_notifications_count],
 407       Pleroma.Notification.unread_notifications_count(user)
 408     )
 409   end
 410
 411   defp maybe_put_unread_notification_count(data, _, _), do: data
 412
 413   defp maybe_put_email_address(data, %User{id: user_id}, %User{id: user_id} = user) do
 414     Kernel.put_in(
 415       data,
 416       [:pleroma, :email],
 417       user.email
 418     )
 419   end
 420
 421   defp maybe_put_email_address(data, _, _), do: data
 422
 423   defp image_url(%{"url" => [%{"href" => href} | _]}), do: href
 424   defp image_url(_), do: nil
 425 end