git.squeep.com Git - akkoma/blob - lib/pleroma/web/federator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.Federator do
   6   alias Pleroma.Activity
   7   alias Pleroma.Object.Containment
   8   alias Pleroma.User
   9   alias Pleroma.Web.ActivityPub.ActivityPub
  10   alias Pleroma.Web.ActivityPub.Transmogrifier
  11   alias Pleroma.Web.ActivityPub.Utils
  12   alias Pleroma.Web.Federator.Publisher
  13   alias Pleroma.Workers.PublisherWorker
  14   alias Pleroma.Workers.ReceiverWorker
  15
  16   require Logger
  17
  18   @behaviour Pleroma.Web.Federator.Publishing
  19
  20   @doc """
  21   Returns `true` if the distance to target object does not exceed max configured value.
  22   Serves to prevent fetching of very long threads, especially useful on smaller instances.
  23   Addresses [memory leaks on recursive replies fetching](https://git.pleroma.social/pleroma/pleroma/issues/161).
  24   Applies to fetching of both ancestor (reply-to) and child (reply) objects.
  25   """
  26   # credo:disable-for-previous-line Credo.Check.Readability.MaxLineLength
  27   def allowed_thread_distance?(distance) do
  28     max_distance = Pleroma.Config.get([:instance, :federation_incoming_replies_max_depth])
  29
  30     if max_distance && max_distance >= 0 do
  31       # Default depth is 0 (an object has zero distance from itself in its thread)
  32       (distance || 0) <= max_distance
  33     else
  34       true
  35     end
  36   end
  37
  38   # Client API
  39
  40   def incoming_ap_doc(params) do
  41     ReceiverWorker.enqueue("incoming_ap_doc", %{"params" => params})
  42   end
  43
  44   @impl true
  45   def publish(%{id: "pleroma:fakeid"} = activity) do
  46     perform(:publish, activity)
  47   end
  48
  49   @impl true
  50   def publish(%{data: %{"object" => object}} = activity) when is_binary(object) do
  51     PublisherWorker.enqueue("publish", %{"activity_id" => activity.id, "object_data" => nil})
  52   end
  53
  54   @impl true
  55   def publish(%{data: %{"object" => object}} = activity) when is_map(object) or is_list(object) do
  56     PublisherWorker.enqueue("publish", %{
  57       "activity_id" => activity.id,
  58       "object_data" => Jason.encode!(object)
  59     })
  60   end
  61
  62   # Job Worker Callbacks
  63
  64   @spec perform(atom(), module(), any()) :: {:ok, any()} | {:error, any()}
  65   def perform(:publish_one, module, params) do
  66     apply(module, :publish_one, [params])
  67   end
  68
  69   def perform(:publish, activity) do
  70     Logger.debug(fn -> "Running publish for #{activity.data["id"]}" end)
  71
  72     with %User{} = actor <- User.get_cached_by_ap_id(activity.data["actor"]),
  73          {:ok, actor} <- User.ensure_keys_present(actor) do
  74       Publisher.publish(actor, activity)
  75     end
  76   end
  77
  78   def perform(:incoming_ap_doc, params) do
  79     Logger.debug("Handling incoming AP activity")
  80
  81     actor =
  82       params
  83       |> Map.get("actor")
  84       |> Utils.get_ap_id()
  85
  86     # NOTE: we use the actor ID to do the containment, this is fine because an
  87     # actor shouldn't be acting on objects outside their own AP server.
  88     with {_, {:ok, _user}} <- {:actor, ap_enabled_actor(actor)},
  89          nil <- Activity.normalize(params["id"]),
  90          {_, :ok} <-
  91            {:correct_origin?, Containment.contain_origin_from_id(actor, params)},
  92          {:ok, activity} <- Transmogrifier.handle_incoming(params) do
  93       {:ok, activity}
  94     else
  95       {:correct_origin?, _} ->
  96         Logger.debug("Origin containment failure for #{params["id"]}")
  97         {:error, :origin_containment_failed}
  98
  99       %Activity{} ->
 100         Logger.debug("Already had #{params["id"]}")
 101         {:error, :already_present}
 102
 103       {:actor, e} ->
 104         Logger.debug("Unhandled actor #{actor}, #{inspect(e)}")
 105         {:error, e}
 106
 107       {:error, {:validate_object, _}} = e ->
 108         Logger.error("Incoming AP doc validation error: #{inspect(e)}")
 109         Logger.debug(Jason.encode!(params, pretty: true))
 110         e
 111
 112       e ->
 113         # Just drop those for now
 114         Logger.debug(fn -> "Unhandled activity\n" <> Jason.encode!(params, pretty: true) end)
 115         {:error, e}
 116     end
 117   end
 118
 119   def ap_enabled_actor(id) do
 120     user = User.get_cached_by_ap_id(id)
 121
 122     if User.ap_enabled?(user) do
 123       {:ok, user}
 124     else
 125       ActivityPub.make_user_from_ap_id(id)
 126     end
 127   end
 128 end