git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/account_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.AccountView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.FollowingRelationship
   9   alias Pleroma.User
  10   alias Pleroma.UserRelationship
  11   alias Pleroma.Web.CommonAPI.Utils
  12   alias Pleroma.Web.MastodonAPI.AccountView
  13   alias Pleroma.Web.MediaProxy
  14
  15   def render("index.json", %{users: users} = opts) do
  16     opts = Map.merge(%{skip_relationships: false}, opts)
  17
  18     reading_user = opts[:for]
  19
  20     relationships_opt =
  21       cond do
  22         Map.has_key?(opts, :relationships) ->
  23           opts[:relationships]
  24
  25         is_nil(reading_user) || opts[:skip_relationships] ->
  26           UserRelationship.view_relationships_option(nil, [])
  27
  28         true ->
  29           UserRelationship.view_relationships_option(reading_user, users)
  30       end
  31
  32     opts = Map.put(opts, :relationships, relationships_opt)
  33
  34     users
  35     |> render_many(AccountView, "show.json", opts)
  36     |> Enum.filter(&Enum.any?/1)
  37   end
  38
  39   def render("show.json", %{user: user} = opts) do
  40     if User.visible_for?(user, opts[:for]),
  41       do: do_render("show.json", opts),
  42       else: %{}
  43   end
  44
  45   def render("mention.json", %{user: user}) do
  46     %{
  47       id: to_string(user.id),
  48       acct: user.nickname,
  49       username: username_from_nickname(user.nickname),
  50       url: user.uri || user.ap_id
  51     }
  52   end
  53
  54   def render("relationship.json", %{user: nil, target: _target}) do
  55     %{}
  56   end
  57
  58   def render(
  59         "relationship.json",
  60         %{user: %User{} = reading_user, target: %User{} = target} = opts
  61       ) do
  62     user_relationships = get_in(opts, [:relationships, :user_relationships])
  63     following_relationships = get_in(opts, [:relationships, :following_relationships])
  64
  65     follow_state =
  66       if following_relationships do
  67         user_to_target_following_relation =
  68           FollowingRelationship.find(following_relationships, reading_user, target)
  69
  70         User.get_follow_state(reading_user, target, user_to_target_following_relation)
  71       else
  72         User.get_follow_state(reading_user, target)
  73       end
  74
  75     followed_by =
  76       if following_relationships do
  77         case FollowingRelationship.find(following_relationships, target, reading_user) do
  78           %{state: :follow_accept} -> true
  79           _ -> false
  80         end
  81       else
  82         User.following?(target, reading_user)
  83       end
  84
  85     # NOTE: adjust UserRelationship.view_relationships_option/2 on new relation-related flags
  86     %{
  87       id: to_string(target.id),
  88       following: follow_state == :follow_accept,
  89       followed_by: followed_by,
  90       blocking:
  91         UserRelationship.exists?(
  92           user_relationships,
  93           :block,
  94           reading_user,
  95           target,
  96           &User.blocks_user?(&1, &2)
  97         ),
  98       blocked_by:
  99         UserRelationship.exists?(
 100           user_relationships,
 101           :block,
 102           target,
 103           reading_user,
 104           &User.blocks_user?(&1, &2)
 105         ),
 106       muting:
 107         UserRelationship.exists?(
 108           user_relationships,
 109           :mute,
 110           reading_user,
 111           target,
 112           &User.mutes?(&1, &2)
 113         ),
 114       muting_notifications:
 115         UserRelationship.exists?(
 116           user_relationships,
 117           :notification_mute,
 118           reading_user,
 119           target,
 120           &User.muted_notifications?(&1, &2)
 121         ),
 122       subscribing:
 123         UserRelationship.exists?(
 124           user_relationships,
 125           :inverse_subscription,
 126           target,
 127           reading_user,
 128           &User.subscribed_to?(&2, &1)
 129         ),
 130       requested: follow_state == :follow_pending,
 131       domain_blocking: User.blocks_domain?(reading_user, target),
 132       showing_reblogs:
 133         not UserRelationship.exists?(
 134           user_relationships,
 135           :reblog_mute,
 136           reading_user,
 137           target,
 138           &User.muting_reblogs?(&1, &2)
 139         ),
 140       endorsed: false
 141     }
 142   end
 143
 144   def render("relationships.json", %{user: user, targets: targets} = opts) do
 145     relationships_opt =
 146       cond do
 147         Map.has_key?(opts, :relationships) ->
 148           opts[:relationships]
 149
 150         is_nil(user) ->
 151           UserRelationship.view_relationships_option(nil, [])
 152
 153         true ->
 154           UserRelationship.view_relationships_option(user, targets)
 155       end
 156
 157     render_opts = %{as: :target, user: user, relationships: relationships_opt}
 158     render_many(targets, AccountView, "relationship.json", render_opts)
 159   end
 160
 161   defp do_render("show.json", %{user: user} = opts) do
 162     opts = Map.merge(%{skip_relationships: false}, opts)
 163
 164     user = User.sanitize_html(user, User.html_filter_policy(opts[:for]))
 165     display_name = user.name || user.nickname
 166
 167     image = User.avatar_url(user) |> MediaProxy.url()
 168     header = User.banner_url(user) |> MediaProxy.url()
 169
 170     following_count =
 171       if !user.hide_follows_count or !user.hide_follows or opts[:for] == user do
 172         user.following_count || 0
 173       else
 174         0
 175       end
 176
 177     followers_count =
 178       if !user.hide_followers_count or !user.hide_followers or opts[:for] == user do
 179         user.follower_count || 0
 180       else
 181         0
 182       end
 183
 184     bot = user.actor_type in ["Application", "Service"]
 185
 186     emojis =
 187       Enum.map(user.emoji, fn {shortcode, url} ->
 188         %{
 189           "shortcode" => shortcode,
 190           "url" => url,
 191           "static_url" => url,
 192           "visible_in_picker" => false
 193         }
 194       end)
 195
 196     relationship =
 197       if opts[:skip_relationships] do
 198         %{}
 199       else
 200         render("relationship.json", %{
 201           user: opts[:for],
 202           target: user,
 203           relationships: opts[:relationships]
 204         })
 205       end
 206
 207     %{
 208       id: to_string(user.id),
 209       username: username_from_nickname(user.nickname),
 210       acct: user.nickname,
 211       display_name: display_name,
 212       locked: user.locked,
 213       created_at: Utils.to_masto_date(user.inserted_at),
 214       followers_count: followers_count,
 215       following_count: following_count,
 216       statuses_count: user.note_count,
 217       note: user.bio || "",
 218       url: user.uri || user.ap_id,
 219       avatar: image,
 220       avatar_static: image,
 221       header: header,
 222       header_static: header,
 223       emojis: emojis,
 224       fields: user.fields,
 225       bot: bot,
 226       source: %{
 227         note: (user.bio || "") |> String.replace(~r(<br */?>), "\n") |> Pleroma.HTML.strip_tags(),
 228         sensitive: false,
 229         fields: user.raw_fields,
 230         pleroma: %{
 231           discoverable: user.discoverable,
 232           actor_type: user.actor_type
 233         }
 234       },
 235
 236       # Pleroma extension
 237       pleroma: %{
 238         confirmation_pending: user.confirmation_pending,
 239         tags: user.tags,
 240         hide_followers_count: user.hide_followers_count,
 241         hide_follows_count: user.hide_follows_count,
 242         hide_followers: user.hide_followers,
 243         hide_follows: user.hide_follows,
 244         hide_favorites: user.hide_favorites,
 245         relationship: relationship,
 246         skip_thread_containment: user.skip_thread_containment,
 247         background_image: image_url(user.background) |> MediaProxy.url()
 248       }
 249     }
 250     |> maybe_put_role(user, opts[:for])
 251     |> maybe_put_settings(user, opts[:for], opts)
 252     |> maybe_put_notification_settings(user, opts[:for])
 253     |> maybe_put_settings_store(user, opts[:for], opts)
 254     |> maybe_put_chat_token(user, opts[:for], opts)
 255     |> maybe_put_activation_status(user, opts[:for])
 256     |> maybe_put_follow_requests_count(user, opts[:for])
 257     |> maybe_put_allow_following_move(user, opts[:for])
 258     |> maybe_put_unread_conversation_count(user, opts[:for])
 259   end
 260
 261   defp username_from_nickname(string) when is_binary(string) do
 262     hd(String.split(string, "@"))
 263   end
 264
 265   defp username_from_nickname(_), do: nil
 266
 267   defp maybe_put_follow_requests_count(
 268          data,
 269          %User{id: user_id} = user,
 270          %User{id: user_id}
 271        ) do
 272     count =
 273       User.get_follow_requests(user)
 274       |> length()
 275
 276     data
 277     |> Kernel.put_in([:follow_requests_count], count)
 278   end
 279
 280   defp maybe_put_follow_requests_count(data, _, _), do: data
 281
 282   defp maybe_put_settings(
 283          data,
 284          %User{id: user_id} = user,
 285          %User{id: user_id},
 286          _opts
 287        ) do
 288     data
 289     |> Kernel.put_in([:source, :privacy], user.default_scope)
 290     |> Kernel.put_in([:source, :pleroma, :show_role], user.show_role)
 291     |> Kernel.put_in([:source, :pleroma, :no_rich_text], user.no_rich_text)
 292   end
 293
 294   defp maybe_put_settings(data, _, _, _), do: data
 295
 296   defp maybe_put_settings_store(data, %User{} = user, %User{}, %{
 297          with_pleroma_settings: true
 298        }) do
 299     data
 300     |> Kernel.put_in([:pleroma, :settings_store], user.pleroma_settings_store)
 301   end
 302
 303   defp maybe_put_settings_store(data, _, _, _), do: data
 304
 305   defp maybe_put_chat_token(data, %User{id: id}, %User{id: id}, %{
 306          with_chat_token: token
 307        }) do
 308     data
 309     |> Kernel.put_in([:pleroma, :chat_token], token)
 310   end
 311
 312   defp maybe_put_chat_token(data, _, _, _), do: data
 313
 314   defp maybe_put_role(data, %User{show_role: true} = user, _) do
 315     data
 316     |> Kernel.put_in([:pleroma, :is_admin], user.is_admin)
 317     |> Kernel.put_in([:pleroma, :is_moderator], user.is_moderator)
 318   end
 319
 320   defp maybe_put_role(data, %User{id: user_id} = user, %User{id: user_id}) do
 321     data
 322     |> Kernel.put_in([:pleroma, :is_admin], user.is_admin)
 323     |> Kernel.put_in([:pleroma, :is_moderator], user.is_moderator)
 324   end
 325
 326   defp maybe_put_role(data, _, _), do: data
 327
 328   defp maybe_put_notification_settings(data, %User{id: user_id} = user, %User{id: user_id}) do
 329     Kernel.put_in(data, [:pleroma, :notification_settings], user.notification_settings)
 330   end
 331
 332   defp maybe_put_notification_settings(data, _, _), do: data
 333
 334   defp maybe_put_allow_following_move(data, %User{id: user_id} = user, %User{id: user_id}) do
 335     Kernel.put_in(data, [:pleroma, :allow_following_move], user.allow_following_move)
 336   end
 337
 338   defp maybe_put_allow_following_move(data, _, _), do: data
 339
 340   defp maybe_put_activation_status(data, user, %User{is_admin: true}) do
 341     Kernel.put_in(data, [:pleroma, :deactivated], user.deactivated)
 342   end
 343
 344   defp maybe_put_activation_status(data, _, _), do: data
 345
 346   defp maybe_put_unread_conversation_count(data, %User{id: user_id} = user, %User{id: user_id}) do
 347     data
 348     |> Kernel.put_in(
 349       [:pleroma, :unread_conversation_count],
 350       user.unread_conversation_count
 351     )
 352   end
 353
 354   defp maybe_put_unread_conversation_count(data, _, _), do: data
 355
 356   defp image_url(%{"url" => [%{"href" => href} | _]}), do: href
 357   defp image_url(_), do: nil
 358 end