git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/visibility.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.Visibility do
   6   alias Pleroma.Activity
   7   alias Pleroma.Object
   8   alias Pleroma.Repo
   9   alias Pleroma.User
  10   alias Pleroma.Web.ActivityPub.Utils
  11
  12   require Pleroma.Constants
  13
  14   @spec is_public?(Object.t() | Activity.t() | map()) :: boolean()
  15   def is_public?(%Object{data: %{"type" => "Tombstone"}}), do: false
  16   def is_public?(%Object{data: data}), do: is_public?(data)
  17   def is_public?(%Activity{data: %{"type" => "Move"}}), do: true
  18   def is_public?(%Activity{data: data}), do: is_public?(data)
  19   def is_public?(%{"directMessage" => true}), do: false
  20
  21   def is_public?(data) do
  22     Utils.label_in_message?(Pleroma.Constants.as_public(), data) or
  23       Utils.label_in_message?(Pleroma.Constants.as_local_public(), data)
  24   end
  25
  26   def is_local_public?(%Object{data: data}), do: is_local_public?(data)
  27   def is_local_public?(%Activity{data: data}), do: is_local_public?(data)
  28
  29   def is_local_public?(data) do
  30     Utils.label_in_message?(Pleroma.Constants.as_local_public(), data) and
  31       not Utils.label_in_message?(Pleroma.Constants.as_public(), data)
  32   end
  33
  34   def is_private?(activity) do
  35     with false <- is_public?(activity),
  36          %User{follower_address: follower_address} <-
  37            User.get_cached_by_ap_id(activity.data["actor"]) do
  38       follower_address in activity.data["to"]
  39     else
  40       _ -> false
  41     end
  42   end
  43
  44   def is_announceable?(activity, user, public \\ true) do
  45     is_public?(activity) ||
  46       (!public && is_private?(activity) && activity.data["actor"] == user.ap_id)
  47   end
  48
  49   def is_direct?(%Activity{data: %{"directMessage" => true}}), do: true
  50   def is_direct?(%Object{data: %{"directMessage" => true}}), do: true
  51
  52   def is_direct?(activity) do
  53     !is_public?(activity) && !is_private?(activity)
  54   end
  55
  56   def is_list?(%{data: %{"listMessage" => _}}), do: true
  57   def is_list?(_), do: false
  58
  59   @spec visible_for_user?(Activity.t() | nil, User.t() | nil) :: boolean()
  60   def visible_for_user?(%Activity{actor: ap_id}, %User{ap_id: ap_id}), do: true
  61
  62   def visible_for_user?(nil, _), do: false
  63
  64   def visible_for_user?(%Activity{data: %{"listMessage" => _}}, nil), do: false
  65
  66   def visible_for_user?(
  67         %Activity{data: %{"listMessage" => list_ap_id}} = activity,
  68         %User{} = user
  69       ) do
  70     user.ap_id in activity.data["to"] ||
  71       list_ap_id
  72       |> Pleroma.List.get_by_ap_id()
  73       |> Pleroma.List.member?(user)
  74   end
  75
  76   def visible_for_user?(%Activity{} = activity, nil) do
  77     if restrict_unauthenticated_access?(activity),
  78       do: false,
  79       else: is_public?(activity)
  80   end
  81
  82   def visible_for_user?(%Activity{} = activity, user) do
  83     x = [user.ap_id | User.following(user)]
  84     y = [activity.actor] ++ activity.data["to"] ++ (activity.data["cc"] || [])
  85     is_public?(activity) || Enum.any?(x, &(&1 in y))
  86   end
  87
  88   def entire_thread_visible_for_user?(%Activity{} = activity, %User{} = user) do
  89     {:ok, %{rows: [[result]]}} =
  90       Ecto.Adapters.SQL.query(Repo, "SELECT thread_visibility($1, $2)", [
  91         user.ap_id,
  92         activity.data["id"]
  93       ])
  94
  95     result
  96   end
  97
  98   def restrict_unauthenticated_access?(%Activity{local: local}) do
  99     restrict_unauthenticated_access_to_activity?(local)
 100   end
 101
 102   def restrict_unauthenticated_access?(%Object{} = object) do
 103     object
 104     |> Object.local?()
 105     |> restrict_unauthenticated_access_to_activity?()
 106   end
 107
 108   def restrict_unauthenticated_access?(%User{} = user) do
 109     User.visible_for(user, _reading_user = nil)
 110   end
 111
 112   defp restrict_unauthenticated_access_to_activity?(local?) when is_boolean(local?) do
 113     cfg_key = if local?, do: :local, else: :remote
 114
 115     Pleroma.Config.restrict_unauthenticated_access?(:activities, cfg_key)
 116   end
 117
 118   def get_visibility(object) do
 119     to = object.data["to"] || []
 120     cc = object.data["cc"] || []
 121
 122     cond do
 123       Pleroma.Constants.as_public() in to ->
 124         "public"
 125
 126       Pleroma.Constants.as_public() in cc ->
 127         "unlisted"
 128
 129       Pleroma.Constants.as_local_public() in to ->
 130         "local"
 131
 132       # this should use the sql for the object's activity
 133       Enum.any?(to, &String.contains?(&1, "/followers")) ->
 134         "private"
 135
 136       object.data["directMessage"] == true ->
 137         "direct"
 138
 139       is_binary(object.data["listMessage"]) ->
 140         "list"
 141
 142       length(cc) > 0 ->
 143         "private"
 144
 145       true ->
 146         "direct"
 147     end
 148   end
 149 end