git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/mastodon_api.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.MastodonAPI do
   6   import Ecto.Query
   7   import Ecto.Changeset
   8
   9   alias Pleroma.Notification
  10   alias Pleroma.Pagination
  11   alias Pleroma.ScheduledActivity
  12   alias Pleroma.User
  13   alias Pleroma.Web.CommonAPI
  14
  15   @spec follow(User.t(), User.t(), map) :: {:ok, User.t()} | {:error, String.t()}
  16   def follow(follower, followed, params \\ %{}) do
  17     result =
  18       if not User.following?(follower, followed) do
  19         CommonAPI.follow(follower, followed)
  20       else
  21         {:ok, follower, followed, nil}
  22       end
  23
  24     with {:ok, follower, _followed, _} <- result do
  25       options = cast_params(params)
  26       set_reblogs_visibility(options[:reblogs], result)
  27       {:ok, follower}
  28     end
  29   end
  30
  31   defp set_reblogs_visibility(false, {:ok, follower, followed, _}) do
  32     CommonAPI.hide_reblogs(follower, followed)
  33   end
  34
  35   defp set_reblogs_visibility(_, {:ok, follower, followed, _}) do
  36     CommonAPI.show_reblogs(follower, followed)
  37   end
  38
  39   @spec get_followers(User.t(), map()) :: list(User.t())
  40   def get_followers(user, params \\ %{}) do
  41     user
  42     |> User.get_followers_query()
  43     |> Pagination.fetch_paginated(params)
  44   end
  45
  46   def get_friends(user, params \\ %{}) do
  47     user
  48     |> User.get_friends_query()
  49     |> Pagination.fetch_paginated(params)
  50   end
  51
  52   def get_notifications(user, params \\ %{}) do
  53     options = cast_params(params)
  54
  55     user
  56     |> Notification.for_user_query(options)
  57     |> restrict(:include_types, options)
  58     |> restrict(:exclude_types, options)
  59     |> restrict(:account_ap_id, options)
  60     |> Pagination.fetch_paginated(params)
  61   end
  62
  63   def get_scheduled_activities(user, params \\ %{}) do
  64     user
  65     |> ScheduledActivity.for_user_query()
  66     |> Pagination.fetch_paginated(params)
  67   end
  68
  69   defp cast_params(params) do
  70     param_types = %{
  71       exclude_types: {:array, :string},
  72       include_types: {:array, :string},
  73       exclude_visibilities: {:array, :string},
  74       reblogs: :boolean,
  75       with_muted: :boolean,
  76       account_ap_id: :string
  77     }
  78
  79     changeset = cast({%{}, param_types}, params, Map.keys(param_types))
  80     changeset.changes
  81   end
  82
  83   defp restrict(query, :include_types, %{include_types: mastodon_types = [_ | _]}) do
  84     where(query, [n], n.type in ^mastodon_types)
  85   end
  86
  87   defp restrict(query, :exclude_types, %{exclude_types: mastodon_types = [_ | _]}) do
  88     where(query, [n], n.type not in ^mastodon_types)
  89   end
  90
  91   defp restrict(query, :account_ap_id, %{account_ap_id: account_ap_id}) do
  92     where(query, [n, a], a.actor == ^account_ap_id)
  93   end
  94
  95   defp restrict(query, _, _), do: query
  96 end