git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/controllers/timeline_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.TimelineController do
   6   use Pleroma.Web, :controller
   7
   8   import Pleroma.Web.ControllerHelper,
   9     only: [add_link_headers: 2, add_link_headers: 3, truthy_param?: 1]
  10
  11   alias Pleroma.Pagination
  12   alias Pleroma.Plugs.OAuthScopesPlug
  13   alias Pleroma.User
  14   alias Pleroma.Web.ActivityPub.ActivityPub
  15
  16   plug(OAuthScopesPlug, %{scopes: ["read:statuses"]} when action in [:home, :direct])
  17   plug(OAuthScopesPlug, %{scopes: ["read:lists"]} when action == :list)
  18
  19   plug(Pleroma.Plugs.EnsurePublicOrAuthenticatedPlug)
  20
  21   plug(:put_view, Pleroma.Web.MastodonAPI.StatusView)
  22
  23   # GET /api/v1/timelines/home
  24   def home(%{assigns: %{user: user}} = conn, params) do
  25     params =
  26       params
  27       |> Map.put("type", ["Create", "Announce"])
  28       |> Map.put("blocking_user", user)
  29       |> Map.put("muting_user", user)
  30       |> Map.put("user", user)
  31
  32     recipients = [user.ap_id | User.following(user)]
  33
  34     activities =
  35       recipients
  36       |> ActivityPub.fetch_activities(params)
  37       |> Enum.reverse()
  38
  39     conn
  40     |> add_link_headers(activities)
  41     |> render("index.json", activities: activities, for: user, as: :activity)
  42   end
  43
  44   # GET /api/v1/timelines/direct
  45   def direct(%{assigns: %{user: user}} = conn, params) do
  46     params =
  47       params
  48       |> Map.put("type", "Create")
  49       |> Map.put("blocking_user", user)
  50       |> Map.put("user", user)
  51       |> Map.put(:visibility, "direct")
  52
  53     activities =
  54       [user.ap_id]
  55       |> ActivityPub.fetch_activities_query(params)
  56       |> Pagination.fetch_paginated(params)
  57
  58     conn
  59     |> add_link_headers(activities)
  60     |> render("index.json", activities: activities, for: user, as: :activity)
  61   end
  62
  63   # GET /api/v1/timelines/public
  64   def public(%{assigns: %{user: user}} = conn, params) do
  65     local_only = truthy_param?(params["local"])
  66
  67     activities =
  68       params
  69       |> Map.put("type", ["Create", "Announce"])
  70       |> Map.put("local_only", local_only)
  71       |> Map.put("blocking_user", user)
  72       |> Map.put("muting_user", user)
  73       |> ActivityPub.fetch_public_activities()
  74
  75     conn
  76     |> add_link_headers(activities, %{"local" => local_only})
  77     |> render("index.json", activities: activities, for: user, as: :activity)
  78   end
  79
  80   # GET /api/v1/timelines/tag/:tag
  81   def hashtag(%{assigns: %{user: user}} = conn, params) do
  82     local_only = truthy_param?(params["local"])
  83
  84     tags =
  85       [params["tag"], params["any"]]
  86       |> List.flatten()
  87       |> Enum.uniq()
  88       |> Enum.filter(& &1)
  89       |> Enum.map(&String.downcase(&1))
  90
  91     tag_all =
  92       params
  93       |> Map.get("all", [])
  94       |> Enum.map(&String.downcase(&1))
  95
  96     tag_reject =
  97       params
  98       |> Map.get("none", [])
  99       |> Enum.map(&String.downcase(&1))
 100
 101     activities =
 102       params
 103       |> Map.put("type", "Create")
 104       |> Map.put("local_only", local_only)
 105       |> Map.put("blocking_user", user)
 106       |> Map.put("muting_user", user)
 107       |> Map.put("user", user)
 108       |> Map.put("tag", tags)
 109       |> Map.put("tag_all", tag_all)
 110       |> Map.put("tag_reject", tag_reject)
 111       |> ActivityPub.fetch_public_activities()
 112
 113     conn
 114     |> add_link_headers(activities, %{"local" => local_only})
 115     |> render("index.json", activities: activities, for: user, as: :activity)
 116   end
 117
 118   # GET /api/v1/timelines/list/:list_id
 119   def list(%{assigns: %{user: user}} = conn, %{"list_id" => id} = params) do
 120     with %Pleroma.List{title: _title, following: following} <- Pleroma.List.get(id, user) do
 121       params =
 122         params
 123         |> Map.put("type", "Create")
 124         |> Map.put("blocking_user", user)
 125         |> Map.put("user", user)
 126         |> Map.put("muting_user", user)
 127
 128       # we must filter the following list for the user to avoid leaking statuses the user
 129       # does not actually have permission to see (for more info, peruse security issue #270).
 130
 131       user_following = User.following(user)
 132
 133       activities =
 134         following
 135         |> Enum.filter(fn x -> x in user_following end)
 136         |> ActivityPub.fetch_activities_bounded(following, params)
 137         |> Enum.reverse()
 138
 139       render(conn, "index.json", activities: activities, for: user, as: :activity)
 140     else
 141       _e -> render_error(conn, :forbidden, "Error.")
 142     end
 143   end
 144 end