git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/mastodon_api.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.MastodonAPI do
   6   import Ecto.Query
   7   import Ecto.Changeset
   8
   9   alias Pleroma.Activity
  10   alias Pleroma.Notification
  11   alias Pleroma.Pagination
  12   alias Pleroma.ScheduledActivity
  13   alias Pleroma.SubscriptionNotification
  14   alias Pleroma.User
  15   alias Pleroma.Web.CommonAPI
  16
  17   @spec follow(User.t(), User.t(), map) :: {:ok, User.t()} | {:error, String.t()}
  18   def follow(follower, followed, params \\ %{}) do
  19     result =
  20       if not User.following?(follower, followed) do
  21         CommonAPI.follow(follower, followed)
  22       else
  23         {:ok, follower, followed, nil}
  24       end
  25
  26     with {:ok, follower, _followed, _} <- result do
  27       options = cast_params(params)
  28
  29       case reblogs_visibility(options[:reblogs], result) do
  30         {:ok, follower} -> {:ok, follower}
  31         _ -> {:ok, follower}
  32       end
  33     end
  34   end
  35
  36   defp reblogs_visibility(false, {:ok, follower, followed, _}) do
  37     CommonAPI.hide_reblogs(follower, followed)
  38   end
  39
  40   defp reblogs_visibility(_, {:ok, follower, followed, _}) do
  41     CommonAPI.show_reblogs(follower, followed)
  42   end
  43
  44   @spec get_followers(User.t(), map()) :: list(User.t())
  45   def get_followers(user, params \\ %{}) do
  46     user
  47     |> User.get_followers_query()
  48     |> Pagination.fetch_paginated(params)
  49   end
  50
  51   def get_friends(user, params \\ %{}) do
  52     user
  53     |> User.get_friends_query()
  54     |> Pagination.fetch_paginated(params)
  55   end
  56
  57   def get_notifications(user, params \\ %{}) do
  58     options = cast_params(params)
  59
  60     user
  61     |> Notification.for_user_query(options)
  62     |> restrict(:exclude_types, options)
  63     |> Pagination.fetch_paginated(params)
  64   end
  65
  66   def get_subscription_notifications(user, params \\ %{}) do
  67     options = cast_params(params)
  68
  69     user
  70     |> SubscriptionNotification.for_user_query(options)
  71     |> restrict(:exclude_types, options)
  72     |> Pagination.fetch_paginated(params)
  73   end
  74
  75   def get_scheduled_activities(user, params \\ %{}) do
  76     user
  77     |> ScheduledActivity.for_user_query()
  78     |> Pagination.fetch_paginated(params)
  79   end
  80
  81   defp cast_params(params) do
  82     param_types = %{
  83       exclude_types: {:array, :string},
  84       reblogs: :boolean,
  85       with_muted: :boolean
  86     }
  87
  88     changeset = cast({%{}, param_types}, params, Map.keys(param_types))
  89     changeset.changes
  90   end
  91
  92   defp restrict(query, :exclude_types, %{exclude_types: mastodon_types = [_ | _]}) do
  93     ap_types =
  94       mastodon_types
  95       |> Enum.map(&Activity.from_mastodon_notification_type/1)
  96       |> Enum.filter(& &1)
  97
  98     query
  99     |> where([q, a], not fragment("? @> ARRAY[?->>'type']::varchar[]", ^ap_types, a.data))
 100   end
 101
 102   defp restrict(query, _, _), do: query
 103 end