git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/account_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.AccountView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.FollowingRelationship
   9   alias Pleroma.User
  10   alias Pleroma.UserNote
  11   alias Pleroma.UserRelationship
  12   alias Pleroma.Web.CommonAPI.Utils
  13   alias Pleroma.Web.MastodonAPI.AccountView
  14   alias Pleroma.Web.MediaProxy
  15
  16   def render("index.json", %{users: users} = opts) do
  17     reading_user = opts[:for]
  18
  19     relationships_opt =
  20       cond do
  21         Map.has_key?(opts, :relationships) ->
  22           opts[:relationships]
  23
  24         is_nil(reading_user) || !opts[:embed_relationships] ->
  25           UserRelationship.view_relationships_option(nil, [])
  26
  27         true ->
  28           UserRelationship.view_relationships_option(reading_user, users)
  29       end
  30
  31     opts =
  32       opts
  33       |> Map.merge(%{relationships: relationships_opt, as: :user})
  34       |> Map.delete(:users)
  35
  36     users
  37     |> render_many(AccountView, "show.json", opts)
  38     |> Enum.filter(&Enum.any?/1)
  39   end
  40
  41   @doc """
  42   Renders specified user account.
  43     :skip_visibility_check option skips visibility check and renders any user (local or remote)
  44       regardless of [:pleroma, :restrict_unauthenticated] setting.
  45     :for option specifies the requester and can be a User record or nil.
  46       Only use `user: user, for: user` when `user` is the actual requester of own profile.
  47   """
  48   def render("show.json", %{user: _user, skip_visibility_check: true} = opts) do
  49     do_render("show.json", opts)
  50   end
  51
  52   def render("show.json", %{user: user, for: for_user_or_nil} = opts) do
  53     if User.visible_for(user, for_user_or_nil) == :visible do
  54       do_render("show.json", opts)
  55     else
  56       %{}
  57     end
  58   end
  59
  60   def render("show.json", _) do
  61     raise "In order to prevent account accessibility issues, " <>
  62             ":skip_visibility_check or :for option is required."
  63   end
  64
  65   def render("mention.json", %{user: user}) do
  66     %{
  67       id: to_string(user.id),
  68       acct: user.nickname,
  69       username: username_from_nickname(user.nickname),
  70       url: user.uri || user.ap_id
  71     }
  72   end
  73
  74   def render("relationship.json", %{user: nil, target: _target}) do
  75     %{}
  76   end
  77
  78   def render(
  79         "relationship.json",
  80         %{user: %User{} = reading_user, target: %User{} = target} = opts
  81       ) do
  82     user_relationships = get_in(opts, [:relationships, :user_relationships])
  83     following_relationships = get_in(opts, [:relationships, :following_relationships])
  84
  85     follow_state =
  86       if following_relationships do
  87         user_to_target_following_relation =
  88           FollowingRelationship.find(following_relationships, reading_user, target)
  89
  90         User.get_follow_state(reading_user, target, user_to_target_following_relation)
  91       else
  92         User.get_follow_state(reading_user, target)
  93       end
  94
  95     followed_by =
  96       if following_relationships do
  97         case FollowingRelationship.find(following_relationships, target, reading_user) do
  98           %{state: :follow_accept} -> true
  99           _ -> false
 100         end
 101       else
 102         User.following?(target, reading_user)
 103       end
 104
 105     subscribing =
 106       UserRelationship.exists?(
 107         user_relationships,
 108         :inverse_subscription,
 109         target,
 110         reading_user,
 111         &User.subscribed_to?(&2, &1)
 112       )
 113
 114     # NOTE: adjust UserRelationship.view_relationships_option/2 on new relation-related flags
 115     %{
 116       id: to_string(target.id),
 117       following: follow_state == :follow_accept,
 118       followed_by: followed_by,
 119       blocking:
 120         UserRelationship.exists?(
 121           user_relationships,
 122           :block,
 123           reading_user,
 124           target,
 125           &User.blocks_user?(&1, &2)
 126         ),
 127       blocked_by:
 128         UserRelationship.exists?(
 129           user_relationships,
 130           :block,
 131           target,
 132           reading_user,
 133           &User.blocks_user?(&1, &2)
 134         ),
 135       muting:
 136         UserRelationship.exists?(
 137           user_relationships,
 138           :mute,
 139           reading_user,
 140           target,
 141           &User.mutes?(&1, &2)
 142         ),
 143       muting_notifications:
 144         UserRelationship.exists?(
 145           user_relationships,
 146           :notification_mute,
 147           reading_user,
 148           target,
 149           &User.muted_notifications?(&1, &2)
 150         ),
 151       subscribing: subscribing,
 152       notifying: subscribing,
 153       requested: follow_state == :follow_pending,
 154       domain_blocking: User.blocks_domain?(reading_user, target),
 155       showing_reblogs:
 156         not UserRelationship.exists?(
 157           user_relationships,
 158           :reblog_mute,
 159           reading_user,
 160           target,
 161           &User.muting_reblogs?(&1, &2)
 162         ),
 163       endorsed: false,
 164       note:
 165         UserNote.show(
 166           reading_user,
 167           target
 168         )
 169     }
 170   end
 171
 172   def render("relationships.json", %{user: user, targets: targets} = opts) do
 173     relationships_opt =
 174       cond do
 175         Map.has_key?(opts, :relationships) ->
 176           opts[:relationships]
 177
 178         is_nil(user) ->
 179           UserRelationship.view_relationships_option(nil, [])
 180
 181         true ->
 182           UserRelationship.view_relationships_option(user, targets)
 183       end
 184
 185     render_opts = %{as: :target, user: user, relationships: relationships_opt}
 186     render_many(targets, AccountView, "relationship.json", render_opts)
 187   end
 188
 189   defp do_render("show.json", %{user: user} = opts) do
 190     user = User.sanitize_html(user, User.html_filter_policy(opts[:for]))
 191     display_name = user.name || user.nickname
 192
 193     avatar = User.avatar_url(user) |> MediaProxy.url()
 194     avatar_static = User.avatar_url(user) |> MediaProxy.preview_url(static: true)
 195     header = User.banner_url(user) |> MediaProxy.url()
 196     header_static = User.banner_url(user) |> MediaProxy.preview_url(static: true)
 197
 198     following_count =
 199       if !user.hide_follows_count or !user.hide_follows or opts[:for] == user,
 200         do: user.following_count,
 201         else: 0
 202
 203     followers_count =
 204       if !user.hide_followers_count or !user.hide_followers or opts[:for] == user,
 205         do: user.follower_count,
 206         else: 0
 207
 208     bot = user.actor_type == "Service"
 209
 210     emojis =
 211       Enum.map(user.emoji, fn {shortcode, raw_url} ->
 212         url = MediaProxy.url(raw_url)
 213
 214         %{
 215           shortcode: shortcode,
 216           url: url,
 217           static_url: url,
 218           visible_in_picker: false
 219         }
 220       end)
 221
 222     relationship =
 223       if opts[:embed_relationships] do
 224         render("relationship.json", %{
 225           user: opts[:for],
 226           target: user,
 227           relationships: opts[:relationships]
 228         })
 229       else
 230         %{}
 231       end
 232
 233     favicon =
 234       if Pleroma.Config.get([:instances_favicons, :enabled]) do
 235         user
 236         |> Map.get(:ap_id, "")
 237         |> URI.parse()
 238         |> URI.merge("/")
 239         |> Pleroma.Instances.Instance.get_or_update_favicon()
 240         |> MediaProxy.url()
 241       else
 242         nil
 243       end
 244
 245     %{
 246       id: to_string(user.id),
 247       username: username_from_nickname(user.nickname),
 248       acct: user.nickname,
 249       display_name: display_name,
 250       locked: user.is_locked,
 251       created_at: Utils.to_masto_date(user.inserted_at),
 252       followers_count: followers_count,
 253       following_count: following_count,
 254       statuses_count: user.note_count,
 255       note: user.bio,
 256       url: user.uri || user.ap_id,
 257       avatar: avatar,
 258       avatar_static: avatar_static,
 259       header: header,
 260       header_static: header_static,
 261       emojis: emojis,
 262       fields: user.fields,
 263       bot: bot,
 264       source: %{
 265         note: user.raw_bio || "",
 266         sensitive: false,
 267         fields: user.raw_fields,
 268         pleroma: %{
 269           discoverable: user.is_discoverable,
 270           actor_type: user.actor_type
 271         }
 272       },
 273       last_status_at: user.last_status_at,
 274
 275       # Pleroma extensions
 276       # Note: it's insecure to output :email but fully-qualified nickname may serve as safe stub
 277       fqn: User.full_nickname(user),
 278       pleroma: %{
 279         ap_id: user.ap_id,
 280         also_known_as: user.also_known_as,
 281         is_confirmed: user.is_confirmed,
 282         is_suggested: user.is_suggested,
 283         tags: user.tags,
 284         hide_followers_count: user.hide_followers_count,
 285         hide_follows_count: user.hide_follows_count,
 286         hide_followers: user.hide_followers,
 287         hide_follows: user.hide_follows,
 288         hide_favorites: user.hide_favorites,
 289         relationship: relationship,
 290         skip_thread_containment: user.skip_thread_containment,
 291         background_image: image_url(user.background) |> MediaProxy.url(),
 292         accepts_chat_messages: user.accepts_chat_messages,
 293         favicon: favicon
 294       }
 295     }
 296     |> maybe_put_role(user, opts[:for])
 297     |> maybe_put_settings(user, opts[:for], opts)
 298     |> maybe_put_notification_settings(user, opts[:for])
 299     |> maybe_put_settings_store(user, opts[:for], opts)
 300     |> maybe_put_chat_token(user, opts[:for], opts)
 301     |> maybe_put_activation_status(user, opts[:for])
 302     |> maybe_put_follow_requests_count(user, opts[:for])
 303     |> maybe_put_allow_following_move(user, opts[:for])
 304     |> maybe_put_unread_conversation_count(user, opts[:for])
 305     |> maybe_put_unread_notification_count(user, opts[:for])
 306     |> maybe_put_email_address(user, opts[:for])
 307   end
 308
 309   defp username_from_nickname(string) when is_binary(string) do
 310     hd(String.split(string, "@"))
 311   end
 312
 313   defp username_from_nickname(_), do: nil
 314
 315   defp maybe_put_follow_requests_count(
 316          data,
 317          %User{id: user_id} = user,
 318          %User{id: user_id}
 319        ) do
 320     count =
 321       User.get_follow_requests(user)
 322       |> length()
 323
 324     data
 325     |> Kernel.put_in([:follow_requests_count], count)
 326   end
 327
 328   defp maybe_put_follow_requests_count(data, _, _), do: data
 329
 330   defp maybe_put_settings(
 331          data,
 332          %User{id: user_id} = user,
 333          %User{id: user_id},
 334          _opts
 335        ) do
 336     data
 337     |> Kernel.put_in([:source, :privacy], user.default_scope)
 338     |> Kernel.put_in([:source, :pleroma, :show_role], user.show_role)
 339     |> Kernel.put_in([:source, :pleroma, :no_rich_text], user.no_rich_text)
 340   end
 341
 342   defp maybe_put_settings(data, _, _, _), do: data
 343
 344   defp maybe_put_settings_store(data, %User{} = user, %User{}, %{
 345          with_pleroma_settings: true
 346        }) do
 347     data
 348     |> Kernel.put_in([:pleroma, :settings_store], user.pleroma_settings_store)
 349   end
 350
 351   defp maybe_put_settings_store(data, _, _, _), do: data
 352
 353   defp maybe_put_chat_token(data, %User{id: id}, %User{id: id}, %{
 354          with_chat_token: token
 355        }) do
 356     data
 357     |> Kernel.put_in([:pleroma, :chat_token], token)
 358   end
 359
 360   defp maybe_put_chat_token(data, _, _, _), do: data
 361
 362   defp maybe_put_role(data, %User{show_role: true} = user, _) do
 363     data
 364     |> Kernel.put_in([:pleroma, :is_admin], user.is_admin)
 365     |> Kernel.put_in([:pleroma, :is_moderator], user.is_moderator)
 366   end
 367
 368   defp maybe_put_role(data, %User{id: user_id} = user, %User{id: user_id}) do
 369     data
 370     |> Kernel.put_in([:pleroma, :is_admin], user.is_admin)
 371     |> Kernel.put_in([:pleroma, :is_moderator], user.is_moderator)
 372   end
 373
 374   defp maybe_put_role(data, _, _), do: data
 375
 376   defp maybe_put_notification_settings(data, %User{id: user_id} = user, %User{id: user_id}) do
 377     Kernel.put_in(
 378       data,
 379       [:pleroma, :notification_settings],
 380       Map.from_struct(user.notification_settings)
 381     )
 382   end
 383
 384   defp maybe_put_notification_settings(data, _, _), do: data
 385
 386   defp maybe_put_allow_following_move(data, %User{id: user_id} = user, %User{id: user_id}) do
 387     Kernel.put_in(data, [:pleroma, :allow_following_move], user.allow_following_move)
 388   end
 389
 390   defp maybe_put_allow_following_move(data, _, _), do: data
 391
 392   defp maybe_put_activation_status(data, user, %User{is_admin: true}) do
 393     Kernel.put_in(data, [:pleroma, :deactivated], !user.is_active)
 394   end
 395
 396   defp maybe_put_activation_status(data, _, _), do: data
 397
 398   defp maybe_put_unread_conversation_count(data, %User{id: user_id} = user, %User{id: user_id}) do
 399     data
 400     |> Kernel.put_in(
 401       [:pleroma, :unread_conversation_count],
 402       Pleroma.Conversation.Participation.unread_count(user)
 403     )
 404   end
 405
 406   defp maybe_put_unread_conversation_count(data, _, _), do: data
 407
 408   defp maybe_put_unread_notification_count(data, %User{id: user_id}, %User{id: user_id} = user) do
 409     Kernel.put_in(
 410       data,
 411       [:pleroma, :unread_notifications_count],
 412       Pleroma.Notification.unread_notifications_count(user)
 413     )
 414   end
 415
 416   defp maybe_put_unread_notification_count(data, _, _), do: data
 417
 418   defp maybe_put_email_address(data, %User{id: user_id}, %User{id: user_id} = user) do
 419     Kernel.put_in(
 420       data,
 421       [:pleroma, :email],
 422       user.email
 423     )
 424   end
 425
 426   defp maybe_put_email_address(data, _, _), do: data
 427
 428   defp image_url(%{"url" => [%{"href" => href} | _]}), do: href
 429   defp image_url(_), do: nil
 430 end