git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/views/user_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.UserView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.Keys
   9   alias Pleroma.Repo
  10   alias Pleroma.User
  11   alias Pleroma.Web.ActivityPub.Transmogrifier
  12   alias Pleroma.Web.ActivityPub.Utils
  13   alias Pleroma.Web.Endpoint
  14   alias Pleroma.Web.Router.Helpers
  15
  16   import Ecto.Query
  17
  18   def render("endpoints.json", %{user: %User{nickname: nil, local: true} = _user}) do
  19     %{"sharedInbox" => Helpers.activity_pub_url(Endpoint, :inbox)}
  20   end
  21
  22   def render("endpoints.json", %{user: %User{local: true} = _user}) do
  23     %{
  24       "oauthAuthorizationEndpoint" => Helpers.o_auth_url(Endpoint, :authorize),
  25       "oauthRegistrationEndpoint" => Helpers.app_url(Endpoint, :create),
  26       "oauthTokenEndpoint" => Helpers.o_auth_url(Endpoint, :token_exchange),
  27       "sharedInbox" => Helpers.activity_pub_url(Endpoint, :inbox),
  28       "uploadMedia" => Helpers.activity_pub_url(Endpoint, :upload_media)
  29     }
  30   end
  31
  32   def render("endpoints.json", _), do: %{}
  33
  34   def render("service.json", %{user: user}) do
  35     {:ok, user} = User.ensure_keys_present(user)
  36     {:ok, _, public_key} = Keys.keys_from_pem(user.keys)
  37     public_key = :public_key.pem_entry_encode(:SubjectPublicKeyInfo, public_key)
  38     public_key = :public_key.pem_encode([public_key])
  39
  40     endpoints = render("endpoints.json", %{user: user})
  41
  42     %{
  43       "id" => user.ap_id,
  44       "type" => "Application",
  45       "following" => "#{user.ap_id}/following",
  46       "followers" => "#{user.ap_id}/followers",
  47       "inbox" => "#{user.ap_id}/inbox",
  48       "name" => "Pleroma",
  49       "summary" =>
  50         "An internal service actor for this Pleroma instance.  No user-serviceable parts inside.",
  51       "url" => user.ap_id,
  52       "manuallyApprovesFollowers" => false,
  53       "publicKey" => %{
  54         "id" => "#{user.ap_id}#main-key",
  55         "owner" => user.ap_id,
  56         "publicKeyPem" => public_key
  57       },
  58       "endpoints" => endpoints,
  59       "invisible" => User.invisible?(user)
  60     }
  61     |> Map.merge(Utils.make_json_ld_header())
  62   end
  63
  64   # the instance itself is not a Person, but instead an Application
  65   def render("user.json", %{user: %User{nickname: nil} = user}),
  66     do: render("service.json", %{user: user})
  67
  68   def render("user.json", %{user: %User{nickname: "internal." <> _} = user}),
  69     do: render("service.json", %{user: user}) |> Map.put("preferredUsername", user.nickname)
  70
  71   def render("user.json", %{user: user}) do
  72     {:ok, user} = User.ensure_keys_present(user)
  73     {:ok, _, public_key} = Keys.keys_from_pem(user.keys)
  74     public_key = :public_key.pem_entry_encode(:SubjectPublicKeyInfo, public_key)
  75     public_key = :public_key.pem_encode([public_key])
  76     user = User.sanitize_html(user)
  77
  78     endpoints = render("endpoints.json", %{user: user})
  79
  80     emoji_tags = Transmogrifier.take_emoji_tags(user)
  81
  82     fields = Enum.map(user.fields, &Map.put(&1, "type", "PropertyValue"))
  83
  84     capabilities =
  85       if is_boolean(user.accepts_chat_messages) do
  86         %{
  87           "acceptsChatMessages" => user.accepts_chat_messages
  88         }
  89       else
  90         %{}
  91       end
  92
  93     %{
  94       "id" => user.ap_id,
  95       "type" => user.actor_type,
  96       "following" => "#{user.ap_id}/following",
  97       "followers" => "#{user.ap_id}/followers",
  98       "inbox" => "#{user.ap_id}/inbox",
  99       "outbox" => "#{user.ap_id}/outbox",
 100       "preferredUsername" => user.nickname,
 101       "name" => user.name,
 102       "summary" => user.bio,
 103       "url" => user.ap_id,
 104       "manuallyApprovesFollowers" => user.is_locked,
 105       "publicKey" => %{
 106         "id" => "#{user.ap_id}#main-key",
 107         "owner" => user.ap_id,
 108         "publicKeyPem" => public_key
 109       },
 110       "endpoints" => endpoints,
 111       "attachment" => fields,
 112       "tag" => emoji_tags,
 113       "discoverable" => user.discoverable,
 114       "capabilities" => capabilities
 115     }
 116     |> Map.merge(maybe_make_image(&User.avatar_url/2, "icon", user))
 117     |> Map.merge(maybe_make_image(&User.banner_url/2, "image", user))
 118     |> Map.merge(Utils.make_json_ld_header())
 119   end
 120
 121   def render("following.json", %{user: user, page: page} = opts) do
 122     showing_items = (opts[:for] && opts[:for] == user) || !user.hide_follows
 123     showing_count = showing_items || !user.hide_follows_count
 124
 125     query = User.get_friends_query(user)
 126     query = from(user in query, select: [:ap_id])
 127     following = Repo.all(query)
 128
 129     total =
 130       if showing_count do
 131         length(following)
 132       else
 133         0
 134       end
 135
 136     collection(following, "#{user.ap_id}/following", page, showing_items, total)
 137     |> Map.merge(Utils.make_json_ld_header())
 138   end
 139
 140   def render("following.json", %{user: user} = opts) do
 141     showing_items = (opts[:for] && opts[:for] == user) || !user.hide_follows
 142     showing_count = showing_items || !user.hide_follows_count
 143
 144     query = User.get_friends_query(user)
 145     query = from(user in query, select: [:ap_id])
 146     following = Repo.all(query)
 147
 148     total =
 149       if showing_count do
 150         length(following)
 151       else
 152         0
 153       end
 154
 155     %{
 156       "id" => "#{user.ap_id}/following",
 157       "type" => "OrderedCollection",
 158       "totalItems" => total,
 159       "first" =>
 160         if showing_items do
 161           collection(following, "#{user.ap_id}/following", 1, !user.hide_follows)
 162         else
 163           "#{user.ap_id}/following?page=1"
 164         end
 165     }
 166     |> Map.merge(Utils.make_json_ld_header())
 167   end
 168
 169   def render("followers.json", %{user: user, page: page} = opts) do
 170     showing_items = (opts[:for] && opts[:for] == user) || !user.hide_followers
 171     showing_count = showing_items || !user.hide_followers_count
 172
 173     query = User.get_followers_query(user)
 174     query = from(user in query, select: [:ap_id])
 175     followers = Repo.all(query)
 176
 177     total =
 178       if showing_count do
 179         length(followers)
 180       else
 181         0
 182       end
 183
 184     collection(followers, "#{user.ap_id}/followers", page, showing_items, total)
 185     |> Map.merge(Utils.make_json_ld_header())
 186   end
 187
 188   def render("followers.json", %{user: user} = opts) do
 189     showing_items = (opts[:for] && opts[:for] == user) || !user.hide_followers
 190     showing_count = showing_items || !user.hide_followers_count
 191
 192     query = User.get_followers_query(user)
 193     query = from(user in query, select: [:ap_id])
 194     followers = Repo.all(query)
 195
 196     total =
 197       if showing_count do
 198         length(followers)
 199       else
 200         0
 201       end
 202
 203     %{
 204       "id" => "#{user.ap_id}/followers",
 205       "type" => "OrderedCollection",
 206       "first" =>
 207         if showing_items do
 208           collection(followers, "#{user.ap_id}/followers", 1, showing_items, total)
 209         else
 210           "#{user.ap_id}/followers?page=1"
 211         end
 212     }
 213     |> maybe_put_total_items(showing_count, total)
 214     |> Map.merge(Utils.make_json_ld_header())
 215   end
 216
 217   def render("activity_collection.json", %{iri: iri}) do
 218     %{
 219       "id" => iri,
 220       "type" => "OrderedCollection",
 221       "first" => "#{iri}?page=true"
 222     }
 223     |> Map.merge(Utils.make_json_ld_header())
 224   end
 225
 226   def render("activity_collection_page.json", %{
 227         activities: activities,
 228         iri: iri,
 229         pagination: pagination
 230       }) do
 231     collection =
 232       Enum.map(activities, fn activity ->
 233         {:ok, data} = Transmogrifier.prepare_outgoing(activity.data)
 234         data
 235       end)
 236
 237     %{
 238       "type" => "OrderedCollectionPage",
 239       "partOf" => iri,
 240       "orderedItems" => collection
 241     }
 242     |> Map.merge(Utils.make_json_ld_header())
 243     |> Map.merge(pagination)
 244   end
 245
 246   defp maybe_put_total_items(map, false, _total), do: map
 247
 248   defp maybe_put_total_items(map, true, total) do
 249     Map.put(map, "totalItems", total)
 250   end
 251
 252   def collection(collection, iri, page, show_items \\ true, total \\ nil) do
 253     offset = (page - 1) * 10
 254     items = Enum.slice(collection, offset, 10)
 255     items = Enum.map(items, fn user -> user.ap_id end)
 256     total = total || length(collection)
 257
 258     map = %{
 259       "id" => "#{iri}?page=#{page}",
 260       "type" => "OrderedCollectionPage",
 261       "partOf" => iri,
 262       "totalItems" => total,
 263       "orderedItems" => if(show_items, do: items, else: [])
 264     }
 265
 266     if offset < total do
 267       Map.put(map, "next", "#{iri}?page=#{page + 1}")
 268     else
 269       map
 270     end
 271   end
 272
 273   defp maybe_make_image(func, key, user) do
 274     if image = func.(user, no_default: true) do
 275       %{
 276         key => %{
 277           "type" => "Image",
 278           "url" => image
 279         }
 280       }
 281     else
 282       %{}
 283     end
 284   end
 285 end