git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/controllers/follow_request_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.FollowRequestController do
   6   use Pleroma.Web, :controller
   7
   8   alias Pleroma.Plugs.OAuthScopesPlug
   9   alias Pleroma.User
  10   alias Pleroma.Web.CommonAPI
  11
  12   plug(:put_view, Pleroma.Web.MastodonAPI.AccountView)
  13   plug(:assign_follower when action != :index)
  14
  15   action_fallback(:errors)
  16
  17   plug(OAuthScopesPlug, %{scopes: ["follow", "read:follows"]} when action == :index)
  18
  19   plug(
  20     OAuthScopesPlug,
  21     %{scopes: ["follow", "write:follows"]} when action != :index
  22   )
  23
  24   @doc "GET /api/v1/follow_requests"
  25   def index(%{assigns: %{user: followed}} = conn, _params) do
  26     follow_requests = User.get_follow_requests(followed)
  27
  28     render(conn, "index.json", for: followed, users: follow_requests, as: :user)
  29   end
  30
  31   @doc "POST /api/v1/follow_requests/:id/authorize"
  32   def authorize(%{assigns: %{user: followed, follower: follower}} = conn, _params) do
  33     with {:ok, follower} <- CommonAPI.accept_follow_request(follower, followed) do
  34       render(conn, "relationship.json", user: followed, target: follower)
  35     end
  36   end
  37
  38   @doc "POST /api/v1/follow_requests/:id/reject"
  39   def reject(%{assigns: %{user: followed, follower: follower}} = conn, _params) do
  40     with {:ok, follower} <- CommonAPI.reject_follow_request(follower, followed) do
  41       render(conn, "relationship.json", user: followed, target: follower)
  42     end
  43   end
  44
  45   defp assign_follower(%{params: %{"id" => id}} = conn, _) do
  46     case User.get_cached_by_id(id) do
  47       %User{} = follower -> assign(conn, :follower, follower)
  48       nil -> Pleroma.Web.MastodonAPI.FallbackController.call(conn, {:error, :not_found}) |> halt()
  49     end
  50   end
  51
  52   defp errors(conn, {:error, message}) do
  53     conn
  54     |> put_status(:forbidden)
  55     |> json(%{error: message})
  56   end
  57 end