git.squeep.com Git - akkoma/blob - lib/pleroma/web/admin_api/config.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.AdminAPI.Config do
   6   use Ecto.Schema
   7   import Ecto.Changeset
   8   import Pleroma.Web.Gettext
   9   alias __MODULE__
  10   alias Pleroma.Repo
  11
  12   @type t :: %__MODULE__{}
  13
  14   schema "config" do
  15     field(:key, :string)
  16     field(:group, :string)
  17     field(:value, :binary)
  18
  19     timestamps()
  20   end
  21
  22   @spec get_by_params(map()) :: Config.t() | nil
  23   def get_by_params(params), do: Repo.get_by(Config, params)
  24
  25   @spec changeset(Config.t(), map()) :: Changeset.t()
  26   def changeset(config, params \\ %{}) do
  27     params = Map.put(params, :value, transform(params[:value]))
  28
  29     config
  30     |> cast(params, [:key, :group, :value])
  31     |> validate_required([:key, :group, :value])
  32     |> unique_constraint(:key, name: :config_group_key_index)
  33   end
  34
  35   @spec create(map()) :: {:ok, Config.t()} | {:error, Changeset.t()}
  36   def create(params) do
  37     %Config{}
  38     |> changeset(params)
  39     |> Repo.insert()
  40   end
  41
  42   @spec update(Config.t(), map()) :: {:ok, Config} | {:error, Changeset.t()}
  43   def update(%Config{} = config, %{value: value}) do
  44     config
  45     |> changeset(%{value: value})
  46     |> Repo.update()
  47   end
  48
  49   @full_key_update [
  50     {:pleroma, :ecto_repos},
  51     {:pleroma, :assets},
  52     {:quack, :meta},
  53     {:mime, :types},
  54     {:cors_plug, [:max_age, :methods, :expose, :headers]},
  55     {:auto_linker, :opts},
  56     {:swarm, :node_blacklist},
  57     {:logger, :backends}
  58   ]
  59
  60   defp only_full_update?(%Config{} = config) do
  61     config_group = Config.from_string(config.group)
  62     config_key = Config.from_string(config.key)
  63
  64     Enum.any?(@full_key_update, fn
  65       {group, key} when is_list(key) ->
  66         config_group == group and config_key in key
  67
  68       {group, key} ->
  69         config_group == group and config_key == key
  70     end)
  71   end
  72
  73   defp can_be_partially_updated?(%Config{} = config), do: not only_full_update?(config)
  74
  75   @spec update_or_create(map()) :: {:ok, Config.t()} | {:error, Changeset.t()}
  76   def update_or_create(params) do
  77     search_opts = Map.take(params, [:group, :key])
  78
  79     with %Config{} = config <- Config.get_by_params(search_opts),
  80          {:partial_update, true, config} <-
  81            {:partial_update, can_be_partially_updated?(config), config},
  82          old_value <- from_binary(config.value),
  83          transformed_value <- do_transform(params[:value]),
  84          {:can_be_merged, true, config} <- {:can_be_merged, is_list(transformed_value), config},
  85          new_value <- DeepMerge.deep_merge(old_value, transformed_value) do
  86       Config.update(config, %{value: new_value, transformed?: true})
  87     else
  88       {reason, false, config} when reason in [:partial_update, :can_be_merged] ->
  89         Config.update(config, params)
  90
  91       nil ->
  92         Config.create(params)
  93     end
  94   end
  95
  96   @spec delete(map()) :: {:ok, Config.t()} | {:error, Changeset.t()} | {:ok, nil}
  97   def delete(params) do
  98     search_opts = Map.delete(params, :subkeys)
  99
 100     with %Config{} = config <- Config.get_by_params(search_opts),
 101          {config, sub_keys} when is_list(sub_keys) <- {config, params[:subkeys]},
 102          old_value <- from_binary(config.value),
 103          keys <- Enum.map(sub_keys, &do_transform_string(&1)),
 104          new_value <- Keyword.drop(old_value, keys) do
 105       Config.update(config, %{value: new_value})
 106     else
 107       {config, nil} ->
 108         Repo.delete(config)
 109         {:ok, nil}
 110
 111       nil ->
 112         err =
 113           dgettext("errors", "Config with params %{params} not found", params: inspect(params))
 114
 115         {:error, err}
 116     end
 117   end
 118
 119   @spec from_binary(binary()) :: term()
 120   def from_binary(binary), do: :erlang.binary_to_term(binary)
 121
 122   @spec from_binary_with_convert(binary()) :: any()
 123   def from_binary_with_convert(binary) do
 124     binary
 125     |> from_binary()
 126     |> do_convert()
 127   end
 128
 129   @spec from_string(String.t()) :: atom() | no_return()
 130   def from_string(":" <> entity), do: String.to_existing_atom(entity)
 131
 132   def from_string(entity) when is_binary(entity) do
 133     if is_module_name?(entity) do
 134       String.to_existing_atom("Elixir.#{entity}")
 135     else
 136       entity
 137     end
 138   end
 139
 140   defp do_convert(entity) when is_list(entity) do
 141     for v <- entity, into: [], do: do_convert(v)
 142   end
 143
 144   defp do_convert(%Regex{} = entity), do: inspect(entity)
 145
 146   defp do_convert(entity) when is_map(entity) do
 147     for {k, v} <- entity, into: %{}, do: {do_convert(k), do_convert(v)}
 148   end
 149
 150   defp do_convert({:proxy_url, {type, :localhost, port}}) do
 151     %{"tuple" => [":proxy_url", %{"tuple" => [do_convert(type), "localhost", port]}]}
 152   end
 153
 154   defp do_convert({:proxy_url, {type, host, port}}) when is_tuple(host) do
 155     ip =
 156       host
 157       |> :inet_parse.ntoa()
 158       |> to_string()
 159
 160     %{
 161       "tuple" => [
 162         ":proxy_url",
 163         %{"tuple" => [do_convert(type), ip, port]}
 164       ]
 165     }
 166   end
 167
 168   defp do_convert({:proxy_url, {type, host, port}}) do
 169     %{
 170       "tuple" => [
 171         ":proxy_url",
 172         %{"tuple" => [do_convert(type), to_string(host), port]}
 173       ]
 174     }
 175   end
 176
 177   defp do_convert({:dispatch, [entity]}), do: %{"tuple" => [":dispatch", [inspect(entity)]]}
 178   # TODO: will become useless after removing hackney
 179   defp do_convert({:partial_chain, entity}), do: %{"tuple" => [":partial_chain", inspect(entity)]}
 180
 181   defp do_convert(entity) when is_tuple(entity),
 182     do: %{"tuple" => do_convert(Tuple.to_list(entity))}
 183
 184   defp do_convert(entity) when is_boolean(entity) or is_number(entity) or is_nil(entity),
 185     do: entity
 186
 187   defp do_convert(entity)
 188        when is_atom(entity) and entity in [:"tlsv1.1", :"tlsv1.2", :"tlsv1.3"] do
 189     ":#{to_string(entity)}"
 190   end
 191
 192   defp do_convert(entity) when is_atom(entity), do: inspect(entity)
 193
 194   defp do_convert(entity) when is_binary(entity), do: entity
 195
 196   @spec transform(any()) :: binary() | no_return()
 197   def transform(entity) when is_binary(entity) or is_map(entity) or is_list(entity) do
 198     entity
 199     |> do_transform()
 200     |> to_binary()
 201   end
 202
 203   def transform(entity), do: to_binary(entity)
 204
 205   @spec to_binary(any()) :: binary()
 206   def to_binary(entity), do: :erlang.term_to_binary(entity)
 207
 208   defp do_transform(%Regex{} = entity), do: entity
 209
 210   defp do_transform(%{"tuple" => [":proxy_url", %{"tuple" => [type, host, port]}]}) do
 211     {:proxy_url, {do_transform_string(type), parse_host(host), port}}
 212   end
 213
 214   defp do_transform(%{"tuple" => [":dispatch", [entity]]}) do
 215     {dispatch_settings, []} = do_eval(entity)
 216     {:dispatch, [dispatch_settings]}
 217   end
 218
 219   # TODO: will become useless after removing hackney
 220   defp do_transform(%{"tuple" => [":partial_chain", entity]}) do
 221     {partial_chain, []} = do_eval(entity)
 222     {:partial_chain, partial_chain}
 223   end
 224
 225   defp do_transform(%{"tuple" => entity}) do
 226     Enum.reduce(entity, {}, fn val, acc -> Tuple.append(acc, do_transform(val)) end)
 227   end
 228
 229   defp do_transform(entity) when is_map(entity) do
 230     for {k, v} <- entity, into: %{}, do: {do_transform(k), do_transform(v)}
 231   end
 232
 233   defp do_transform(entity) when is_list(entity) do
 234     for v <- entity, into: [], do: do_transform(v)
 235   end
 236
 237   defp do_transform(entity) when is_binary(entity) do
 238     entity
 239     |> String.trim()
 240     |> do_transform_string()
 241   end
 242
 243   defp do_transform(entity), do: entity
 244
 245   defp parse_host("localhost"), do: :localhost
 246
 247   defp parse_host(host) do
 248     charlist = to_charlist(host)
 249
 250     case :inet.parse_address(charlist) do
 251       {:error, :einval} ->
 252         charlist
 253
 254       {:ok, ip} ->
 255         ip
 256     end
 257   end
 258
 259   @delimiters ["/", "|", "\"", "'", {"(", ")"}, {"[", "]"}, {"{", "}"}, {"<", ">"}]
 260
 261   defp find_valid_delimiter([], _string, _),
 262     do: raise(ArgumentError, message: "valid delimiter for Regex expression not found")
 263
 264   defp find_valid_delimiter([{leading, closing} = delimiter | others], pattern, regex_delimiter)
 265        when is_tuple(delimiter) do
 266     if String.contains?(pattern, closing) do
 267       find_valid_delimiter(others, pattern, regex_delimiter)
 268     else
 269       {:ok, {leading, closing}}
 270     end
 271   end
 272
 273   defp find_valid_delimiter([delimiter | others], pattern, regex_delimiter) do
 274     if String.contains?(pattern, delimiter) do
 275       find_valid_delimiter(others, pattern, regex_delimiter)
 276     else
 277       {:ok, {delimiter, delimiter}}
 278     end
 279   end
 280
 281   @regex_parts ~r/^~r(?'delimiter'[\/|"'([{<]{1})(?'pattern'.+)[\/|"')\]}>]{1}(?'modifier'[uismxfU]*)/u
 282
 283   defp do_transform_string("~r" <> _pattern = regex) do
 284     with %{"modifier" => modifier, "pattern" => pattern, "delimiter" => regex_delimiter} <-
 285            Regex.named_captures(@regex_parts, regex),
 286          {:ok, {leading, closing}} <- find_valid_delimiter(@delimiters, pattern, regex_delimiter),
 287          {result, _} <- Code.eval_string("~r#{leading}#{pattern}#{closing}#{modifier}") do
 288       result
 289     end
 290   end
 291
 292   defp do_transform_string(":" <> atom), do: String.to_atom(atom)
 293
 294   defp do_transform_string(value) do
 295     if is_module_name?(value) do
 296       String.to_existing_atom("Elixir." <> value)
 297     else
 298       value
 299     end
 300   end
 301
 302   @spec is_module_name?(String.t()) :: boolean()
 303   def is_module_name?(string) do
 304     Regex.match?(~r/^(Pleroma|Phoenix|Tesla|Quack)\./, string) or
 305       string in ["Oban", "Ueberauth", "ExSyslogger"]
 306   end
 307
 308   defp do_eval(entity) do
 309     cleaned_string = String.replace(entity, ~r/[^\w|^{:,[|^,|^[|^\]^}|^\/|^\.|^"]^\s/, "")
 310     Code.eval_string(cleaned_string)
 311   end
 312 end