git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/controllers/timeline_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.TimelineController do
   6   use Pleroma.Web, :controller
   7
   8   import Pleroma.Web.ControllerHelper,
   9     only: [add_link_headers: 2, add_link_headers: 3, truthy_param?: 1, skip_relationships?: 1]
  10
  11   alias Pleroma.Pagination
  12   alias Pleroma.Plugs.OAuthScopesPlug
  13   alias Pleroma.Plugs.RateLimiter
  14   alias Pleroma.User
  15   alias Pleroma.Web.ActivityPub.ActivityPub
  16
  17   # TODO: Replace with a macro when there is a Phoenix release with the following commit in it:
  18   # https://github.com/phoenixframework/phoenix/commit/2e8c63c01fec4dde5467dbbbf9705ff9e780735e
  19
  20   plug(RateLimiter, [name: :timeline, bucket_name: :direct_timeline] when action == :direct)
  21   plug(RateLimiter, [name: :timeline, bucket_name: :public_timeline] when action == :public)
  22   plug(RateLimiter, [name: :timeline, bucket_name: :home_timeline] when action == :home)
  23   plug(RateLimiter, [name: :timeline, bucket_name: :hashtag_timeline] when action == :hashtag)
  24   plug(RateLimiter, [name: :timeline, bucket_name: :list_timeline] when action == :list)
  25
  26   plug(OAuthScopesPlug, %{scopes: ["read:statuses"]} when action in [:home, :direct])
  27   plug(OAuthScopesPlug, %{scopes: ["read:lists"]} when action == :list)
  28
  29   plug(Pleroma.Plugs.EnsurePublicOrAuthenticatedPlug when action != :public)
  30
  31   plug(:put_view, Pleroma.Web.MastodonAPI.StatusView)
  32
  33   # GET /api/v1/timelines/home
  34   def home(%{assigns: %{user: user}} = conn, params) do
  35     params =
  36       params
  37       |> Map.put("type", ["Create", "Announce"])
  38       |> Map.put("blocking_user", user)
  39       |> Map.put("muting_user", user)
  40       |> Map.put("user", user)
  41
  42     recipients = [user.ap_id | User.following(user)]
  43
  44     activities =
  45       recipients
  46       |> ActivityPub.fetch_activities(params)
  47       |> Enum.reverse()
  48
  49     conn
  50     |> add_link_headers(activities)
  51     |> render("index.json",
  52       activities: activities,
  53       for: user,
  54       as: :activity,
  55       skip_relationships: skip_relationships?(params)
  56     )
  57   end
  58
  59   # GET /api/v1/timelines/direct
  60   def direct(%{assigns: %{user: user}} = conn, params) do
  61     params =
  62       params
  63       |> Map.put("type", "Create")
  64       |> Map.put("blocking_user", user)
  65       |> Map.put("user", user)
  66       |> Map.put(:visibility, "direct")
  67
  68     activities =
  69       [user.ap_id]
  70       |> ActivityPub.fetch_activities_query(params)
  71       |> Pagination.fetch_paginated(params)
  72
  73     conn
  74     |> add_link_headers(activities)
  75     |> render("index.json",
  76       activities: activities,
  77       for: user,
  78       as: :activity,
  79       skip_relationships: skip_relationships?(params)
  80     )
  81   end
  82
  83   # GET /api/v1/timelines/public
  84   def public(%{assigns: %{user: user}} = conn, params) do
  85     local_only = truthy_param?(params["local"])
  86
  87     cfg_key =
  88       if local_only do
  89         :local
  90       else
  91         :federated
  92       end
  93
  94     restrict? = Pleroma.Config.get([:restrict_unauthenticated, :timelines, cfg_key])
  95
  96     if not (restrict? and is_nil(user)) do
  97       activities =
  98         params
  99         |> Map.put("type", ["Create", "Announce"])
 100         |> Map.put("local_only", local_only)
 101         |> Map.put("blocking_user", user)
 102         |> Map.put("muting_user", user)
 103         |> Map.put("user", user)
 104         |> ActivityPub.fetch_public_activities()
 105
 106       conn
 107       |> add_link_headers(activities, %{"local" => local_only})
 108       |> render("index.json",
 109         activities: activities,
 110         for: user,
 111         as: :activity,
 112         skip_relationships: skip_relationships?(params)
 113       )
 114     else
 115       render_error(conn, :unauthorized, "authorization required for timeline view")
 116     end
 117   end
 118
 119   def hashtag_fetching(params, user, local_only) do
 120     tags =
 121       [params["tag"], params["any"]]
 122       |> List.flatten()
 123       |> Enum.uniq()
 124       |> Enum.filter(& &1)
 125       |> Enum.map(&String.downcase(&1))
 126
 127     tag_all =
 128       params
 129       |> Map.get("all", [])
 130       |> Enum.map(&String.downcase(&1))
 131
 132     tag_reject =
 133       params
 134       |> Map.get("none", [])
 135       |> Enum.map(&String.downcase(&1))
 136
 137     _activities =
 138       params
 139       |> Map.put("type", "Create")
 140       |> Map.put("local_only", local_only)
 141       |> Map.put("blocking_user", user)
 142       |> Map.put("muting_user", user)
 143       |> Map.put("user", user)
 144       |> Map.put("tag", tags)
 145       |> Map.put("tag_all", tag_all)
 146       |> Map.put("tag_reject", tag_reject)
 147       |> ActivityPub.fetch_public_activities()
 148   end
 149
 150   # GET /api/v1/timelines/tag/:tag
 151   def hashtag(%{assigns: %{user: user}} = conn, params) do
 152     local_only = truthy_param?(params["local"])
 153
 154     activities = hashtag_fetching(params, user, local_only)
 155
 156     conn
 157     |> add_link_headers(activities, %{"local" => local_only})
 158     |> render("index.json",
 159       activities: activities,
 160       for: user,
 161       as: :activity,
 162       skip_relationships: skip_relationships?(params)
 163     )
 164   end
 165
 166   # GET /api/v1/timelines/list/:list_id
 167   def list(%{assigns: %{user: user}} = conn, %{"list_id" => id} = params) do
 168     with %Pleroma.List{title: _title, following: following} <- Pleroma.List.get(id, user) do
 169       params =
 170         params
 171         |> Map.put("type", "Create")
 172         |> Map.put("blocking_user", user)
 173         |> Map.put("user", user)
 174         |> Map.put("muting_user", user)
 175
 176       # we must filter the following list for the user to avoid leaking statuses the user
 177       # does not actually have permission to see (for more info, peruse security issue #270).
 178
 179       user_following = User.following(user)
 180
 181       activities =
 182         following
 183         |> Enum.filter(fn x -> x in user_following end)
 184         |> ActivityPub.fetch_activities_bounded(following, params)
 185         |> Enum.reverse()
 186
 187       render(conn, "index.json",
 188         activities: activities,
 189         for: user,
 190         as: :activity,
 191         skip_relationships: skip_relationships?(params)
 192       )
 193     else
 194       _e -> render_error(conn, :forbidden, "Error.")
 195     end
 196   end
 197 end