git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/account_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.AccountView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.FollowingRelationship
   9   alias Pleroma.User
  10   alias Pleroma.UserRelationship
  11   alias Pleroma.Web.CommonAPI.Utils
  12   alias Pleroma.Web.MastodonAPI.AccountView
  13   alias Pleroma.Web.MediaProxy
  14
  15   def render("index.json", %{users: users} = opts) do
  16     # Note: :skip_relationships option is currently intentionally not supported for accounts
  17     relationships_opt =
  18       cond do
  19         Map.has_key?(opts, :relationships) ->
  20           opts[:relationships]
  21
  22         is_nil(opts[:for]) ->
  23           UserRelationship.view_relationships_option(nil, [])
  24
  25         true ->
  26           UserRelationship.view_relationships_option(opts[:for], users)
  27       end
  28
  29     opts = Map.put(opts, :relationships, relationships_opt)
  30
  31     users
  32     |> render_many(AccountView, "show.json", opts)
  33     |> Enum.filter(&Enum.any?/1)
  34   end
  35
  36   def render("show.json", %{user: user} = opts) do
  37     if User.visible_for?(user, opts[:for]),
  38       do: do_render("show.json", opts),
  39       else: %{}
  40   end
  41
  42   def render("mention.json", %{user: user}) do
  43     %{
  44       id: to_string(user.id),
  45       acct: user.nickname,
  46       username: username_from_nickname(user.nickname),
  47       url: user.uri || user.ap_id
  48     }
  49   end
  50
  51   def render("relationship.json", %{user: nil, target: _target}) do
  52     %{}
  53   end
  54
  55   def render(
  56         "relationship.json",
  57         %{user: %User{} = reading_user, target: %User{} = target} = opts
  58       ) do
  59     user_relationships = get_in(opts, [:relationships, :user_relationships])
  60     following_relationships = get_in(opts, [:relationships, :following_relationships])
  61
  62     follow_state =
  63       if following_relationships do
  64         user_to_target_following_relation =
  65           FollowingRelationship.find(following_relationships, reading_user, target)
  66
  67         User.get_follow_state(reading_user, target, user_to_target_following_relation)
  68       else
  69         User.get_follow_state(reading_user, target)
  70       end
  71
  72     followed_by =
  73       if following_relationships do
  74         case FollowingRelationship.find(following_relationships, target, reading_user) do
  75           %{state: "accept"} -> true
  76           _ -> false
  77         end
  78       else
  79         User.following?(target, reading_user)
  80       end
  81
  82     # NOTE: adjust UserRelationship.view_relationships_option/2 on new relation-related flags
  83     %{
  84       id: to_string(target.id),
  85       following: follow_state == "accept",
  86       followed_by: followed_by,
  87       blocking:
  88         UserRelationship.exists?(
  89           user_relationships,
  90           :block,
  91           reading_user,
  92           target,
  93           &User.blocks_user?(&1, &2)
  94         ),
  95       blocked_by:
  96         UserRelationship.exists?(
  97           user_relationships,
  98           :block,
  99           target,
 100           reading_user,
 101           &User.blocks_user?(&1, &2)
 102         ),
 103       muting:
 104         UserRelationship.exists?(
 105           user_relationships,
 106           :mute,
 107           reading_user,
 108           target,
 109           &User.mutes?(&1, &2)
 110         ),
 111       muting_notifications:
 112         UserRelationship.exists?(
 113           user_relationships,
 114           :notification_mute,
 115           reading_user,
 116           target,
 117           &User.muted_notifications?(&1, &2)
 118         ),
 119       subscribing:
 120         UserRelationship.exists?(
 121           user_relationships,
 122           :inverse_subscription,
 123           target,
 124           reading_user,
 125           &User.subscribed_to?(&2, &1)
 126         ),
 127       requested: follow_state == "pending",
 128       domain_blocking: User.blocks_domain?(reading_user, target),
 129       showing_reblogs:
 130         not UserRelationship.exists?(
 131           user_relationships,
 132           :reblog_mute,
 133           reading_user,
 134           target,
 135           &User.muting_reblogs?(&1, &2)
 136         ),
 137       endorsed: false
 138     }
 139   end
 140
 141   def render("relationships.json", %{user: user, targets: targets} = opts) do
 142     relationships_opt =
 143       cond do
 144         Map.has_key?(opts, :relationships) ->
 145           opts[:relationships]
 146
 147         is_nil(opts[:for]) ->
 148           UserRelationship.view_relationships_option(nil, [])
 149
 150         true ->
 151           UserRelationship.view_relationships_option(user, targets)
 152       end
 153
 154     render_opts = %{as: :target, user: user, relationships: relationships_opt}
 155     render_many(targets, AccountView, "relationship.json", render_opts)
 156   end
 157
 158   defp do_render("show.json", %{user: user} = opts) do
 159     user = User.sanitize_html(user, User.html_filter_policy(opts[:for]))
 160     display_name = user.name || user.nickname
 161
 162     image = User.avatar_url(user) |> MediaProxy.url()
 163     header = User.banner_url(user) |> MediaProxy.url()
 164
 165     following_count =
 166       if !user.hide_follows_count or !user.hide_follows or opts[:for] == user do
 167         user.following_count || 0
 168       else
 169         0
 170       end
 171
 172     followers_count =
 173       if !user.hide_followers_count or !user.hide_followers or opts[:for] == user do
 174         user.follower_count || 0
 175       else
 176         0
 177       end
 178
 179     bot = user.actor_type in ["Application", "Service"]
 180
 181     emojis =
 182       (user.source_data["tag"] || [])
 183       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
 184       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
 185         %{
 186           "shortcode" => String.trim(name, ":"),
 187           "url" => MediaProxy.url(url),
 188           "static_url" => MediaProxy.url(url),
 189           "visible_in_picker" => false
 190         }
 191       end)
 192
 193     relationship =
 194       if opts[:skip_relationships] do
 195         %{}
 196       else
 197         render("relationship.json", %{
 198           user: opts[:for],
 199           target: user,
 200           relationships: opts[:relationships]
 201         })
 202       end
 203
 204     %{
 205       id: to_string(user.id),
 206       username: username_from_nickname(user.nickname),
 207       acct: user.nickname,
 208       display_name: display_name,
 209       locked: user.locked,
 210       created_at: Utils.to_masto_date(user.inserted_at),
 211       followers_count: followers_count,
 212       following_count: following_count,
 213       statuses_count: user.note_count,
 214       note: user.bio || "",
 215       url: user.uri || user.ap_id,
 216       avatar: image,
 217       avatar_static: image,
 218       header: header,
 219       header_static: header,
 220       emojis: emojis,
 221       fields: user.fields,
 222       bot: bot,
 223       source: %{
 224         note: (user.bio || "") |> String.replace(~r(<br */?>), "\n") |> Pleroma.HTML.strip_tags(),
 225         sensitive: false,
 226         fields: user.raw_fields,
 227         pleroma: %{
 228           discoverable: user.discoverable,
 229           actor_type: user.actor_type
 230         }
 231       },
 232
 233       # Pleroma extension
 234       pleroma: %{
 235         confirmation_pending: user.confirmation_pending,
 236         tags: user.tags,
 237         hide_followers_count: user.hide_followers_count,
 238         hide_follows_count: user.hide_follows_count,
 239         hide_followers: user.hide_followers,
 240         hide_follows: user.hide_follows,
 241         hide_favorites: user.hide_favorites,
 242         relationship: relationship,
 243         skip_thread_containment: user.skip_thread_containment,
 244         background_image: image_url(user.background) |> MediaProxy.url()
 245       }
 246     }
 247     |> maybe_put_role(user, opts[:for])
 248     |> maybe_put_settings(user, opts[:for], opts)
 249     |> maybe_put_notification_settings(user, opts[:for])
 250     |> maybe_put_settings_store(user, opts[:for], opts)
 251     |> maybe_put_chat_token(user, opts[:for], opts)
 252     |> maybe_put_activation_status(user, opts[:for])
 253     |> maybe_put_follow_requests_count(user, opts[:for])
 254     |> maybe_put_allow_following_move(user, opts[:for])
 255     |> maybe_put_unread_conversation_count(user, opts[:for])
 256   end
 257
 258   defp username_from_nickname(string) when is_binary(string) do
 259     hd(String.split(string, "@"))
 260   end
 261
 262   defp username_from_nickname(_), do: nil
 263
 264   defp maybe_put_follow_requests_count(
 265          data,
 266          %User{id: user_id} = user,
 267          %User{id: user_id}
 268        ) do
 269     count =
 270       User.get_follow_requests(user)
 271       |> length()
 272
 273     data
 274     |> Kernel.put_in([:follow_requests_count], count)
 275   end
 276
 277   defp maybe_put_follow_requests_count(data, _, _), do: data
 278
 279   defp maybe_put_settings(
 280          data,
 281          %User{id: user_id} = user,
 282          %User{id: user_id},
 283          _opts
 284        ) do
 285     data
 286     |> Kernel.put_in([:source, :privacy], user.default_scope)
 287     |> Kernel.put_in([:source, :pleroma, :show_role], user.show_role)
 288     |> Kernel.put_in([:source, :pleroma, :no_rich_text], user.no_rich_text)
 289   end
 290
 291   defp maybe_put_settings(data, _, _, _), do: data
 292
 293   defp maybe_put_settings_store(data, %User{} = user, %User{}, %{
 294          with_pleroma_settings: true
 295        }) do
 296     data
 297     |> Kernel.put_in([:pleroma, :settings_store], user.pleroma_settings_store)
 298   end
 299
 300   defp maybe_put_settings_store(data, _, _, _), do: data
 301
 302   defp maybe_put_chat_token(data, %User{id: id}, %User{id: id}, %{
 303          with_chat_token: token
 304        }) do
 305     data
 306     |> Kernel.put_in([:pleroma, :chat_token], token)
 307   end
 308
 309   defp maybe_put_chat_token(data, _, _, _), do: data
 310
 311   defp maybe_put_role(data, %User{show_role: true} = user, _) do
 312     data
 313     |> Kernel.put_in([:pleroma, :is_admin], user.is_admin)
 314     |> Kernel.put_in([:pleroma, :is_moderator], user.is_moderator)
 315   end
 316
 317   defp maybe_put_role(data, %User{id: user_id} = user, %User{id: user_id}) do
 318     data
 319     |> Kernel.put_in([:pleroma, :is_admin], user.is_admin)
 320     |> Kernel.put_in([:pleroma, :is_moderator], user.is_moderator)
 321   end
 322
 323   defp maybe_put_role(data, _, _), do: data
 324
 325   defp maybe_put_notification_settings(data, %User{id: user_id} = user, %User{id: user_id}) do
 326     Kernel.put_in(data, [:pleroma, :notification_settings], user.notification_settings)
 327   end
 328
 329   defp maybe_put_notification_settings(data, _, _), do: data
 330
 331   defp maybe_put_allow_following_move(data, %User{id: user_id} = user, %User{id: user_id}) do
 332     Kernel.put_in(data, [:pleroma, :allow_following_move], user.allow_following_move)
 333   end
 334
 335   defp maybe_put_allow_following_move(data, _, _), do: data
 336
 337   defp maybe_put_activation_status(data, user, %User{is_admin: true}) do
 338     Kernel.put_in(data, [:pleroma, :deactivated], user.deactivated)
 339   end
 340
 341   defp maybe_put_activation_status(data, _, _), do: data
 342
 343   defp maybe_put_unread_conversation_count(data, %User{id: user_id} = user, %User{id: user_id}) do
 344     data
 345     |> Kernel.put_in(
 346       [:pleroma, :unread_conversation_count],
 347       user.unread_conversation_count
 348     )
 349   end
 350
 351   defp maybe_put_unread_conversation_count(data, _, _), do: data
 352
 353   defp image_url(%{"url" => [%{"href" => href} | _]}), do: href
 354   defp image_url(_), do: nil
 355 end