git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/account_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.AccountView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.FollowingRelationship
   9   alias Pleroma.User
  10   alias Pleroma.UserRelationship
  11   alias Pleroma.Web.CommonAPI.Utils
  12   alias Pleroma.Web.MastodonAPI.AccountView
  13   alias Pleroma.Web.MediaProxy
  14
  15   def render("index.json", %{users: users} = opts) do
  16     reading_user = opts[:for]
  17
  18     relationships_opt =
  19       cond do
  20         Map.has_key?(opts, :relationships) ->
  21           opts[:relationships]
  22
  23         is_nil(reading_user) || !opts[:embed_relationships] ->
  24           UserRelationship.view_relationships_option(nil, [])
  25
  26         true ->
  27           UserRelationship.view_relationships_option(reading_user, users)
  28       end
  29
  30     opts =
  31       opts
  32       |> Map.merge(%{relationships: relationships_opt, as: :user})
  33       |> Map.delete(:users)
  34
  35     users
  36     |> render_many(AccountView, "show.json", opts)
  37     |> Enum.filter(&Enum.any?/1)
  38   end
  39
  40   @doc """
  41   Renders specified user account.
  42     :skip_visibility_check option skips visibility check and renders any user (local or remote)
  43       regardless of [:pleroma, :restrict_unauthenticated] setting.
  44     :for option specifies the requester and can be a User record or nil.
  45       Only use `user: user, for: user` when `user` is the actual requester of own profile.
  46   """
  47   def render("show.json", %{user: _user, skip_visibility_check: true} = opts) do
  48     do_render("show.json", opts)
  49   end
  50
  51   def render("show.json", %{user: user, for: for_user_or_nil} = opts) do
  52     if User.visible_for(user, for_user_or_nil) == :visible do
  53       do_render("show.json", opts)
  54     else
  55       %{}
  56     end
  57   end
  58
  59   def render("show.json", _) do
  60     raise "In order to prevent account accessibility issues, " <>
  61             ":skip_visibility_check or :for option is required."
  62   end
  63
  64   def render("mention.json", %{user: user}) do
  65     %{
  66       id: to_string(user.id),
  67       acct: user.nickname,
  68       username: username_from_nickname(user.nickname),
  69       url: user.uri || user.ap_id
  70     }
  71   end
  72
  73   def render("relationship.json", %{user: nil, target: _target}) do
  74     %{}
  75   end
  76
  77   def render(
  78         "relationship.json",
  79         %{user: %User{} = reading_user, target: %User{} = target} = opts
  80       ) do
  81     user_relationships = get_in(opts, [:relationships, :user_relationships])
  82     following_relationships = get_in(opts, [:relationships, :following_relationships])
  83
  84     follow_state =
  85       if following_relationships do
  86         user_to_target_following_relation =
  87           FollowingRelationship.find(following_relationships, reading_user, target)
  88
  89         User.get_follow_state(reading_user, target, user_to_target_following_relation)
  90       else
  91         User.get_follow_state(reading_user, target)
  92       end
  93
  94     followed_by =
  95       if following_relationships do
  96         case FollowingRelationship.find(following_relationships, target, reading_user) do
  97           %{state: :follow_accept} -> true
  98           _ -> false
  99         end
 100       else
 101         User.following?(target, reading_user)
 102       end
 103
 104     # NOTE: adjust UserRelationship.view_relationships_option/2 on new relation-related flags
 105     %{
 106       id: to_string(target.id),
 107       following: follow_state == :follow_accept,
 108       followed_by: followed_by,
 109       blocking:
 110         UserRelationship.exists?(
 111           user_relationships,
 112           :block,
 113           reading_user,
 114           target,
 115           &User.blocks_user?(&1, &2)
 116         ),
 117       blocked_by:
 118         UserRelationship.exists?(
 119           user_relationships,
 120           :block,
 121           target,
 122           reading_user,
 123           &User.blocks_user?(&1, &2)
 124         ),
 125       muting:
 126         UserRelationship.exists?(
 127           user_relationships,
 128           :mute,
 129           reading_user,
 130           target,
 131           &User.mutes?(&1, &2)
 132         ),
 133       muting_notifications:
 134         UserRelationship.exists?(
 135           user_relationships,
 136           :notification_mute,
 137           reading_user,
 138           target,
 139           &User.muted_notifications?(&1, &2)
 140         ),
 141       subscribing:
 142         UserRelationship.exists?(
 143           user_relationships,
 144           :inverse_subscription,
 145           target,
 146           reading_user,
 147           &User.subscribed_to?(&2, &1)
 148         ),
 149       requested: follow_state == :follow_pending,
 150       domain_blocking: User.blocks_domain?(reading_user, target),
 151       showing_reblogs:
 152         not UserRelationship.exists?(
 153           user_relationships,
 154           :reblog_mute,
 155           reading_user,
 156           target,
 157           &User.muting_reblogs?(&1, &2)
 158         ),
 159       endorsed: false
 160     }
 161   end
 162
 163   def render("relationships.json", %{user: user, targets: targets} = opts) do
 164     relationships_opt =
 165       cond do
 166         Map.has_key?(opts, :relationships) ->
 167           opts[:relationships]
 168
 169         is_nil(user) ->
 170           UserRelationship.view_relationships_option(nil, [])
 171
 172         true ->
 173           UserRelationship.view_relationships_option(user, targets)
 174       end
 175
 176     render_opts = %{as: :target, user: user, relationships: relationships_opt}
 177     render_many(targets, AccountView, "relationship.json", render_opts)
 178   end
 179
 180   defp do_render("show.json", %{user: user} = opts) do
 181     user = User.sanitize_html(user, User.html_filter_policy(opts[:for]))
 182     display_name = user.name || user.nickname
 183
 184     avatar = User.avatar_url(user) |> MediaProxy.url()
 185     avatar_static = User.avatar_url(user) |> MediaProxy.preview_url(static: true)
 186     header = User.banner_url(user) |> MediaProxy.url()
 187     header_static = User.banner_url(user) |> MediaProxy.preview_url(static: true)
 188
 189     following_count =
 190       if !user.hide_follows_count or !user.hide_follows or opts[:for] == user,
 191         do: user.following_count,
 192         else: 0
 193
 194     followers_count =
 195       if !user.hide_followers_count or !user.hide_followers or opts[:for] == user,
 196         do: user.follower_count,
 197         else: 0
 198
 199     bot = user.actor_type == "Service"
 200
 201     emojis =
 202       Enum.map(user.emoji, fn {shortcode, raw_url} ->
 203         url = MediaProxy.url(raw_url)
 204
 205         %{
 206           shortcode: shortcode,
 207           url: url,
 208           static_url: url,
 209           visible_in_picker: false
 210         }
 211       end)
 212
 213     relationship =
 214       if opts[:embed_relationships] do
 215         render("relationship.json", %{
 216           user: opts[:for],
 217           target: user,
 218           relationships: opts[:relationships]
 219         })
 220       else
 221         %{}
 222       end
 223
 224     favicon =
 225       if Pleroma.Config.get([:instances_favicons, :enabled]) do
 226         user
 227         |> Map.get(:ap_id, "")
 228         |> URI.parse()
 229         |> URI.merge("/")
 230         |> Pleroma.Instances.Instance.get_or_update_favicon()
 231         |> MediaProxy.url()
 232       else
 233         nil
 234       end
 235
 236     %{
 237       id: to_string(user.id),
 238       username: username_from_nickname(user.nickname),
 239       acct: user.nickname,
 240       display_name: display_name,
 241       locked: user.is_locked,
 242       created_at: Utils.to_masto_date(user.inserted_at),
 243       followers_count: followers_count,
 244       following_count: following_count,
 245       statuses_count: user.note_count,
 246       note: user.bio,
 247       url: user.uri || user.ap_id,
 248       avatar: avatar,
 249       avatar_static: avatar_static,
 250       header: header,
 251       header_static: header_static,
 252       emojis: emojis,
 253       fields: user.fields,
 254       bot: bot,
 255       source: %{
 256         note: user.raw_bio || "",
 257         sensitive: false,
 258         fields: user.raw_fields,
 259         pleroma: %{
 260           discoverable: user.is_discoverable,
 261           actor_type: user.actor_type
 262         }
 263       },
 264
 265       # Pleroma extensions
 266       # Note: it's insecure to output :email but fully-qualified nickname may serve as safe stub
 267       fqn: User.full_nickname(user),
 268       pleroma: %{
 269         ap_id: user.ap_id,
 270         also_known_as: user.also_known_as,
 271         is_confirmed: user.is_confirmed,
 272         tags: user.tags,
 273         hide_followers_count: user.hide_followers_count,
 274         hide_follows_count: user.hide_follows_count,
 275         hide_followers: user.hide_followers,
 276         hide_follows: user.hide_follows,
 277         hide_favorites: user.hide_favorites,
 278         relationship: relationship,
 279         skip_thread_containment: user.skip_thread_containment,
 280         background_image: image_url(user.background) |> MediaProxy.url(),
 281         accepts_chat_messages: user.accepts_chat_messages,
 282         favicon: favicon
 283       }
 284     }
 285     |> maybe_put_role(user, opts[:for])
 286     |> maybe_put_settings(user, opts[:for], opts)
 287     |> maybe_put_notification_settings(user, opts[:for])
 288     |> maybe_put_settings_store(user, opts[:for], opts)
 289     |> maybe_put_chat_token(user, opts[:for], opts)
 290     |> maybe_put_activation_status(user, opts[:for])
 291     |> maybe_put_follow_requests_count(user, opts[:for])
 292     |> maybe_put_allow_following_move(user, opts[:for])
 293     |> maybe_put_unread_conversation_count(user, opts[:for])
 294     |> maybe_put_unread_notification_count(user, opts[:for])
 295     |> maybe_put_email_address(user, opts[:for])
 296   end
 297
 298   defp username_from_nickname(string) when is_binary(string) do
 299     hd(String.split(string, "@"))
 300   end
 301
 302   defp username_from_nickname(_), do: nil
 303
 304   defp maybe_put_follow_requests_count(
 305          data,
 306          %User{id: user_id} = user,
 307          %User{id: user_id}
 308        ) do
 309     count =
 310       User.get_follow_requests(user)
 311       |> length()
 312
 313     data
 314     |> Kernel.put_in([:follow_requests_count], count)
 315   end
 316
 317   defp maybe_put_follow_requests_count(data, _, _), do: data
 318
 319   defp maybe_put_settings(
 320          data,
 321          %User{id: user_id} = user,
 322          %User{id: user_id},
 323          _opts
 324        ) do
 325     data
 326     |> Kernel.put_in([:source, :privacy], user.default_scope)
 327     |> Kernel.put_in([:source, :pleroma, :show_role], user.show_role)
 328     |> Kernel.put_in([:source, :pleroma, :no_rich_text], user.no_rich_text)
 329   end
 330
 331   defp maybe_put_settings(data, _, _, _), do: data
 332
 333   defp maybe_put_settings_store(data, %User{} = user, %User{}, %{
 334          with_pleroma_settings: true
 335        }) do
 336     data
 337     |> Kernel.put_in([:pleroma, :settings_store], user.pleroma_settings_store)
 338   end
 339
 340   defp maybe_put_settings_store(data, _, _, _), do: data
 341
 342   defp maybe_put_chat_token(data, %User{id: id}, %User{id: id}, %{
 343          with_chat_token: token
 344        }) do
 345     data
 346     |> Kernel.put_in([:pleroma, :chat_token], token)
 347   end
 348
 349   defp maybe_put_chat_token(data, _, _, _), do: data
 350
 351   defp maybe_put_role(data, %User{show_role: true} = user, _) do
 352     data
 353     |> Kernel.put_in([:pleroma, :is_admin], user.is_admin)
 354     |> Kernel.put_in([:pleroma, :is_moderator], user.is_moderator)
 355   end
 356
 357   defp maybe_put_role(data, %User{id: user_id} = user, %User{id: user_id}) do
 358     data
 359     |> Kernel.put_in([:pleroma, :is_admin], user.is_admin)
 360     |> Kernel.put_in([:pleroma, :is_moderator], user.is_moderator)
 361   end
 362
 363   defp maybe_put_role(data, _, _), do: data
 364
 365   defp maybe_put_notification_settings(data, %User{id: user_id} = user, %User{id: user_id}) do
 366     Kernel.put_in(
 367       data,
 368       [:pleroma, :notification_settings],
 369       Map.from_struct(user.notification_settings)
 370     )
 371   end
 372
 373   defp maybe_put_notification_settings(data, _, _), do: data
 374
 375   defp maybe_put_allow_following_move(data, %User{id: user_id} = user, %User{id: user_id}) do
 376     Kernel.put_in(data, [:pleroma, :allow_following_move], user.allow_following_move)
 377   end
 378
 379   defp maybe_put_allow_following_move(data, _, _), do: data
 380
 381   defp maybe_put_activation_status(data, user, %User{is_admin: true}) do
 382     Kernel.put_in(data, [:pleroma, :deactivated], !user.is_active)
 383   end
 384
 385   defp maybe_put_activation_status(data, _, _), do: data
 386
 387   defp maybe_put_unread_conversation_count(data, %User{id: user_id} = user, %User{id: user_id}) do
 388     data
 389     |> Kernel.put_in(
 390       [:pleroma, :unread_conversation_count],
 391       Pleroma.Conversation.Participation.unread_count(user)
 392     )
 393   end
 394
 395   defp maybe_put_unread_conversation_count(data, _, _), do: data
 396
 397   defp maybe_put_unread_notification_count(data, %User{id: user_id}, %User{id: user_id} = user) do
 398     Kernel.put_in(
 399       data,
 400       [:pleroma, :unread_notifications_count],
 401       Pleroma.Notification.unread_notifications_count(user)
 402     )
 403   end
 404
 405   defp maybe_put_unread_notification_count(data, _, _), do: data
 406
 407   defp maybe_put_email_address(data, %User{id: user_id}, %User{id: user_id} = user) do
 408     Kernel.put_in(
 409       data,
 410       [:pleroma, :email],
 411       user.email
 412     )
 413   end
 414
 415   defp maybe_put_email_address(data, _, _), do: data
 416
 417   defp image_url(%{"url" => [%{"href" => href} | _]}), do: href
 418   defp image_url(_), do: nil
 419 end