git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/views/object_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectView do
   6   use Pleroma.Web, :view
   7   alias Pleroma.Activity
   8   alias Pleroma.Object
   9   alias Pleroma.Web.ActivityPub.Transmogrifier
  10
  11   def render("object.json", %{object: %Object{} = object}) do
  12     base = Pleroma.Web.ActivityPub.Utils.make_json_ld_header()
  13
  14     additional = Transmogrifier.prepare_object(object.data)
  15     Map.merge(base, additional)
  16   end
  17
  18   def render("object.json", %{object: %Activity{data: %{"type" => activity_type}} = activity})
  19       when activity_type in ["Create", "Listen"] do
  20     base = Pleroma.Web.ActivityPub.Utils.make_json_ld_header()
  21     object = Object.normalize(activity)
  22
  23     additional =
  24       Transmogrifier.prepare_object(activity.data)
  25       |> Map.put("object", Transmogrifier.prepare_object(object.data))
  26
  27     Map.merge(base, additional)
  28   end
  29
  30   def render("object.json", %{object: %Activity{} = activity}) do
  31     base = Pleroma.Web.ActivityPub.Utils.make_json_ld_header()
  32     object = Object.normalize(activity)
  33
  34     additional =
  35       Transmogrifier.prepare_object(activity.data)
  36       |> Map.put("object", object.data["id"])
  37
  38     Map.merge(base, additional)
  39   end
  40
  41   def render("likes.json", %{ap_id: ap_id, likes: likes, page: page}) do
  42     collection(likes, "#{ap_id}/likes", page)
  43     |> Map.merge(Pleroma.Web.ActivityPub.Utils.make_json_ld_header())
  44   end
  45
  46   def render("likes.json", %{ap_id: ap_id, likes: likes}) do
  47     %{
  48       "id" => "#{ap_id}/likes",
  49       "type" => "OrderedCollection",
  50       "totalItems" => length(likes),
  51       "first" => collection(likes, "#{ap_id}/likes", 1)
  52     }
  53     |> Map.merge(Pleroma.Web.ActivityPub.Utils.make_json_ld_header())
  54   end
  55
  56   def collection(collection, iri, page) do
  57     offset = (page - 1) * 10
  58     items = Enum.slice(collection, offset, 10)
  59     items = Enum.map(items, fn object -> Transmogrifier.prepare_object(object.data) end)
  60     total = length(collection)
  61
  62     map = %{
  63       "id" => "#{iri}?page=#{page}",
  64       "type" => "OrderedCollectionPage",
  65       "partOf" => iri,
  66       "totalItems" => total,
  67       "orderedItems" => items
  68     }
  69
  70     if offset + length(items) < total do
  71       Map.put(map, "next", "#{iri}?page=#{page + 1}")
  72     else
  73       map
  74     end
  75   end
  76 end