git.squeep.com Git - akkoma/blob - lib/pleroma/web/controller_helper.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ControllerHelper do
   6   use Pleroma.Web, :controller
   7
   8   # As in MastoAPI, per https://api.rubyonrails.org/classes/ActiveModel/Type/Boolean.html
   9   @falsy_param_values [false, 0, "0", "f", "F", "false", "FALSE", "off", "OFF"]
  10   def truthy_param?(blank_value) when blank_value in [nil, ""], do: nil
  11   def truthy_param?(value), do: value not in @falsy_param_values
  12
  13   def json_response(conn, status, json) do
  14     conn
  15     |> put_status(status)
  16     |> json(json)
  17   end
  18
  19   @spec fetch_integer_param(map(), String.t(), integer() | nil) :: integer() | nil
  20   def fetch_integer_param(params, name, default \\ nil) do
  21     params
  22     |> Map.get(name, default)
  23     |> param_to_integer(default)
  24   end
  25
  26   defp param_to_integer(val, _) when is_integer(val), do: val
  27
  28   defp param_to_integer(val, default) when is_binary(val) do
  29     case Integer.parse(val) do
  30       {res, _} -> res
  31       _ -> default
  32     end
  33   end
  34
  35   defp param_to_integer(_, default), do: default
  36
  37   def add_link_headers(
  38         conn,
  39         method,
  40         activities,
  41         param \\ nil,
  42         params \\ %{},
  43         func3 \\ nil,
  44         func4 \\ nil
  45       ) do
  46     params =
  47       conn.params
  48       |> Map.drop(["since_id", "max_id", "min_id"])
  49       |> Map.merge(params)
  50
  51     last = List.last(activities)
  52
  53     func3 = func3 || (&mastodon_api_url/3)
  54     func4 = func4 || (&mastodon_api_url/4)
  55
  56     if last do
  57       max_id = last.id
  58
  59       limit =
  60         params
  61         |> Map.get("limit", "20")
  62         |> String.to_integer()
  63
  64       min_id =
  65         if length(activities) <= limit do
  66           activities
  67           |> List.first()
  68           |> Map.get(:id)
  69         else
  70           activities
  71           |> Enum.at(limit * -1)
  72           |> Map.get(:id)
  73         end
  74
  75       {next_url, prev_url} =
  76         if param do
  77           {
  78             func4.(
  79               Pleroma.Web.Endpoint,
  80               method,
  81               param,
  82               Map.merge(params, %{max_id: max_id})
  83             ),
  84             func4.(
  85               Pleroma.Web.Endpoint,
  86               method,
  87               param,
  88               Map.merge(params, %{min_id: min_id})
  89             )
  90           }
  91         else
  92           {
  93             func3.(
  94               Pleroma.Web.Endpoint,
  95               method,
  96               Map.merge(params, %{max_id: max_id})
  97             ),
  98             func3.(
  99               Pleroma.Web.Endpoint,
 100               method,
 101               Map.merge(params, %{min_id: min_id})
 102             )
 103           }
 104         end
 105
 106       conn
 107       |> put_resp_header("link", "<#{next_url}>; rel=\"next\", <#{prev_url}>; rel=\"prev\"")
 108     else
 109       conn
 110     end
 111   end
 112 end