git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/controllers/timeline_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.TimelineController do
   6   use Pleroma.Web, :controller
   7
   8   import Pleroma.Web.ControllerHelper,
   9     only: [add_link_headers: 2, add_link_headers: 3, truthy_param?: 1]
  10
  11   alias Pleroma.Pagination
  12   alias Pleroma.Plugs.OAuthScopesPlug
  13   alias Pleroma.User
  14   alias Pleroma.Web.ActivityPub.ActivityPub
  15
  16   plug(OAuthScopesPlug, %{scopes: ["read:statuses"]} when action in [:home, :direct])
  17   plug(OAuthScopesPlug, %{scopes: ["read:lists"]} when action == :list)
  18
  19   plug(Pleroma.Plugs.EnsurePublicOrAuthenticatedPlug)
  20
  21   plug(:put_view, Pleroma.Web.MastodonAPI.StatusView)
  22
  23   # GET /api/v1/timelines/home
  24   def home(%{assigns: %{user: user}} = conn, params) do
  25     params =
  26       params
  27       |> Map.put("type", ["Create", "Announce"])
  28       |> Map.put("blocking_user", user)
  29       |> Map.put("muting_user", user)
  30       |> Map.put("user", user)
  31
  32     recipients = [user.ap_id | User.following(user)]
  33
  34     activities =
  35       recipients
  36       |> ActivityPub.fetch_activities(params)
  37       |> Enum.reverse()
  38
  39     conn
  40     |> add_link_headers(activities)
  41     |> render("index.json", activities: activities, for: user, as: :activity)
  42   end
  43
  44   # GET /api/v1/timelines/direct
  45   def direct(%{assigns: %{user: user}} = conn, params) do
  46     params =
  47       params
  48       |> Map.put("type", "Create")
  49       |> Map.put("blocking_user", user)
  50       |> Map.put("user", user)
  51       |> Map.put(:visibility, "direct")
  52
  53     activities =
  54       [user.ap_id]
  55       |> ActivityPub.fetch_activities_query(params)
  56       |> Pagination.fetch_paginated(params)
  57
  58     conn
  59     |> add_link_headers(activities)
  60     |> render("index.json", activities: activities, for: user, as: :activity)
  61   end
  62
  63   # GET /api/v1/timelines/public
  64   def public(%{assigns: %{user: user}} = conn, params) do
  65     local_only = truthy_param?(params["local"])
  66
  67     activities =
  68       params
  69       |> Map.put("type", ["Create", "Announce"])
  70       |> Map.put("local_only", local_only)
  71       |> Map.put("blocking_user", user)
  72       |> Map.put("muting_user", user)
  73       |> ActivityPub.fetch_public_activities()
  74
  75     conn
  76     |> add_link_headers(activities, %{"local" => local_only})
  77     |> render("index.json", activities: activities, for: user, as: :activity)
  78   end
  79
  80   def hashtag_fetching(params, user, local_only) do
  81     tags =
  82       [params["tag"], params["any"]]
  83       |> List.flatten()
  84       |> Enum.uniq()
  85       |> Enum.filter(& &1)
  86       |> Enum.map(&String.downcase(&1))
  87
  88     tag_all =
  89       params
  90       |> Map.get("all", [])
  91       |> Enum.map(&String.downcase(&1))
  92
  93     tag_reject =
  94       params
  95       |> Map.get("none", [])
  96       |> Enum.map(&String.downcase(&1))
  97
  98     _activities =
  99       params
 100       |> Map.put("type", "Create")
 101       |> Map.put("local_only", local_only)
 102       |> Map.put("blocking_user", user)
 103       |> Map.put("muting_user", user)
 104       |> Map.put("user", user)
 105       |> Map.put("tag", tags)
 106       |> Map.put("tag_all", tag_all)
 107       |> Map.put("tag_reject", tag_reject)
 108       |> ActivityPub.fetch_public_activities()
 109   end
 110
 111   # GET /api/v1/timelines/tag/:tag
 112   def hashtag(%{assigns: %{user: user}} = conn, params) do
 113     local_only = truthy_param?(params["local"])
 114
 115     activities = hashtag_fetching(params, user, local_only)
 116
 117     conn
 118     |> add_link_headers(activities, %{"local" => local_only})
 119     |> render("index.json", activities: activities, for: user, as: :activity)
 120   end
 121
 122   # GET /api/v1/timelines/list/:list_id
 123   def list(%{assigns: %{user: user}} = conn, %{"list_id" => id} = params) do
 124     with %Pleroma.List{title: _title, following: following} <- Pleroma.List.get(id, user) do
 125       params =
 126         params
 127         |> Map.put("type", "Create")
 128         |> Map.put("blocking_user", user)
 129         |> Map.put("user", user)
 130         |> Map.put("muting_user", user)
 131
 132       # we must filter the following list for the user to avoid leaking statuses the user
 133       # does not actually have permission to see (for more info, peruse security issue #270).
 134
 135       user_following = User.following(user)
 136
 137       activities =
 138         following
 139         |> Enum.filter(fn x -> x in user_following end)
 140         |> ActivityPub.fetch_activities_bounded(following, params)
 141         |> Enum.reverse()
 142
 143       render(conn, "index.json", activities: activities, for: user, as: :activity)
 144     else
 145       _e -> render_error(conn, :forbidden, "Error.")
 146     end
 147   end
 148 end