git.squeep.com Git - akkoma/blob - lib/pleroma/web/common_api/utils.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.CommonAPI.Utils do
   6   alias Calendar.Strftime
   7   alias Comeonin.Pbkdf2
   8   alias Pleroma.{Activity, Formatter, Object, Repo}
   9   alias Pleroma.{User, Web}
  10   alias Pleroma.Web.ActivityPub.Utils
  11   alias Pleroma.Web.Endpoint
  12   alias Pleroma.Web.MediaProxy
  13
  14   # This is a hack for twidere.
  15   def get_by_id_or_ap_id(id) do
  16     activity = Repo.get(Activity, id) || Activity.get_create_by_object_ap_id(id)
  17
  18     activity &&
  19       if activity.data["type"] == "Create" do
  20         activity
  21       else
  22         Activity.get_create_by_object_ap_id(activity.data["object"])
  23       end
  24   end
  25
  26   def get_replied_to_activity(""), do: nil
  27
  28   def get_replied_to_activity(id) when not is_nil(id) do
  29     Repo.get(Activity, id)
  30   end
  31
  32   def get_replied_to_activity(_), do: nil
  33
  34   def attachments_from_ids(ids) do
  35     Enum.map(ids || [], fn media_id ->
  36       Repo.get(Object, media_id).data
  37     end)
  38   end
  39
  40   def to_for_user_and_mentions(user, mentions, inReplyTo, "public") do
  41     mentioned_users = Enum.map(mentions, fn {_, %{ap_id: ap_id}} -> ap_id end)
  42
  43     to = ["https://www.w3.org/ns/activitystreams#Public" | mentioned_users]
  44     cc = [user.follower_address]
  45
  46     if inReplyTo do
  47       {Enum.uniq([inReplyTo.data["actor"] | to]), cc}
  48     else
  49       {to, cc}
  50     end
  51   end
  52
  53   def to_for_user_and_mentions(user, mentions, inReplyTo, "unlisted") do
  54     mentioned_users = Enum.map(mentions, fn {_, %{ap_id: ap_id}} -> ap_id end)
  55
  56     to = [user.follower_address | mentioned_users]
  57     cc = ["https://www.w3.org/ns/activitystreams#Public"]
  58
  59     if inReplyTo do
  60       {Enum.uniq([inReplyTo.data["actor"] | to]), cc}
  61     else
  62       {to, cc}
  63     end
  64   end
  65
  66   def to_for_user_and_mentions(user, mentions, inReplyTo, "private") do
  67     {to, cc} = to_for_user_and_mentions(user, mentions, inReplyTo, "direct")
  68     {[user.follower_address | to], cc}
  69   end
  70
  71   def to_for_user_and_mentions(_user, mentions, inReplyTo, "direct") do
  72     mentioned_users = Enum.map(mentions, fn {_, %{ap_id: ap_id}} -> ap_id end)
  73
  74     if inReplyTo do
  75       {Enum.uniq([inReplyTo.data["actor"] | mentioned_users]), []}
  76     else
  77       {mentioned_users, []}
  78     end
  79   end
  80
  81   def make_content_html(
  82         status,
  83         mentions,
  84         attachments,
  85         tags,
  86         content_type,
  87         no_attachment_links \\ false
  88       ) do
  89     status
  90     |> format_input(mentions, tags, content_type)
  91     |> maybe_add_attachments(attachments, no_attachment_links)
  92   end
  93
  94   def make_context(%Activity{data: %{"context" => context}}), do: context
  95   def make_context(_), do: Utils.generate_context_id()
  96
  97   def maybe_add_attachments(text, _attachments, _no_links = true), do: text
  98
  99   def maybe_add_attachments(text, attachments, _no_links) do
 100     add_attachments(text, attachments)
 101   end
 102
 103   def add_attachments(text, attachments) do
 104     attachment_text =
 105       Enum.map(attachments, fn
 106         %{"url" => [%{"href" => href} | _]} = attachment ->
 107           name = attachment["name"] || URI.decode(Path.basename(href))
 108           href = MediaProxy.url(href)
 109           "<a href=\"#{href}\" class='attachment'>#{shortname(name)}</a>"
 110
 111         _ ->
 112           ""
 113       end)
 114
 115     Enum.join([text | attachment_text], "<br>")
 116   end
 117
 118   def format_input(text, mentions, tags, format, options \\ [])
 119
 120   @doc """
 121   Formatting text to plain text.
 122   """
 123   def format_input(text, mentions, tags, "text/plain", options) do
 124     text
 125     |> Formatter.html_escape("text/plain")
 126     |> String.replace(~r/\r?\n/, "<br>")
 127     |> (&{[], &1}).()
 128     |> Formatter.add_links()
 129     |> Formatter.add_user_links(mentions, options[:user_links] || [])
 130     |> Formatter.add_hashtag_links(tags)
 131     |> Formatter.finalize()
 132   end
 133
 134   @doc """
 135   Formatting text to html.
 136   """
 137   def format_input(text, mentions, _tags, "text/html", options) do
 138     text
 139     |> Formatter.html_escape("text/html")
 140     |> (&{[], &1}).()
 141     |> Formatter.add_user_links(mentions, options[:user_links] || [])
 142     |> Formatter.finalize()
 143   end
 144
 145   @doc """
 146   Formatting text to markdown.
 147   """
 148   def format_input(text, mentions, tags, "text/markdown", options) do
 149     text
 150     |> Formatter.mentions_escape(mentions)
 151     |> Earmark.as_html!()
 152     |> Formatter.html_escape("text/html")
 153     |> (&{[], &1}).()
 154     |> Formatter.add_user_links(mentions, options[:user_links] || [])
 155     |> Formatter.add_hashtag_links(tags)
 156     |> Formatter.finalize()
 157   end
 158
 159   def add_tag_links(text, tags) do
 160     tags =
 161       tags
 162       |> Enum.sort_by(fn {tag, _} -> -String.length(tag) end)
 163
 164     Enum.reduce(tags, text, fn {full, tag}, text ->
 165       url = "<a href='#{Web.base_url()}/tag/#{tag}' rel='tag'>##{tag}</a>"
 166       String.replace(text, full, url)
 167     end)
 168   end
 169
 170   def make_note_data(
 171         actor,
 172         to,
 173         context,
 174         content_html,
 175         attachments,
 176         inReplyTo,
 177         tags,
 178         cw \\ nil,
 179         cc \\ []
 180       ) do
 181     object = %{
 182       "type" => "Note",
 183       "to" => to,
 184       "cc" => cc,
 185       "content" => content_html,
 186       "summary" => cw,
 187       "context" => context,
 188       "attachment" => attachments,
 189       "actor" => actor,
 190       "tag" => tags |> Enum.map(fn {_, tag} -> tag end) |> Enum.uniq()
 191     }
 192
 193     if inReplyTo do
 194       object
 195       |> Map.put("inReplyTo", inReplyTo.data["object"]["id"])
 196       |> Map.put("inReplyToStatusId", inReplyTo.id)
 197     else
 198       object
 199     end
 200   end
 201
 202   def format_naive_asctime(date) do
 203     date |> DateTime.from_naive!("Etc/UTC") |> format_asctime
 204   end
 205
 206   def format_asctime(date) do
 207     Strftime.strftime!(date, "%a %b %d %H:%M:%S %z %Y")
 208   end
 209
 210   def date_to_asctime(date) do
 211     with {:ok, date, _offset} <- date |> DateTime.from_iso8601() do
 212       format_asctime(date)
 213     else
 214       _e ->
 215         ""
 216     end
 217   end
 218
 219   def to_masto_date(%NaiveDateTime{} = date) do
 220     date
 221     |> NaiveDateTime.to_iso8601()
 222     |> String.replace(~r/(\.\d+)?$/, ".000Z", global: false)
 223   end
 224
 225   def to_masto_date(date) do
 226     try do
 227       date
 228       |> NaiveDateTime.from_iso8601!()
 229       |> NaiveDateTime.to_iso8601()
 230       |> String.replace(~r/(\.\d+)?$/, ".000Z", global: false)
 231     rescue
 232       _e -> ""
 233     end
 234   end
 235
 236   defp shortname(name) do
 237     if String.length(name) < 30 do
 238       name
 239     else
 240       String.slice(name, 0..30) <> "…"
 241     end
 242   end
 243
 244   def confirm_current_password(user, password) do
 245     with %User{local: true} = db_user <- Repo.get(User, user.id),
 246          true <- Pbkdf2.checkpw(password, db_user.password_hash) do
 247       {:ok, db_user}
 248     else
 249       _ -> {:error, "Invalid password."}
 250     end
 251   end
 252
 253   def emoji_from_profile(%{info: _info} = user) do
 254     (Formatter.get_emoji(user.bio) ++ Formatter.get_emoji(user.name))
 255     |> Enum.map(fn {shortcode, url} ->
 256       %{
 257         "type" => "Emoji",
 258         "icon" => %{"type" => "Image", "url" => "#{Endpoint.url()}#{url}"},
 259         "name" => ":#{shortcode}:"
 260       }
 261     end)
 262   end
 263
 264   def maybe_notify_to_recipients(
 265         recipients,
 266         %Activity{data: %{"to" => to, "type" => _type}} = _activity
 267       ) do
 268     recipients ++ to
 269   end
 270
 271   def maybe_notify_mentioned_recipients(
 272         recipients,
 273         %Activity{data: %{"to" => _to, "type" => type} = data} = _activity
 274       )
 275       when type == "Create" do
 276     object = Object.normalize(data["object"])
 277
 278     object_data =
 279       cond do
 280         !is_nil(object) ->
 281           object.data
 282
 283         is_map(data["object"]) ->
 284           data["object"]
 285
 286         true ->
 287           %{}
 288       end
 289
 290     tagged_mentions = maybe_extract_mentions(object_data)
 291
 292     recipients ++ tagged_mentions
 293   end
 294
 295   def maybe_notify_mentioned_recipients(recipients, _), do: recipients
 296
 297   def maybe_extract_mentions(%{"tag" => tag}) do
 298     tag
 299     |> Enum.filter(fn x -> is_map(x) end)
 300     |> Enum.filter(fn x -> x["type"] == "Mention" end)
 301     |> Enum.map(fn x -> x["href"] end)
 302   end
 303
 304   def maybe_extract_mentions(_), do: []
 305 end