git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/controllers/timeline_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.TimelineController do
   6   use Pleroma.Web, :controller
   7
   8   import Pleroma.Web.ControllerHelper,
   9     only: [add_link_headers: 2, add_link_headers: 3, truthy_param?: 1, skip_relationships?: 1]
  10
  11   alias Pleroma.Pagination
  12   alias Pleroma.Plugs.OAuthScopesPlug
  13   alias Pleroma.Plugs.RateLimiter
  14   alias Pleroma.User
  15   alias Pleroma.Web.ActivityPub.ActivityPub
  16
  17   # TODO: Replace with a macro when there is a Phoenix release with the following commit in it:
  18   # https://github.com/phoenixframework/phoenix/commit/2e8c63c01fec4dde5467dbbbf9705ff9e780735e
  19
  20   plug(RateLimiter, [name: :timeline, bucket_name: :direct_timeline] when action == :direct)
  21   plug(RateLimiter, [name: :timeline, bucket_name: :public_timeline] when action == :public)
  22   plug(RateLimiter, [name: :timeline, bucket_name: :home_timeline] when action == :home)
  23   plug(RateLimiter, [name: :timeline, bucket_name: :hashtag_timeline] when action == :hashtag)
  24   plug(RateLimiter, [name: :timeline, bucket_name: :list_timeline] when action == :list)
  25
  26   plug(OAuthScopesPlug, %{scopes: ["read:statuses"]} when action in [:home, :direct])
  27   plug(OAuthScopesPlug, %{scopes: ["read:lists"]} when action == :list)
  28
  29   plug(Pleroma.Plugs.EnsurePublicOrAuthenticatedPlug when action != :public)
  30
  31   plug(:put_view, Pleroma.Web.MastodonAPI.StatusView)
  32
  33   # GET /api/v1/timelines/home
  34   def home(%{assigns: %{user: user}} = conn, params) do
  35     params =
  36       params
  37       |> Map.put("type", ["Create", "Announce"])
  38       |> Map.put("blocking_user", user)
  39       |> Map.put("muting_user", user)
  40       |> Map.put("reply_filtering_user", user)
  41       |> Map.put("user", user)
  42
  43     recipients = [user.ap_id | User.following(user)]
  44
  45     activities =
  46       recipients
  47       |> ActivityPub.fetch_activities(params)
  48       |> Enum.reverse()
  49
  50     conn
  51     |> add_link_headers(activities)
  52     |> render("index.json",
  53       activities: activities,
  54       for: user,
  55       as: :activity,
  56       skip_relationships: skip_relationships?(params)
  57     )
  58   end
  59
  60   # GET /api/v1/timelines/direct
  61   def direct(%{assigns: %{user: user}} = conn, params) do
  62     params =
  63       params
  64       |> Map.put("type", "Create")
  65       |> Map.put("blocking_user", user)
  66       |> Map.put("user", user)
  67       |> Map.put(:visibility, "direct")
  68
  69     activities =
  70       [user.ap_id]
  71       |> ActivityPub.fetch_activities_query(params)
  72       |> Pagination.fetch_paginated(params)
  73
  74     conn
  75     |> add_link_headers(activities)
  76     |> render("index.json",
  77       activities: activities,
  78       for: user,
  79       as: :activity,
  80       skip_relationships: skip_relationships?(params)
  81     )
  82   end
  83
  84   # GET /api/v1/timelines/public
  85   def public(%{assigns: %{user: user}} = conn, params) do
  86     local_only = truthy_param?(params["local"])
  87
  88     cfg_key =
  89       if local_only do
  90         :local
  91       else
  92         :federated
  93       end
  94
  95     restrict? = Pleroma.Config.get([:restrict_unauthenticated, :timelines, cfg_key])
  96
  97     if not (restrict? and is_nil(user)) do
  98       activities =
  99         params
 100         |> Map.put("type", ["Create", "Announce"])
 101         |> Map.put("local_only", local_only)
 102         |> Map.put("blocking_user", user)
 103         |> Map.put("muting_user", user)
 104         |> Map.put("reply_filtering_user", user)
 105         |> ActivityPub.fetch_public_activities()
 106
 107       conn
 108       |> add_link_headers(activities, %{"local" => local_only})
 109       |> render("index.json",
 110         activities: activities,
 111         for: user,
 112         as: :activity,
 113         skip_relationships: skip_relationships?(params)
 114       )
 115     else
 116       render_error(conn, :unauthorized, "authorization required for timeline view")
 117     end
 118   end
 119
 120   def hashtag_fetching(params, user, local_only) do
 121     tags =
 122       [params["tag"], params["any"]]
 123       |> List.flatten()
 124       |> Enum.uniq()
 125       |> Enum.filter(& &1)
 126       |> Enum.map(&String.downcase(&1))
 127
 128     tag_all =
 129       params
 130       |> Map.get("all", [])
 131       |> Enum.map(&String.downcase(&1))
 132
 133     tag_reject =
 134       params
 135       |> Map.get("none", [])
 136       |> Enum.map(&String.downcase(&1))
 137
 138     _activities =
 139       params
 140       |> Map.put("type", "Create")
 141       |> Map.put("local_only", local_only)
 142       |> Map.put("blocking_user", user)
 143       |> Map.put("muting_user", user)
 144       |> Map.put("user", user)
 145       |> Map.put("tag", tags)
 146       |> Map.put("tag_all", tag_all)
 147       |> Map.put("tag_reject", tag_reject)
 148       |> ActivityPub.fetch_public_activities()
 149   end
 150
 151   # GET /api/v1/timelines/tag/:tag
 152   def hashtag(%{assigns: %{user: user}} = conn, params) do
 153     local_only = truthy_param?(params["local"])
 154
 155     activities = hashtag_fetching(params, user, local_only)
 156
 157     conn
 158     |> add_link_headers(activities, %{"local" => local_only})
 159     |> render("index.json",
 160       activities: activities,
 161       for: user,
 162       as: :activity,
 163       skip_relationships: skip_relationships?(params)
 164     )
 165   end
 166
 167   # GET /api/v1/timelines/list/:list_id
 168   def list(%{assigns: %{user: user}} = conn, %{"list_id" => id} = params) do
 169     with %Pleroma.List{title: _title, following: following} <- Pleroma.List.get(id, user) do
 170       params =
 171         params
 172         |> Map.put("type", "Create")
 173         |> Map.put("blocking_user", user)
 174         |> Map.put("user", user)
 175         |> Map.put("muting_user", user)
 176
 177       # we must filter the following list for the user to avoid leaking statuses the user
 178       # does not actually have permission to see (for more info, peruse security issue #270).
 179
 180       user_following = User.following(user)
 181
 182       activities =
 183         following
 184         |> Enum.filter(fn x -> x in user_following end)
 185         |> ActivityPub.fetch_activities_bounded(following, params)
 186         |> Enum.reverse()
 187
 188       render(conn, "index.json",
 189         activities: activities,
 190         for: user,
 191         as: :activity,
 192         skip_relationships: skip_relationships?(params)
 193       )
 194     else
 195       _e -> render_error(conn, :forbidden, "Error.")
 196     end
 197   end
 198 end