git.squeep.com Git - akkoma/blob - lib/pleroma/web/admin_api/views/account_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.AdminAPI.AccountView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.User
   9   alias Pleroma.Web.AdminAPI
  10   alias Pleroma.Web.AdminAPI.AccountView
  11   alias Pleroma.Web.MastodonAPI
  12   alias Pleroma.Web.MediaProxy
  13
  14   def render("index.json", %{users: users, count: count, page_size: page_size}) do
  15     %{
  16       users: render_many(users, AccountView, "show.json", as: :user),
  17       count: count,
  18       page_size: page_size
  19     }
  20   end
  21
  22   def render("index.json", %{users: users}) do
  23     %{
  24       users: render_many(users, AccountView, "show.json", as: :user)
  25     }
  26   end
  27
  28   def render("credentials.json", %{user: user, for: for_user}) do
  29     user = User.sanitize_html(user, User.html_filter_policy(for_user))
  30     avatar = User.avatar_url(user) |> MediaProxy.url()
  31     banner = User.banner_url(user) |> MediaProxy.url()
  32     background = image_url(user.background) |> MediaProxy.url()
  33
  34     user
  35     |> Map.take([
  36       :id,
  37       :bio,
  38       :email,
  39       :fields,
  40       :name,
  41       :nickname,
  42       :locked,
  43       :no_rich_text,
  44       :default_scope,
  45       :hide_follows,
  46       :hide_followers_count,
  47       :hide_follows_count,
  48       :hide_followers,
  49       :hide_favorites,
  50       :allow_following_move,
  51       :show_role,
  52       :skip_thread_containment,
  53       :pleroma_settings_store,
  54       :raw_fields,
  55       :discoverable,
  56       :actor_type
  57     ])
  58     |> Map.merge(%{
  59       "avatar" => avatar,
  60       "banner" => banner,
  61       "background" => background
  62     })
  63   end
  64
  65   def render("show.json", %{user: user}) do
  66     avatar = User.avatar_url(user) |> MediaProxy.url()
  67     display_name = Pleroma.HTML.strip_tags(user.name || user.nickname)
  68     user = User.sanitize_html(user, FastSanitize.Sanitizer.StripTags)
  69
  70     %{
  71       "id" => user.id,
  72       "avatar" => avatar,
  73       "nickname" => user.nickname,
  74       "display_name" => display_name,
  75       "deactivated" => user.deactivated,
  76       "local" => user.local,
  77       "roles" => User.roles(user),
  78       "tags" => user.tags || [],
  79       "confirmation_pending" => user.confirmation_pending,
  80       "approval_pending" => user.approval_pending,
  81       "url" => user.uri || user.ap_id,
  82       "registration_reason" => user.registration_reason,
  83       "actor_type" => user.actor_type
  84     }
  85   end
  86
  87   def render("created.json", %{user: user}) do
  88     %{
  89       type: "success",
  90       code: 200,
  91       data: %{
  92         nickname: user.nickname,
  93         email: user.email
  94       }
  95     }
  96   end
  97
  98   def render("create-error.json", %{changeset: %Ecto.Changeset{changes: changes, errors: errors}}) do
  99     %{
 100       type: "error",
 101       code: 409,
 102       error: parse_error(errors),
 103       data: %{
 104         nickname: Map.get(changes, :nickname),
 105         email: Map.get(changes, :email)
 106       }
 107     }
 108   end
 109
 110   def merge_account_views(%User{} = user) do
 111     MastodonAPI.AccountView.render("show.json", %{user: user, skip_visibility_check: true})
 112     |> Map.merge(AdminAPI.AccountView.render("show.json", %{user: user}))
 113   end
 114
 115   def merge_account_views(_), do: %{}
 116
 117   defp parse_error([]), do: ""
 118
 119   defp parse_error(errors) do
 120     ## when nickname is duplicate ap_id constraint error is raised
 121     nickname_error = Keyword.get(errors, :nickname) || Keyword.get(errors, :ap_id)
 122     email_error = Keyword.get(errors, :email)
 123     password_error = Keyword.get(errors, :password)
 124
 125     cond do
 126       nickname_error ->
 127         "nickname #{elem(nickname_error, 0)}"
 128
 129       email_error ->
 130         "email #{elem(email_error, 0)}"
 131
 132       password_error ->
 133         "password #{elem(password_error, 0)}"
 134
 135       true ->
 136         ""
 137     end
 138   end
 139
 140   defp image_url(%{"url" => [%{"href" => href} | _]}), do: href
 141   defp image_url(_), do: nil
 142 end