git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/controllers/follow_request_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.FollowRequestController do
   6   use Pleroma.Web, :controller
   7
   8   import Pleroma.Web.ControllerHelper,
   9     only: [add_link_headers: 2]
  10
  11   alias Pleroma.User
  12   alias Pleroma.Web.CommonAPI
  13   alias Pleroma.Web.Plugs.OAuthScopesPlug
  14   alias Pleroma.Pagination
  15
  16   plug(Pleroma.Web.ApiSpec.CastAndValidate)
  17   plug(:assign_follower when action != :index)
  18
  19   action_fallback(:errors)
  20
  21   plug(OAuthScopesPlug, %{scopes: ["follow", "read:follows"]} when action == :index)
  22
  23   plug(
  24     OAuthScopesPlug,
  25     %{scopes: ["follow", "write:follows"]} when action != :index
  26   )
  27
  28   defdelegate open_api_operation(action), to: Pleroma.Web.ApiSpec.FollowRequestOperation
  29
  30   @doc "GET /api/v1/follow_requests"
  31   def index(%{assigns: %{user: followed}} = conn, params) do
  32     follow_requests =
  33       followed
  34       |> User.get_follow_requests_query()
  35       |> Pagination.fetch_paginated(params, :keyset, :follower)
  36
  37     conn
  38     |> add_link_headers(follow_requests)
  39     |> render("index.json", for: followed, users: follow_requests, as: :user)
  40   end
  41
  42   @doc "POST /api/v1/follow_requests/:id/authorize"
  43   def authorize(%{assigns: %{user: followed, follower: follower}} = conn, _params) do
  44     with {:ok, follower} <- CommonAPI.accept_follow_request(follower, followed) do
  45       render(conn, "relationship.json", user: followed, target: follower)
  46     end
  47   end
  48
  49   @doc "POST /api/v1/follow_requests/:id/reject"
  50   def reject(%{assigns: %{user: followed, follower: follower}} = conn, _params) do
  51     with {:ok, follower} <- CommonAPI.reject_follow_request(follower, followed) do
  52       render(conn, "relationship.json", user: followed, target: follower)
  53     end
  54   end
  55
  56   defp assign_follower(%{params: %{id: id}} = conn, _) do
  57     case User.get_cached_by_id(id) do
  58       %User{} = follower -> assign(conn, :follower, follower)
  59       nil -> Pleroma.Web.MastodonAPI.FallbackController.call(conn, {:error, :not_found}) |> halt()
  60     end
  61   end
  62
  63   defp errors(conn, {:error, message}) do
  64     conn
  65     |> put_status(:forbidden)
  66     |> json(%{error: message})
  67   end
  68 end