git.squeep.com Git - akkoma/blob - lib/pleroma/web/federator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.Federator do
   6   alias Pleroma.Activity
   7   alias Pleroma.Object.Containment
   8   alias Pleroma.User
   9   alias Pleroma.Web.ActivityPub.ActivityPub
  10   alias Pleroma.Web.ActivityPub.Transmogrifier
  11   alias Pleroma.Web.ActivityPub.Utils
  12   alias Pleroma.Web.Federator.Publisher
  13   alias Pleroma.Workers.PublisherWorker
  14   alias Pleroma.Workers.ReceiverWorker
  15
  16   require Logger
  17
  18   @behaviour Pleroma.Web.Federator.Publishing
  19
  20   @doc """
  21   Returns `true` if the distance to target object does not exceed max configured value.
  22   Serves to prevent fetching of very long threads, especially useful on smaller instances.
  23   Addresses [memory leaks on recursive replies fetching](https://git.pleroma.social/pleroma/pleroma/issues/161).
  24   Applies to fetching of both ancestor (reply-to) and child (reply) objects.
  25   """
  26   # credo:disable-for-previous-line Credo.Check.Readability.MaxLineLength
  27   def allowed_thread_distance?(distance) do
  28     max_distance = Pleroma.Config.get([:instance, :federation_incoming_replies_max_depth])
  29
  30     if max_distance && max_distance >= 0 do
  31       # Default depth is 0 (an object has zero distance from itself in its thread)
  32       (distance || 0) <= max_distance
  33     else
  34       true
  35     end
  36   end
  37
  38   # Client API
  39
  40   def incoming_ap_doc(params) do
  41     ReceiverWorker.enqueue("incoming_ap_doc", %{"params" => params})
  42   end
  43
  44   @impl true
  45   def publish(%{id: "pleroma:fakeid"} = activity) do
  46     perform(:publish, activity)
  47   end
  48
  49   @impl true
  50   def publish(%{data: %{"object" => object}} = activity) when is_binary(object) do
  51     PublisherWorker.enqueue("publish", %{"activity_id" => activity.id, "object_data" => nil})
  52   end
  53
  54   @impl true
  55   def publish(%{data: %{"object" => object}} = activity) when is_map(object) or is_list(object) do
  56     PublisherWorker.enqueue("publish", %{
  57       "activity_id" => activity.id,
  58       "object_data" => Jason.encode!(object)
  59     })
  60   end
  61
  62   # Job Worker Callbacks
  63
  64   @spec perform(atom(), module(), any()) :: {:ok, any()} | {:error, any()}
  65   def perform(:publish_one, module, params) do
  66     apply(module, :publish_one, [params])
  67   end
  68
  69   def perform(:publish, activity) do
  70     Logger.debug(fn -> "Running publish for #{activity.data["id"]}" end)
  71
  72     %User{} = actor = User.get_cached_by_ap_id(activity.data["actor"])
  73     Publisher.publish(actor, activity)
  74   end
  75
  76   def perform(:incoming_ap_doc, params) do
  77     Logger.debug("Handling incoming AP activity")
  78
  79     actor =
  80       params
  81       |> Map.get("actor")
  82       |> Utils.get_ap_id()
  83
  84     # NOTE: we use the actor ID to do the containment, this is fine because an
  85     # actor shouldn't be acting on objects outside their own AP server.
  86     with {_, {:ok, _user}} <- {:actor, ap_enabled_actor(actor)},
  87          nil <- Activity.normalize(params["id"]),
  88          {_, :ok} <-
  89            {:correct_origin?, Containment.contain_origin_from_id(actor, params)},
  90          {:ok, activity} <- Transmogrifier.handle_incoming(params) do
  91       {:ok, activity}
  92     else
  93       {:correct_origin?, _} ->
  94         Logger.debug("Origin containment failure for #{params["id"]}")
  95         {:error, :origin_containment_failed}
  96
  97       %Activity{} ->
  98         Logger.debug("Already had #{params["id"]}")
  99         {:error, :already_present}
 100
 101       {:actor, e} ->
 102         Logger.debug("Unhandled actor #{actor}, #{inspect(e)}")
 103         {:error, e}
 104
 105       {:error, {:validate_object, _}} = e ->
 106         Logger.error("Incoming AP doc validation error: #{inspect(e)}")
 107         Logger.debug(Jason.encode!(params, pretty: true))
 108         e
 109
 110       e ->
 111         # Just drop those for now
 112         Logger.debug(fn -> "Unhandled activity\n" <> Jason.encode!(params, pretty: true) end)
 113         {:error, e}
 114     end
 115   end
 116
 117   def ap_enabled_actor(id) do
 118     user = User.get_cached_by_ap_id(id)
 119
 120     if User.ap_enabled?(user) do
 121       {:ok, user}
 122     else
 123       ActivityPub.make_user_from_ap_id(id)
 124     end
 125   end
 126 end