git.squeep.com Git - akkoma/blob - lib/pleroma/web/admin_api/config.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.AdminAPI.Config do
   6   use Ecto.Schema
   7   import Ecto.Changeset
   8   import Pleroma.Web.Gettext
   9   alias __MODULE__
  10   alias Pleroma.Repo
  11
  12   @type t :: %__MODULE__{}
  13
  14   schema "config" do
  15     field(:key, :string)
  16     field(:group, :string)
  17     field(:value, :binary)
  18
  19     timestamps()
  20   end
  21
  22   @spec get_by_params(map()) :: Config.t() | nil
  23   def get_by_params(params), do: Repo.get_by(Config, params)
  24
  25   @spec changeset(Config.t(), map()) :: Changeset.t()
  26   def changeset(config, params \\ %{}) do
  27     params = Map.put(params, :value, transform(params[:value]))
  28
  29     config
  30     |> cast(params, [:key, :group, :value])
  31     |> validate_required([:key, :group, :value])
  32     |> unique_constraint(:key, name: :config_group_key_index)
  33   end
  34
  35   @spec create(map()) :: {:ok, Config.t()} | {:error, Changeset.t()}
  36   def create(params) do
  37     %Config{}
  38     |> changeset(params)
  39     |> Repo.insert()
  40   end
  41
  42   @spec update(Config.t(), map()) :: {:ok, Config} | {:error, Changeset.t()}
  43   def update(%Config{} = config, %{value: value}) do
  44     config
  45     |> changeset(%{value: value})
  46     |> Repo.update()
  47   end
  48
  49   @full_key_update [
  50     {:pleroma, :ecto_repos},
  51     {:quack, :meta},
  52     {:mime, :types},
  53     {:cors_plug, [:max_age, :methods, :expose, :headers]},
  54     {:auto_linker, :opts},
  55     {:swarm, :node_blacklist}
  56   ]
  57
  58   defp only_full_update?(%Config{} = config) do
  59     config_group = Config.from_string(config.group)
  60     config_key = Config.from_string(config.key)
  61
  62     Enum.any?(@full_key_update, fn
  63       {group, key} when is_list(key) ->
  64         config_group == group and config_key in key
  65
  66       {group, key} ->
  67         config_group == group and config_key == key
  68     end)
  69   end
  70
  71   defp can_be_partially_updated?(%Config{} = config), do: not only_full_update?(config)
  72
  73   @spec update_or_create(map()) :: {:ok, Config.t()} | {:error, Changeset.t()}
  74   def update_or_create(params) do
  75     search_opts = Map.take(params, [:group, :key])
  76
  77     with %Config{} = config <- Config.get_by_params(search_opts),
  78          {:partial_update, true, config} <-
  79            {:partial_update, can_be_partially_updated?(config), config},
  80          old_value <- from_binary(config.value),
  81          transformed_value <- do_transform(params[:value]),
  82          {:can_be_merged, true, config} <- {:can_be_merged, is_list(transformed_value), config},
  83          new_value <- Keyword.merge(old_value, transformed_value) do
  84       Config.update(config, %{value: new_value, transformed?: true})
  85     else
  86       {reason, false, config} when reason in [:partial_update, :can_be_merged] ->
  87         Config.update(config, params)
  88
  89       nil ->
  90         Config.create(params)
  91     end
  92   end
  93
  94   @spec delete(map()) :: {:ok, Config.t()} | {:error, Changeset.t()} | {:ok, nil}
  95   def delete(params) do
  96     search_opts = Map.delete(params, :subkeys)
  97
  98     with %Config{} = config <- Config.get_by_params(search_opts),
  99          {config, sub_keys} when is_list(sub_keys) <- {config, params[:subkeys]},
 100          old_value <- from_binary(config.value),
 101          keys <- Enum.map(sub_keys, &do_transform_string(&1)),
 102          new_value <- Keyword.drop(old_value, keys) do
 103       Config.update(config, %{value: new_value})
 104     else
 105       {config, nil} ->
 106         Repo.delete(config)
 107         {:ok, nil}
 108
 109       nil ->
 110         err =
 111           dgettext("errors", "Config with params %{params} not found", params: inspect(params))
 112
 113         {:error, err}
 114     end
 115   end
 116
 117   @spec from_binary(binary()) :: term()
 118   def from_binary(binary), do: :erlang.binary_to_term(binary)
 119
 120   @spec from_binary_with_convert(binary()) :: any()
 121   def from_binary_with_convert(binary) do
 122     binary
 123     |> from_binary()
 124     |> do_convert()
 125   end
 126
 127   @spec from_string(String.t()) :: atom() | no_return()
 128   def from_string(":" <> entity), do: String.to_existing_atom(entity)
 129
 130   def from_string(entity) when is_binary(entity) do
 131     if is_module_name?(entity) do
 132       String.to_existing_atom("Elixir.#{entity}")
 133     else
 134       entity
 135     end
 136   end
 137
 138   defp do_convert(entity) when is_list(entity) do
 139     for v <- entity, into: [], do: do_convert(v)
 140   end
 141
 142   defp do_convert(%Regex{} = entity), do: inspect(entity)
 143
 144   defp do_convert(entity) when is_map(entity) do
 145     for {k, v} <- entity, into: %{}, do: {do_convert(k), do_convert(v)}
 146   end
 147
 148   defp do_convert({:proxy_url, {type, :localhost, port}}) do
 149     %{"tuple" => [":proxy_url", %{"tuple" => [do_convert(type), "localhost", port]}]}
 150   end
 151
 152   defp do_convert({:proxy_url, {type, host, port}}) when is_tuple(host) do
 153     ip =
 154       host
 155       |> :inet_parse.ntoa()
 156       |> to_string()
 157
 158     %{
 159       "tuple" => [
 160         ":proxy_url",
 161         %{"tuple" => [do_convert(type), ip, port]}
 162       ]
 163     }
 164   end
 165
 166   defp do_convert({:proxy_url, {type, host, port}}) do
 167     %{
 168       "tuple" => [
 169         ":proxy_url",
 170         %{"tuple" => [do_convert(type), to_string(host), port]}
 171       ]
 172     }
 173   end
 174
 175   defp do_convert({:dispatch, [entity]}), do: %{"tuple" => [":dispatch", [inspect(entity)]]}
 176   # TODO: will become useless after removing hackney
 177   defp do_convert({:partial_chain, entity}), do: %{"tuple" => [":partial_chain", inspect(entity)]}
 178
 179   defp do_convert(entity) when is_tuple(entity),
 180     do: %{"tuple" => do_convert(Tuple.to_list(entity))}
 181
 182   defp do_convert(entity) when is_boolean(entity) or is_number(entity) or is_nil(entity),
 183     do: entity
 184
 185   defp do_convert(entity) when is_atom(entity), do: inspect(entity)
 186
 187   defp do_convert(entity) when is_binary(entity), do: entity
 188
 189   @spec transform(any()) :: binary() | no_return()
 190   def transform(entity) when is_binary(entity) or is_map(entity) or is_list(entity) do
 191     entity
 192     |> do_transform()
 193     |> to_binary()
 194   end
 195
 196   def transform(entity), do: to_binary(entity)
 197
 198   @spec to_binary(any()) :: binary()
 199   def to_binary(entity), do: :erlang.term_to_binary(entity)
 200
 201   defp do_transform(%Regex{} = entity), do: entity
 202
 203   defp do_transform(%{"tuple" => [":proxy_url", %{"tuple" => [type, host, port]}]}) do
 204     {:proxy_url, {do_transform_string(type), parse_host(host), port}}
 205   end
 206
 207   defp do_transform(%{"tuple" => [":dispatch", [entity]]}) do
 208     {dispatch_settings, []} = do_eval(entity)
 209     {:dispatch, [dispatch_settings]}
 210   end
 211
 212   # TODO: will become useless after removing hackney
 213   defp do_transform(%{"tuple" => [":partial_chain", entity]}) do
 214     {partial_chain, []} = do_eval(entity)
 215     {:partial_chain, partial_chain}
 216   end
 217
 218   defp do_transform(%{"tuple" => entity}) do
 219     Enum.reduce(entity, {}, fn val, acc -> Tuple.append(acc, do_transform(val)) end)
 220   end
 221
 222   defp do_transform(entity) when is_map(entity) do
 223     for {k, v} <- entity, into: %{}, do: {do_transform(k), do_transform(v)}
 224   end
 225
 226   defp do_transform(entity) when is_list(entity) do
 227     for v <- entity, into: [], do: do_transform(v)
 228   end
 229
 230   defp do_transform(entity) when is_binary(entity) do
 231     entity
 232     |> String.trim()
 233     |> do_transform_string()
 234   end
 235
 236   defp do_transform(entity), do: entity
 237
 238   defp parse_host("localhost"), do: :localhost
 239
 240   defp parse_host(host) do
 241     charlist = to_charlist(host)
 242
 243     case :inet.parse_address(charlist) do
 244       {:error, :einval} ->
 245         charlist
 246
 247       {:ok, ip} ->
 248         ip
 249     end
 250   end
 251
 252   @delimiters ["/", "|", "\"", "'", {"(", ")"}, {"[", "]"}, {"{", "}"}, {"<", ">"}]
 253
 254   defp find_valid_delimiter([], _string, _),
 255     do: raise(ArgumentError, message: "valid delimiter for Regex expression not found")
 256
 257   defp find_valid_delimiter([{leading, closing} = delimiter | others], pattern, regex_delimiter)
 258        when is_tuple(delimiter) do
 259     if String.contains?(pattern, closing) do
 260       find_valid_delimiter(others, pattern, regex_delimiter)
 261     else
 262       {:ok, {leading, closing}}
 263     end
 264   end
 265
 266   defp find_valid_delimiter([delimiter | others], pattern, regex_delimiter) do
 267     if String.contains?(pattern, delimiter) do
 268       find_valid_delimiter(others, pattern, regex_delimiter)
 269     else
 270       {:ok, {delimiter, delimiter}}
 271     end
 272   end
 273
 274   @regex_parts ~r/^~r(?'delimiter'[\/|"'([{<]{1})(?'pattern'.+)[\/|"')\]}>]{1}(?'modifier'[uismxfU]*)/u
 275
 276   defp do_transform_string("~r" <> _pattern = regex) do
 277     with %{"modifier" => modifier, "pattern" => pattern, "delimiter" => regex_delimiter} <-
 278            Regex.named_captures(@regex_parts, regex),
 279          {:ok, {leading, closing}} <- find_valid_delimiter(@delimiters, pattern, regex_delimiter),
 280          {result, _} <- Code.eval_string("~r#{leading}#{pattern}#{closing}#{modifier}") do
 281       result
 282     end
 283   end
 284
 285   defp do_transform_string(":" <> atom), do: String.to_atom(atom)
 286
 287   defp do_transform_string(value) do
 288     if is_module_name?(value) do
 289       String.to_existing_atom("Elixir." <> value)
 290     else
 291       value
 292     end
 293   end
 294
 295   @spec is_module_name?(String.t()) :: boolean()
 296   def is_module_name?(string) do
 297     Regex.match?(~r/^(Pleroma|Phoenix|Tesla)\./, string) or string in ["Oban", "Ueberauth"]
 298   end
 299
 300   defp do_eval(entity) do
 301     cleaned_string = String.replace(entity, ~r/[^\w|^{:,[|^,|^[|^\]^}|^\/|^\.|^"]^\s/, "")
 302     Code.eval_string(cleaned_string)
 303   end
 304 end