git.squeep.com Git - akkoma/blob - lib/pleroma/web/admin_api/views/account_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.AdminAPI.AccountView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.User
   9   alias Pleroma.Web.AdminAPI.AccountView
  10   alias Pleroma.Web.MediaProxy
  11
  12   def render("index.json", %{users: users, count: count, page_size: page_size}) do
  13     %{
  14       users: render_many(users, AccountView, "show.json", as: :user),
  15       count: count,
  16       page_size: page_size
  17     }
  18   end
  19
  20   def render("index.json", %{users: users}) do
  21     %{
  22       users: render_many(users, AccountView, "show.json", as: :user)
  23     }
  24   end
  25
  26   def render("credentials.json", %{user: user, for: for_user}) do
  27     user = User.sanitize_html(user, User.html_filter_policy(for_user))
  28     avatar = User.avatar_url(user) |> MediaProxy.url()
  29     banner = User.banner_url(user) |> MediaProxy.url()
  30     background = image_url(user.background) |> MediaProxy.url()
  31
  32     user
  33     |> Map.take([
  34       :id,
  35       :bio,
  36       :email,
  37       :fields,
  38       :name,
  39       :nickname,
  40       :locked,
  41       :no_rich_text,
  42       :default_scope,
  43       :hide_follows,
  44       :hide_followers_count,
  45       :hide_follows_count,
  46       :hide_followers,
  47       :hide_favorites,
  48       :allow_following_move,
  49       :show_role,
  50       :skip_thread_containment,
  51       :pleroma_settings_store,
  52       :raw_fields,
  53       :discoverable,
  54       :actor_type
  55     ])
  56     |> Map.merge(%{
  57       "avatar" => avatar,
  58       "banner" => banner,
  59       "background" => background
  60     })
  61   end
  62
  63   def render("show.json", %{user: user}) do
  64     avatar = User.avatar_url(user) |> MediaProxy.url()
  65     display_name = Pleroma.HTML.strip_tags(user.name || user.nickname)
  66     user = User.sanitize_html(user, FastSanitize.Sanitizer.StripTags)
  67
  68     %{
  69       "id" => user.id,
  70       "avatar" => avatar,
  71       "nickname" => user.nickname,
  72       "display_name" => display_name,
  73       "deactivated" => user.deactivated,
  74       "local" => user.local,
  75       "roles" => User.roles(user),
  76       "tags" => user.tags || [],
  77       "confirmation_pending" => user.confirmation_pending
  78     }
  79   end
  80
  81   def render("invite.json", %{invite: invite}) do
  82     %{
  83       "id" => invite.id,
  84       "token" => invite.token,
  85       "used" => invite.used,
  86       "expires_at" => invite.expires_at,
  87       "uses" => invite.uses,
  88       "max_use" => invite.max_use,
  89       "invite_type" => invite.invite_type
  90     }
  91   end
  92
  93   def render("invites.json", %{invites: invites}) do
  94     %{
  95       invites: render_many(invites, AccountView, "invite.json", as: :invite)
  96     }
  97   end
  98
  99   def render("created.json", %{user: user}) do
 100     %{
 101       type: "success",
 102       code: 200,
 103       data: %{
 104         nickname: user.nickname,
 105         email: user.email
 106       }
 107     }
 108   end
 109
 110   def render("create-error.json", %{changeset: %Ecto.Changeset{changes: changes, errors: errors}}) do
 111     %{
 112       type: "error",
 113       code: 409,
 114       error: parse_error(errors),
 115       data: %{
 116         nickname: Map.get(changes, :nickname),
 117         email: Map.get(changes, :email)
 118       }
 119     }
 120   end
 121
 122   defp parse_error([]), do: ""
 123
 124   defp parse_error(errors) do
 125     ## when nickname is duplicate ap_id constraint error is raised
 126     nickname_error = Keyword.get(errors, :nickname) || Keyword.get(errors, :ap_id)
 127     email_error = Keyword.get(errors, :email)
 128     password_error = Keyword.get(errors, :password)
 129
 130     cond do
 131       nickname_error ->
 132         "nickname #{elem(nickname_error, 0)}"
 133
 134       email_error ->
 135         "email #{elem(email_error, 0)}"
 136
 137       password_error ->
 138         "password #{elem(password_error, 0)}"
 139
 140       true ->
 141         ""
 142     end
 143   end
 144
 145   defp image_url(%{"url" => [%{"href" => href} | _]}), do: href
 146   defp image_url(_), do: nil
 147 end