git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/views/object_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectView do
   6   use Pleroma.Web, :view
   7   alias Pleroma.Activity
   8   alias Pleroma.Object
   9   alias Pleroma.Web.ActivityPub.Transmogrifier
  10
  11   def render("object.json", %{object: %Object{} = object}) do
  12     base = Pleroma.Web.ActivityPub.Utils.make_json_ld_header()
  13
  14     additional = Transmogrifier.prepare_object(object.data)
  15     Map.merge(base, additional)
  16   end
  17
  18   def render("object.json", %{object: %Activity{data: %{"type" => "Create"}} = activity}) do
  19     base = Pleroma.Web.ActivityPub.Utils.make_json_ld_header()
  20     object = Object.normalize(activity)
  21
  22     additional =
  23       Transmogrifier.prepare_object(activity.data)
  24       |> Map.put("object", Transmogrifier.prepare_object(object.data))
  25
  26     Map.merge(base, additional)
  27   end
  28
  29   def render("object.json", %{object: %Activity{} = activity}) do
  30     base = Pleroma.Web.ActivityPub.Utils.make_json_ld_header()
  31     object = Object.normalize(activity)
  32
  33     additional =
  34       Transmogrifier.prepare_object(activity.data)
  35       |> Map.put("object", object.data["id"])
  36
  37     Map.merge(base, additional)
  38   end
  39
  40   def render("likes.json", %{ap_id: ap_id, likes: likes, page: page}) do
  41     collection(likes, "#{ap_id}/likes", page)
  42     |> Map.merge(Pleroma.Web.ActivityPub.Utils.make_json_ld_header())
  43   end
  44
  45   def render("likes.json", %{ap_id: ap_id, likes: likes}) do
  46     %{
  47       "id" => "#{ap_id}/likes",
  48       "type" => "OrderedCollection",
  49       "totalItems" => length(likes),
  50       "first" => collection(likes, "#{ap_id}/likes", 1)
  51     }
  52     |> Map.merge(Pleroma.Web.ActivityPub.Utils.make_json_ld_header())
  53   end
  54
  55   def collection(collection, iri, page) do
  56     offset = (page - 1) * 10
  57     items = Enum.slice(collection, offset, 10)
  58     items = Enum.map(items, fn object -> Transmogrifier.prepare_object(object.data) end)
  59     total = length(collection)
  60
  61     map = %{
  62       "id" => "#{iri}?page=#{page}",
  63       "type" => "OrderedCollectionPage",
  64       "partOf" => iri,
  65       "totalItems" => total,
  66       "orderedItems" => items
  67     }
  68
  69     if offset + length(items) < total do
  70       Map.put(map, "next", "#{iri}?page=#{page + 1}")
  71     else
  72       map
  73     end
  74   end
  75 end