git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/account_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.AccountView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.HTML
   9   alias Pleroma.User
  10   alias Pleroma.Web.CommonAPI.Utils
  11   alias Pleroma.Web.MastodonAPI.AccountView
  12   alias Pleroma.Web.MediaProxy
  13
  14   def render("accounts.json", %{users: users} = opts) do
  15     users
  16     |> render_many(AccountView, "account.json", opts)
  17     |> Enum.filter(&Enum.any?/1)
  18   end
  19
  20   def render("account.json", %{user: user} = opts) do
  21     if User.visible_for?(user, opts[:for]),
  22       do: do_render("account.json", opts),
  23       else: %{}
  24   end
  25
  26   def render("mention.json", %{user: user}) do
  27     %{
  28       id: to_string(user.id),
  29       acct: user.nickname,
  30       username: username_from_nickname(user.nickname),
  31       url: user.ap_id
  32     }
  33   end
  34
  35   def render("relationship.json", %{user: nil, target: _target}) do
  36     %{}
  37   end
  38
  39   def render("relationship.json", %{user: %User{} = user, target: %User{} = target}) do
  40     follow_activity = Pleroma.Web.ActivityPub.Utils.fetch_latest_follow(user, target)
  41
  42     requested =
  43       if follow_activity && !User.following?(target, user) do
  44         follow_activity.data["state"] == "pending"
  45       else
  46         false
  47       end
  48
  49     %{
  50       id: to_string(target.id),
  51       following: User.following?(user, target),
  52       followed_by: User.following?(target, user),
  53       blocking: User.blocks?(user, target),
  54       blocked_by: User.blocks?(target, user),
  55       muting: User.mutes?(user, target),
  56       muting_notifications: User.muted_notifications?(user, target),
  57       subscribing: User.subscribed_to?(user, target),
  58       requested: requested,
  59       domain_blocking: false,
  60       showing_reblogs: User.showing_reblogs?(user, target),
  61       endorsed: false
  62     }
  63   end
  64
  65   def render("relationships.json", %{user: user, targets: targets}) do
  66     render_many(targets, AccountView, "relationship.json", user: user, as: :target)
  67   end
  68
  69   defp do_render("account.json", %{user: user} = opts) do
  70     display_name = HTML.strip_tags(user.name || user.nickname)
  71
  72     image = User.avatar_url(user) |> MediaProxy.url()
  73     header = User.banner_url(user) |> MediaProxy.url()
  74     user_info = User.get_cached_user_info(user)
  75     bot = (user.info.source_data["type"] || "Person") in ["Application", "Service"]
  76
  77     emojis =
  78       (user.info.source_data["tag"] || [])
  79       |> Enum.filter(fn %{"type" => t} -> t == "Emoji" end)
  80       |> Enum.map(fn %{"icon" => %{"url" => url}, "name" => name} ->
  81         %{
  82           "shortcode" => String.trim(name, ":"),
  83           "url" => MediaProxy.url(url),
  84           "static_url" => MediaProxy.url(url),
  85           "visible_in_picker" => false
  86         }
  87       end)
  88
  89     fields =
  90       (user.info.source_data["attachment"] || [])
  91       |> Enum.filter(fn %{"type" => t} -> t == "PropertyValue" end)
  92       |> Enum.map(fn fields -> Map.take(fields, ["name", "value"]) end)
  93
  94     bio = HTML.filter_tags(user.bio, User.html_filter_policy(opts[:for]))
  95
  96     relationship = render("relationship.json", %{user: opts[:for], target: user})
  97
  98     %{
  99       id: to_string(user.id),
 100       username: username_from_nickname(user.nickname),
 101       acct: user.nickname,
 102       display_name: display_name,
 103       locked: user_info.locked,
 104       created_at: Utils.to_masto_date(user.inserted_at),
 105       followers_count: user_info.follower_count,
 106       following_count: user_info.following_count,
 107       statuses_count: user_info.note_count,
 108       note: bio || "",
 109       url: user.ap_id,
 110       avatar: image,
 111       avatar_static: image,
 112       header: header,
 113       header_static: header,
 114       emojis: emojis,
 115       fields: fields,
 116       bot: bot,
 117       source: %{
 118         note: HTML.strip_tags((user.bio || "") |> String.replace("<br>", "\n")),
 119         sensitive: false,
 120         pleroma: %{}
 121       },
 122
 123       # Pleroma extension
 124       pleroma: %{
 125         confirmation_pending: user_info.confirmation_pending,
 126         tags: user.tags,
 127         hide_followers: user.info.hide_followers,
 128         hide_follows: user.info.hide_follows,
 129         hide_favorites: user.info.hide_favorites,
 130         relationship: relationship,
 131         skip_thread_containment: user.info.skip_thread_containment,
 132         background_image: image_url(user.info.background) |> MediaProxy.url()
 133       }
 134     }
 135     |> maybe_put_role(user, opts[:for])
 136     |> maybe_put_settings(user, opts[:for], user_info)
 137     |> maybe_put_notification_settings(user, opts[:for])
 138     |> maybe_put_settings_store(user, opts[:for], opts)
 139     |> maybe_put_chat_token(user, opts[:for], opts)
 140   end
 141
 142   defp username_from_nickname(string) when is_binary(string) do
 143     hd(String.split(string, "@"))
 144   end
 145
 146   defp username_from_nickname(_), do: nil
 147
 148   defp maybe_put_settings(
 149          data,
 150          %User{id: user_id} = user,
 151          %User{id: user_id},
 152          user_info
 153        ) do
 154     data
 155     |> Kernel.put_in([:source, :privacy], user_info.default_scope)
 156     |> Kernel.put_in([:source, :pleroma, :show_role], user.info.show_role)
 157     |> Kernel.put_in([:source, :pleroma, :no_rich_text], user.info.no_rich_text)
 158   end
 159
 160   defp maybe_put_settings(data, _, _, _), do: data
 161
 162   defp maybe_put_settings_store(data, %User{info: info, id: id}, %User{id: id}, %{
 163          with_pleroma_settings: true
 164        }) do
 165     data
 166     |> Kernel.put_in([:pleroma, :settings_store], info.pleroma_settings_store)
 167   end
 168
 169   defp maybe_put_settings_store(data, _, _, _), do: data
 170
 171   defp maybe_put_chat_token(data, %User{id: id}, %User{id: id}, %{
 172          with_chat_token: token
 173        }) do
 174     data
 175     |> Kernel.put_in([:pleroma, :chat_token], token)
 176   end
 177
 178   defp maybe_put_chat_token(data, _, _, _), do: data
 179
 180   defp maybe_put_role(data, %User{info: %{show_role: true}} = user, _) do
 181     data
 182     |> Kernel.put_in([:pleroma, :is_admin], user.info.is_admin)
 183     |> Kernel.put_in([:pleroma, :is_moderator], user.info.is_moderator)
 184   end
 185
 186   defp maybe_put_role(data, %User{id: user_id} = user, %User{id: user_id}) do
 187     data
 188     |> Kernel.put_in([:pleroma, :is_admin], user.info.is_admin)
 189     |> Kernel.put_in([:pleroma, :is_moderator], user.info.is_moderator)
 190   end
 191
 192   defp maybe_put_role(data, _, _), do: data
 193
 194   defp maybe_put_notification_settings(data, %User{id: user_id} = user, %User{id: user_id}) do
 195     Kernel.put_in(data, [:pleroma, :notification_settings], user.info.notification_settings)
 196   end
 197
 198   defp maybe_put_notification_settings(data, _, _), do: data
 199
 200   defp image_url(%{"url" => [%{"href" => href} | _]}), do: href
 201   defp image_url(_), do: nil
 202 end