git.squeep.com Git - akkoma/blob - lib/pleroma/web/federator/federator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.Federator do
   6   alias Pleroma.Activity
   7   alias Pleroma.Object.Containment
   8   alias Pleroma.User
   9   alias Pleroma.Web.ActivityPub.ActivityPub
  10   alias Pleroma.Web.ActivityPub.Transmogrifier
  11   alias Pleroma.Web.ActivityPub.Utils
  12   alias Pleroma.Web.Federator.Publisher
  13   alias Pleroma.Web.OStatus
  14   alias Pleroma.Web.Websub
  15
  16   require Logger
  17
  18   def init do
  19     # 1 minute
  20     Process.sleep(1000 * 60)
  21     refresh_subscriptions()
  22   end
  23
  24   @doc "Addresses [memory leaks on recursive replies fetching](https://git.pleroma.social/pleroma/pleroma/issues/161)"
  25   # credo:disable-for-previous-line Credo.Check.Readability.MaxLineLength
  26   def allowed_incoming_reply_depth?(depth) do
  27     max_replies_depth = Pleroma.Config.get([:instance, :federation_incoming_replies_max_depth])
  28
  29     if max_replies_depth do
  30       (depth || 1) <= max_replies_depth
  31     else
  32       true
  33     end
  34   end
  35
  36   # Client API
  37
  38   def incoming_doc(doc) do
  39     PleromaJobQueue.enqueue(:federator_incoming, __MODULE__, [:incoming_doc, doc])
  40   end
  41
  42   def incoming_ap_doc(params) do
  43     PleromaJobQueue.enqueue(:federator_incoming, __MODULE__, [:incoming_ap_doc, params])
  44   end
  45
  46   def publish(activity, priority \\ 1) do
  47     PleromaJobQueue.enqueue(:federator_outgoing, __MODULE__, [:publish, activity], priority)
  48   end
  49
  50   def verify_websub(websub) do
  51     PleromaJobQueue.enqueue(:federator_outgoing, __MODULE__, [:verify_websub, websub])
  52   end
  53
  54   def request_subscription(sub) do
  55     PleromaJobQueue.enqueue(:federator_outgoing, __MODULE__, [:request_subscription, sub])
  56   end
  57
  58   def refresh_subscriptions do
  59     PleromaJobQueue.enqueue(:federator_outgoing, __MODULE__, [:refresh_subscriptions])
  60   end
  61
  62   # Job Worker Callbacks
  63
  64   def perform(:refresh_subscriptions) do
  65     Logger.debug("Federator running refresh subscriptions")
  66     Websub.refresh_subscriptions()
  67
  68     spawn(fn ->
  69       # 6 hours
  70       Process.sleep(1000 * 60 * 60 * 6)
  71       refresh_subscriptions()
  72     end)
  73   end
  74
  75   def perform(:request_subscription, websub) do
  76     Logger.debug("Refreshing #{websub.topic}")
  77
  78     with {:ok, websub} <- Websub.request_subscription(websub) do
  79       Logger.debug("Successfully refreshed #{websub.topic}")
  80     else
  81       _e -> Logger.debug("Couldn't refresh #{websub.topic}")
  82     end
  83   end
  84
  85   def perform(:publish, activity) do
  86     Logger.debug(fn -> "Running publish for #{activity.data["id"]}" end)
  87
  88     with %User{} = actor <- User.get_cached_by_ap_id(activity.data["actor"]),
  89          {:ok, actor} <- User.ensure_keys_present(actor) do
  90       Publisher.publish(actor, activity)
  91     end
  92   end
  93
  94   def perform(:verify_websub, websub) do
  95     Logger.debug(fn ->
  96       "Running WebSub verification for #{websub.id} (#{websub.topic}, #{websub.callback})"
  97     end)
  98
  99     Websub.verify(websub)
 100   end
 101
 102   def perform(:incoming_doc, doc) do
 103     Logger.info("Got document, trying to parse")
 104     OStatus.handle_incoming(doc)
 105   end
 106
 107   def perform(:incoming_ap_doc, params) do
 108     Logger.info("Handling incoming AP activity")
 109
 110     params = Utils.normalize_params(params)
 111
 112     # NOTE: we use the actor ID to do the containment, this is fine because an
 113     # actor shouldn't be acting on objects outside their own AP server.
 114     with {:ok, _user} <- ap_enabled_actor(params["actor"]),
 115          nil <- Activity.normalize(params["id"]),
 116          :ok <- Containment.contain_origin_from_id(params["actor"], params),
 117          {:ok, activity} <- Transmogrifier.handle_incoming(params) do
 118       {:ok, activity}
 119     else
 120       %Activity{} ->
 121         Logger.info("Already had #{params["id"]}")
 122         :error
 123
 124       _e ->
 125         # Just drop those for now
 126         Logger.info("Unhandled activity")
 127         Logger.info(Jason.encode!(params, pretty: true))
 128         :error
 129     end
 130   end
 131
 132   def perform(type, _) do
 133     Logger.debug(fn -> "Unknown task: #{type}" end)
 134     {:error, "Don't know what to do with this"}
 135   end
 136
 137   def ap_enabled_actor(id) do
 138     user = User.get_cached_by_ap_id(id)
 139
 140     if User.ap_enabled?(user) do
 141       {:ok, user}
 142     else
 143       ActivityPub.make_user_from_ap_id(id)
 144     end
 145   end
 146 end