git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/account_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.AccountView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.FollowingRelationship
   9   alias Pleroma.User
  10   alias Pleroma.UserRelationship
  11   alias Pleroma.Web.CommonAPI.Utils
  12   alias Pleroma.Web.MastodonAPI.AccountView
  13   alias Pleroma.Web.MediaProxy
  14
  15   def render("index.json", %{users: users} = opts) do
  16     opts = Map.merge(%{skip_relationships: false}, opts)
  17
  18     reading_user = opts[:for]
  19
  20     relationships_opt =
  21       cond do
  22         Map.has_key?(opts, :relationships) ->
  23           opts[:relationships]
  24
  25         is_nil(reading_user) || opts[:skip_relationships] ->
  26           UserRelationship.view_relationships_option(nil, [])
  27
  28         true ->
  29           UserRelationship.view_relationships_option(reading_user, users)
  30       end
  31
  32     opts = Map.put(opts, :relationships, relationships_opt)
  33
  34     users
  35     |> render_many(AccountView, "show.json", opts)
  36     |> Enum.filter(&Enum.any?/1)
  37   end
  38
  39   def render("show.json", %{user: user} = opts) do
  40     if User.visible_for?(user, opts[:for]) do
  41       do_render("show.json", opts)
  42     else
  43       %{}
  44     end
  45   end
  46
  47   def render("mention.json", %{user: user}) do
  48     %{
  49       id: to_string(user.id),
  50       acct: user.nickname,
  51       username: username_from_nickname(user.nickname),
  52       url: user.uri || user.ap_id
  53     }
  54   end
  55
  56   def render("relationship.json", %{user: nil, target: _target}) do
  57     %{}
  58   end
  59
  60   def render(
  61         "relationship.json",
  62         %{user: %User{} = reading_user, target: %User{} = target} = opts
  63       ) do
  64     user_relationships = get_in(opts, [:relationships, :user_relationships])
  65     following_relationships = get_in(opts, [:relationships, :following_relationships])
  66
  67     follow_state =
  68       if following_relationships do
  69         user_to_target_following_relation =
  70           FollowingRelationship.find(following_relationships, reading_user, target)
  71
  72         User.get_follow_state(reading_user, target, user_to_target_following_relation)
  73       else
  74         User.get_follow_state(reading_user, target)
  75       end
  76
  77     followed_by =
  78       if following_relationships do
  79         case FollowingRelationship.find(following_relationships, target, reading_user) do
  80           %{state: :follow_accept} -> true
  81           _ -> false
  82         end
  83       else
  84         User.following?(target, reading_user)
  85       end
  86
  87     # NOTE: adjust UserRelationship.view_relationships_option/2 on new relation-related flags
  88     %{
  89       id: to_string(target.id),
  90       following: follow_state == :follow_accept,
  91       followed_by: followed_by,
  92       blocking:
  93         UserRelationship.exists?(
  94           user_relationships,
  95           :block,
  96           reading_user,
  97           target,
  98           &User.blocks_user?(&1, &2)
  99         ),
 100       blocked_by:
 101         UserRelationship.exists?(
 102           user_relationships,
 103           :block,
 104           target,
 105           reading_user,
 106           &User.blocks_user?(&1, &2)
 107         ),
 108       muting:
 109         UserRelationship.exists?(
 110           user_relationships,
 111           :mute,
 112           reading_user,
 113           target,
 114           &User.mutes?(&1, &2)
 115         ),
 116       muting_notifications:
 117         UserRelationship.exists?(
 118           user_relationships,
 119           :notification_mute,
 120           reading_user,
 121           target,
 122           &User.muted_notifications?(&1, &2)
 123         ),
 124       subscribing:
 125         UserRelationship.exists?(
 126           user_relationships,
 127           :inverse_subscription,
 128           target,
 129           reading_user,
 130           &User.subscribed_to?(&2, &1)
 131         ),
 132       requested: follow_state == :follow_pending,
 133       domain_blocking: User.blocks_domain?(reading_user, target),
 134       showing_reblogs:
 135         not UserRelationship.exists?(
 136           user_relationships,
 137           :reblog_mute,
 138           reading_user,
 139           target,
 140           &User.muting_reblogs?(&1, &2)
 141         ),
 142       endorsed: false
 143     }
 144   end
 145
 146   def render("relationships.json", %{user: user, targets: targets} = opts) do
 147     relationships_opt =
 148       cond do
 149         Map.has_key?(opts, :relationships) ->
 150           opts[:relationships]
 151
 152         is_nil(user) ->
 153           UserRelationship.view_relationships_option(nil, [])
 154
 155         true ->
 156           UserRelationship.view_relationships_option(user, targets)
 157       end
 158
 159     render_opts = %{as: :target, user: user, relationships: relationships_opt}
 160     render_many(targets, AccountView, "relationship.json", render_opts)
 161   end
 162
 163   defp do_render("show.json", %{user: user} = opts) do
 164     opts = Map.merge(%{skip_relationships: false}, opts)
 165
 166     user = User.sanitize_html(user, User.html_filter_policy(opts[:for]))
 167     display_name = user.name || user.nickname
 168
 169     image = User.avatar_url(user) |> MediaProxy.url()
 170     header = User.banner_url(user) |> MediaProxy.url()
 171
 172     following_count =
 173       if !user.hide_follows_count or !user.hide_follows or opts[:for] == user do
 174         user.following_count || 0
 175       else
 176         0
 177       end
 178
 179     followers_count =
 180       if !user.hide_followers_count or !user.hide_followers or opts[:for] == user do
 181         user.follower_count || 0
 182       else
 183         0
 184       end
 185
 186     bot = user.actor_type in ["Application", "Service"]
 187
 188     emojis =
 189       Enum.map(user.emoji, fn {shortcode, url} ->
 190         %{
 191           "shortcode" => shortcode,
 192           "url" => url,
 193           "static_url" => url,
 194           "visible_in_picker" => false
 195         }
 196       end)
 197
 198     relationship =
 199       if opts[:skip_relationships] do
 200         %{}
 201       else
 202         render("relationship.json", %{
 203           user: opts[:for],
 204           target: user,
 205           relationships: opts[:relationships]
 206         })
 207       end
 208
 209     %{
 210       id: to_string(user.id),
 211       username: username_from_nickname(user.nickname),
 212       acct: user.nickname,
 213       display_name: display_name,
 214       locked: user.locked,
 215       created_at: Utils.to_masto_date(user.inserted_at),
 216       followers_count: followers_count,
 217       following_count: following_count,
 218       statuses_count: user.note_count,
 219       note: user.bio || "",
 220       url: user.uri || user.ap_id,
 221       avatar: image,
 222       avatar_static: image,
 223       header: header,
 224       header_static: header,
 225       emojis: emojis,
 226       fields: user.fields,
 227       bot: bot,
 228       source: %{
 229         note: prepare_user_bio(user),
 230         sensitive: false,
 231         fields: user.raw_fields,
 232         pleroma: %{
 233           discoverable: user.discoverable,
 234           actor_type: user.actor_type
 235         }
 236       },
 237
 238       # Pleroma extension
 239       pleroma: %{
 240         confirmation_pending: user.confirmation_pending,
 241         tags: user.tags,
 242         hide_followers_count: user.hide_followers_count,
 243         hide_follows_count: user.hide_follows_count,
 244         hide_followers: user.hide_followers,
 245         hide_follows: user.hide_follows,
 246         hide_favorites: user.hide_favorites,
 247         relationship: relationship,
 248         skip_thread_containment: user.skip_thread_containment,
 249         background_image: image_url(user.background) |> MediaProxy.url()
 250       }
 251     }
 252     |> maybe_put_role(user, opts[:for])
 253     |> maybe_put_settings(user, opts[:for], opts)
 254     |> maybe_put_notification_settings(user, opts[:for])
 255     |> maybe_put_settings_store(user, opts[:for], opts)
 256     |> maybe_put_chat_token(user, opts[:for], opts)
 257     |> maybe_put_activation_status(user, opts[:for])
 258     |> maybe_put_follow_requests_count(user, opts[:for])
 259     |> maybe_put_allow_following_move(user, opts[:for])
 260     |> maybe_put_unread_conversation_count(user, opts[:for])
 261     |> maybe_put_unread_notification_count(user, opts[:for])
 262   end
 263
 264   defp prepare_user_bio(%User{bio: ""}), do: ""
 265
 266   defp prepare_user_bio(%User{bio: bio}) when is_binary(bio) do
 267     bio |> String.replace(~r(<br */?>), "\n") |> Pleroma.HTML.strip_tags()
 268   end
 269
 270   defp prepare_user_bio(_), do: ""
 271
 272   defp username_from_nickname(string) when is_binary(string) do
 273     hd(String.split(string, "@"))
 274   end
 275
 276   defp username_from_nickname(_), do: nil
 277
 278   defp maybe_put_follow_requests_count(
 279          data,
 280          %User{id: user_id} = user,
 281          %User{id: user_id}
 282        ) do
 283     count =
 284       User.get_follow_requests(user)
 285       |> length()
 286
 287     data
 288     |> Kernel.put_in([:follow_requests_count], count)
 289   end
 290
 291   defp maybe_put_follow_requests_count(data, _, _), do: data
 292
 293   defp maybe_put_settings(
 294          data,
 295          %User{id: user_id} = user,
 296          %User{id: user_id},
 297          _opts
 298        ) do
 299     data
 300     |> Kernel.put_in([:source, :privacy], user.default_scope)
 301     |> Kernel.put_in([:source, :pleroma, :show_role], user.show_role)
 302     |> Kernel.put_in([:source, :pleroma, :no_rich_text], user.no_rich_text)
 303   end
 304
 305   defp maybe_put_settings(data, _, _, _), do: data
 306
 307   defp maybe_put_settings_store(data, %User{} = user, %User{}, %{
 308          with_pleroma_settings: true
 309        }) do
 310     data
 311     |> Kernel.put_in([:pleroma, :settings_store], user.pleroma_settings_store)
 312   end
 313
 314   defp maybe_put_settings_store(data, _, _, _), do: data
 315
 316   defp maybe_put_chat_token(data, %User{id: id}, %User{id: id}, %{
 317          with_chat_token: token
 318        }) do
 319     data
 320     |> Kernel.put_in([:pleroma, :chat_token], token)
 321   end
 322
 323   defp maybe_put_chat_token(data, _, _, _), do: data
 324
 325   defp maybe_put_role(data, %User{show_role: true} = user, _) do
 326     data
 327     |> Kernel.put_in([:pleroma, :is_admin], user.is_admin)
 328     |> Kernel.put_in([:pleroma, :is_moderator], user.is_moderator)
 329   end
 330
 331   defp maybe_put_role(data, %User{id: user_id} = user, %User{id: user_id}) do
 332     data
 333     |> Kernel.put_in([:pleroma, :is_admin], user.is_admin)
 334     |> Kernel.put_in([:pleroma, :is_moderator], user.is_moderator)
 335   end
 336
 337   defp maybe_put_role(data, _, _), do: data
 338
 339   defp maybe_put_notification_settings(data, %User{id: user_id} = user, %User{id: user_id}) do
 340     Kernel.put_in(data, [:pleroma, :notification_settings], user.notification_settings)
 341   end
 342
 343   defp maybe_put_notification_settings(data, _, _), do: data
 344
 345   defp maybe_put_allow_following_move(data, %User{id: user_id} = user, %User{id: user_id}) do
 346     Kernel.put_in(data, [:pleroma, :allow_following_move], user.allow_following_move)
 347   end
 348
 349   defp maybe_put_allow_following_move(data, _, _), do: data
 350
 351   defp maybe_put_activation_status(data, user, %User{is_admin: true}) do
 352     Kernel.put_in(data, [:pleroma, :deactivated], user.deactivated)
 353   end
 354
 355   defp maybe_put_activation_status(data, _, _), do: data
 356
 357   defp maybe_put_unread_conversation_count(data, %User{id: user_id} = user, %User{id: user_id}) do
 358     data
 359     |> Kernel.put_in(
 360       [:pleroma, :unread_conversation_count],
 361       user.unread_conversation_count
 362     )
 363   end
 364
 365   defp maybe_put_unread_conversation_count(data, _, _), do: data
 366
 367   defp maybe_put_unread_notification_count(data, %User{id: user_id}, %User{id: user_id} = user) do
 368     Kernel.put_in(
 369       data,
 370       [:pleroma, :unread_notifications_count],
 371       Pleroma.Notification.unread_notifications_count(user)
 372     )
 373   end
 374
 375   defp maybe_put_unread_notification_count(data, _, _), do: data
 376
 377   defp image_url(%{"url" => [%{"href" => href} | _]}), do: href
 378   defp image_url(_), do: nil
 379 end