git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/controllers/app_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.AppController do
   6   @moduledoc """
   7   Controller for supporting app-related actions.
   8   If authentication is an option, app tokens (user-unbound) must be supported.
   9   """
  10
  11   use Pleroma.Web, :controller
  12
  13   alias Pleroma.Repo
  14   alias Pleroma.Web.OAuth.App
  15   alias Pleroma.Web.OAuth.Scopes
  16   alias Pleroma.Web.OAuth.Token
  17   alias Pleroma.Web.Plugs.EnsurePublicOrAuthenticatedPlug
  18   alias Pleroma.Web.Plugs.OAuthScopesPlug
  19
  20   action_fallback(Pleroma.Web.MastodonAPI.FallbackController)
  21
  22   plug(
  23     :skip_plug,
  24     [OAuthScopesPlug, EnsurePublicOrAuthenticatedPlug]
  25     when action in [:create, :verify_credentials]
  26   )
  27
  28   plug(Pleroma.Web.ApiSpec.CastAndValidate)
  29
  30   defdelegate open_api_operation(action), to: Pleroma.Web.ApiSpec.AppOperation
  31
  32   @doc "POST /api/v1/apps"
  33   def create(%{body_params: params} = conn, _params) do
  34     scopes = Scopes.fetch_scopes(params, ["read"])
  35
  36     app_attrs =
  37       params
  38       |> Map.take([:client_name, :redirect_uris, :website])
  39       |> Map.put(:scopes, scopes)
  40
  41     with cs <- App.register_changeset(%App{}, app_attrs),
  42          {:ok, app} <- Repo.insert(cs) do
  43       render(conn, "show.json", app: app)
  44     end
  45   end
  46
  47   @doc """
  48   GET /api/v1/apps/verify_credentials
  49   Gets compact non-secret representation of the app. Supports app tokens and user tokens.
  50   """
  51   def verify_credentials(%{assigns: %{token: %Token{} = token}} = conn, _) do
  52     with %{app: %App{} = app} <- Repo.preload(token, :app) do
  53       render(conn, "compact_non_secret.json", app: app)
  54     end
  55   end
  56 end