git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/visibility.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.Visibility do
   6   alias Pleroma.Activity
   7   alias Pleroma.Object
   8   alias Pleroma.Repo
   9   alias Pleroma.User
  10   alias Pleroma.Web.ActivityPub.Utils
  11
  12   require Pleroma.Constants
  13
  14   @spec is_public?(Object.t() | Activity.t() | map()) :: boolean()
  15   def is_public?(%Object{data: %{"type" => "Tombstone"}}), do: false
  16   def is_public?(%Object{data: data}), do: is_public?(data)
  17   def is_public?(%Activity{data: %{"type" => "Move"}}), do: true
  18   def is_public?(%Activity{data: data}), do: is_public?(data)
  19   def is_public?(%{"directMessage" => true}), do: false
  20   def is_public?(data), do: Utils.label_in_message?(Pleroma.Constants.as_public(), data)
  21
  22   def is_private?(activity) do
  23     with false <- is_public?(activity),
  24          %User{follower_address: follower_address} <-
  25            User.get_cached_by_ap_id(activity.data["actor"]) do
  26       follower_address in activity.data["to"]
  27     else
  28       _ -> false
  29     end
  30   end
  31
  32   def is_announceable?(activity, user, public \\ true) do
  33     is_public?(activity) ||
  34       (!public && is_private?(activity) && activity.data["actor"] == user.ap_id)
  35   end
  36
  37   def is_direct?(%Activity{data: %{"directMessage" => true}}), do: true
  38   def is_direct?(%Object{data: %{"directMessage" => true}}), do: true
  39
  40   def is_direct?(activity) do
  41     !is_public?(activity) && !is_private?(activity)
  42   end
  43
  44   def is_list?(%{data: %{"listMessage" => _}}), do: true
  45   def is_list?(_), do: false
  46
  47   @spec visible_for_user?(Activity.t(), User.t() | nil) :: boolean()
  48   def visible_for_user?(%{actor: ap_id}, %User{ap_id: ap_id}), do: true
  49
  50   def visible_for_user?(nil, _), do: false
  51
  52   def visible_for_user?(%{data: %{"listMessage" => _}}, nil), do: false
  53
  54   def visible_for_user?(%{data: %{"listMessage" => list_ap_id}} = activity, %User{} = user) do
  55     user.ap_id in activity.data["to"] ||
  56       list_ap_id
  57       |> Pleroma.List.get_by_ap_id()
  58       |> Pleroma.List.member?(user)
  59   end
  60
  61   def visible_for_user?(%{local: local} = activity, nil) do
  62     cfg_key = if local, do: :local, else: :remote
  63
  64     if Pleroma.Config.restrict_unauthenticated_access?(:activities, cfg_key),
  65       do: false,
  66       else: is_public?(activity)
  67   end
  68
  69   def visible_for_user?(activity, user) do
  70     x = [user.ap_id | User.following(user)]
  71     y = [activity.actor] ++ activity.data["to"] ++ (activity.data["cc"] || [])
  72     is_public?(activity) || Enum.any?(x, &(&1 in y))
  73   end
  74
  75   def entire_thread_visible_for_user?(%Activity{} = activity, %User{} = user) do
  76     {:ok, %{rows: [[result]]}} =
  77       Ecto.Adapters.SQL.query(Repo, "SELECT thread_visibility($1, $2)", [
  78         user.ap_id,
  79         activity.data["id"]
  80       ])
  81
  82     result
  83   end
  84
  85   def get_visibility(object) do
  86     to = object.data["to"] || []
  87     cc = object.data["cc"] || []
  88
  89     cond do
  90       Pleroma.Constants.as_public() in to ->
  91         "public"
  92
  93       Pleroma.Constants.as_public() in cc ->
  94         "unlisted"
  95
  96       # this should use the sql for the object's activity
  97       Enum.any?(to, &String.contains?(&1, "/followers")) ->
  98         "private"
  99
 100       object.data["directMessage"] == true ->
 101         "direct"
 102
 103       is_binary(object.data["listMessage"]) ->
 104         "list"
 105
 106       length(cc) > 0 ->
 107         "private"
 108
 109       true ->
 110         "direct"
 111     end
 112   end
 113 end