git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/transmogrifier.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.Transmogrifier do
   6   @moduledoc """
   7   A module to handle coding from internal to wire ActivityPub and back.
   8   """
   9   alias Pleroma.Activity
  10   alias Pleroma.EarmarkRenderer
  11   alias Pleroma.EctoType.ActivityPub.ObjectValidators
  12   alias Pleroma.FollowingRelationship
  13   alias Pleroma.Maps
  14   alias Pleroma.Notification
  15   alias Pleroma.Object
  16   alias Pleroma.Object.Containment
  17   alias Pleroma.Repo
  18   alias Pleroma.User
  19   alias Pleroma.Web.ActivityPub.ActivityPub
  20   alias Pleroma.Web.ActivityPub.Builder
  21   alias Pleroma.Web.ActivityPub.ObjectValidator
  22   alias Pleroma.Web.ActivityPub.Pipeline
  23   alias Pleroma.Web.ActivityPub.Utils
  24   alias Pleroma.Web.ActivityPub.Visibility
  25   alias Pleroma.Web.Federator
  26   alias Pleroma.Workers.TransmogrifierWorker
  27
  28   import Ecto.Query
  29
  30   require Logger
  31   require Pleroma.Constants
  32
  33   @doc """
  34   Modifies an incoming AP object (mastodon format) to our internal format.
  35   """
  36   def fix_object(object, options \\ []) do
  37     object
  38     |> strip_internal_fields
  39     |> fix_actor
  40     |> fix_url
  41     |> fix_attachments
  42     |> fix_context
  43     |> fix_in_reply_to(options)
  44     |> fix_emoji
  45     |> fix_tag
  46     |> fix_content_map
  47     |> fix_addressing
  48     |> fix_summary
  49     |> fix_type(options)
  50     |> fix_content
  51   end
  52
  53   def fix_summary(%{"summary" => nil} = object) do
  54     Map.put(object, "summary", "")
  55   end
  56
  57   def fix_summary(%{"summary" => _} = object) do
  58     # summary is present, nothing to do
  59     object
  60   end
  61
  62   def fix_summary(object), do: Map.put(object, "summary", "")
  63
  64   def fix_addressing_list(map, field) do
  65     cond do
  66       is_binary(map[field]) ->
  67         Map.put(map, field, [map[field]])
  68
  69       is_nil(map[field]) ->
  70         Map.put(map, field, [])
  71
  72       true ->
  73         map
  74     end
  75   end
  76
  77   def fix_explicit_addressing(
  78         %{"to" => to, "cc" => cc} = object,
  79         explicit_mentions,
  80         follower_collection
  81       ) do
  82     explicit_to = Enum.filter(to, fn x -> x in explicit_mentions end)
  83
  84     explicit_cc = Enum.filter(to, fn x -> x not in explicit_mentions end)
  85
  86     final_cc =
  87       (cc ++ explicit_cc)
  88       |> Enum.reject(fn x -> String.ends_with?(x, "/followers") and x != follower_collection end)
  89       |> Enum.uniq()
  90
  91     object
  92     |> Map.put("to", explicit_to)
  93     |> Map.put("cc", final_cc)
  94   end
  95
  96   def fix_explicit_addressing(object, _explicit_mentions, _followers_collection), do: object
  97
  98   # if directMessage flag is set to true, leave the addressing alone
  99   def fix_explicit_addressing(%{"directMessage" => true} = object), do: object
 100
 101   def fix_explicit_addressing(object) do
 102     explicit_mentions = Utils.determine_explicit_mentions(object)
 103
 104     %User{follower_address: follower_collection} =
 105       object
 106       |> Containment.get_actor()
 107       |> User.get_cached_by_ap_id()
 108
 109     explicit_mentions =
 110       explicit_mentions ++
 111         [
 112           Pleroma.Constants.as_public(),
 113           follower_collection
 114         ]
 115
 116     fix_explicit_addressing(object, explicit_mentions, follower_collection)
 117   end
 118
 119   # if as:Public is addressed, then make sure the followers collection is also addressed
 120   # so that the activities will be delivered to local users.
 121   def fix_implicit_addressing(%{"to" => to, "cc" => cc} = object, followers_collection) do
 122     recipients = to ++ cc
 123
 124     if followers_collection not in recipients do
 125       cond do
 126         Pleroma.Constants.as_public() in cc ->
 127           to = to ++ [followers_collection]
 128           Map.put(object, "to", to)
 129
 130         Pleroma.Constants.as_public() in to ->
 131           cc = cc ++ [followers_collection]
 132           Map.put(object, "cc", cc)
 133
 134         true ->
 135           object
 136       end
 137     else
 138       object
 139     end
 140   end
 141
 142   def fix_implicit_addressing(object, _), do: object
 143
 144   def fix_addressing(object) do
 145     {:ok, %User{} = user} = User.get_or_fetch_by_ap_id(object["actor"])
 146     followers_collection = User.ap_followers(user)
 147
 148     object
 149     |> fix_addressing_list("to")
 150     |> fix_addressing_list("cc")
 151     |> fix_addressing_list("bto")
 152     |> fix_addressing_list("bcc")
 153     |> fix_explicit_addressing()
 154     |> fix_implicit_addressing(followers_collection)
 155   end
 156
 157   def fix_actor(%{"attributedTo" => actor} = object) do
 158     Map.put(object, "actor", Containment.get_actor(%{"actor" => actor}))
 159   end
 160
 161   def fix_in_reply_to(object, options \\ [])
 162
 163   def fix_in_reply_to(%{"inReplyTo" => in_reply_to} = object, options)
 164       when not is_nil(in_reply_to) do
 165     in_reply_to_id = prepare_in_reply_to(in_reply_to)
 166     object = Map.put(object, "inReplyToAtomUri", in_reply_to_id)
 167     depth = (options[:depth] || 0) + 1
 168
 169     if Federator.allowed_thread_distance?(depth) do
 170       with {:ok, replied_object} <- get_obj_helper(in_reply_to_id, options),
 171            %Activity{} <- Activity.get_create_by_object_ap_id(replied_object.data["id"]) do
 172         object
 173         |> Map.put("inReplyTo", replied_object.data["id"])
 174         |> Map.put("inReplyToAtomUri", object["inReplyToAtomUri"] || in_reply_to_id)
 175         |> Map.put("context", replied_object.data["context"] || object["conversation"])
 176         |> Map.drop(["conversation"])
 177       else
 178         e ->
 179           Logger.error("Couldn't fetch #{inspect(in_reply_to_id)}, error: #{inspect(e)}")
 180           object
 181       end
 182     else
 183       object
 184     end
 185   end
 186
 187   def fix_in_reply_to(object, _options), do: object
 188
 189   defp prepare_in_reply_to(in_reply_to) do
 190     cond do
 191       is_bitstring(in_reply_to) ->
 192         in_reply_to
 193
 194       is_map(in_reply_to) && is_bitstring(in_reply_to["id"]) ->
 195         in_reply_to["id"]
 196
 197       is_list(in_reply_to) && is_bitstring(Enum.at(in_reply_to, 0)) ->
 198         Enum.at(in_reply_to, 0)
 199
 200       true ->
 201         ""
 202     end
 203   end
 204
 205   def fix_context(object) do
 206     context = object["context"] || object["conversation"] || Utils.generate_context_id()
 207
 208     object
 209     |> Map.put("context", context)
 210     |> Map.drop(["conversation"])
 211   end
 212
 213   def fix_attachments(%{"attachment" => attachment} = object) when is_list(attachment) do
 214     attachments =
 215       Enum.map(attachment, fn data ->
 216         url =
 217           cond do
 218             is_list(data["url"]) -> List.first(data["url"])
 219             is_map(data["url"]) -> data["url"]
 220             true -> nil
 221           end
 222
 223         media_type =
 224           cond do
 225             is_map(url) && MIME.valid?(url["mediaType"]) -> url["mediaType"]
 226             MIME.valid?(data["mediaType"]) -> data["mediaType"]
 227             MIME.valid?(data["mimeType"]) -> data["mimeType"]
 228             true -> nil
 229           end
 230
 231         href =
 232           cond do
 233             is_map(url) && is_binary(url["href"]) -> url["href"]
 234             is_binary(data["url"]) -> data["url"]
 235             is_binary(data["href"]) -> data["href"]
 236           end
 237
 238         attachment_url =
 239           %{"href" => href}
 240           |> Maps.put_if_present("mediaType", media_type)
 241           |> Maps.put_if_present("type", Map.get(url || %{}, "type"))
 242
 243         %{"url" => [attachment_url]}
 244         |> Maps.put_if_present("mediaType", media_type)
 245         |> Maps.put_if_present("type", data["type"])
 246         |> Maps.put_if_present("name", data["name"])
 247       end)
 248
 249     Map.put(object, "attachment", attachments)
 250   end
 251
 252   def fix_attachments(%{"attachment" => attachment} = object) when is_map(attachment) do
 253     object
 254     |> Map.put("attachment", [attachment])
 255     |> fix_attachments()
 256   end
 257
 258   def fix_attachments(object), do: object
 259
 260   def fix_url(%{"url" => url} = object) when is_map(url) do
 261     Map.put(object, "url", url["href"])
 262   end
 263
 264   def fix_url(%{"type" => object_type, "url" => url} = object)
 265       when object_type in ["Video", "Audio"] and is_list(url) do
 266     first_element = Enum.at(url, 0)
 267
 268     link_element = Enum.find(url, fn x -> is_map(x) and x["mimeType"] == "text/html" end)
 269
 270     object
 271     |> Map.put("attachment", [first_element])
 272     |> Map.put("url", link_element["href"])
 273   end
 274
 275   def fix_url(%{"type" => object_type, "url" => url} = object)
 276       when object_type != "Video" and is_list(url) do
 277     first_element = Enum.at(url, 0)
 278
 279     url_string =
 280       cond do
 281         is_bitstring(first_element) -> first_element
 282         is_map(first_element) -> first_element["href"] || ""
 283         true -> ""
 284       end
 285
 286     Map.put(object, "url", url_string)
 287   end
 288
 289   def fix_url(object), do: object
 290
 291   def fix_emoji(%{"tag" => tags} = object) when is_list(tags) do
 292     emoji =
 293       tags
 294       |> Enum.filter(fn data -> data["type"] == "Emoji" and data["icon"] end)
 295       |> Enum.reduce(%{}, fn data, mapping ->
 296         name = String.trim(data["name"], ":")
 297
 298         Map.put(mapping, name, data["icon"]["url"])
 299       end)
 300
 301     # we merge mastodon and pleroma emoji into a single mapping, to allow for both wire formats
 302     emoji = Map.merge(object["emoji"] || %{}, emoji)
 303
 304     Map.put(object, "emoji", emoji)
 305   end
 306
 307   def fix_emoji(%{"tag" => %{"type" => "Emoji"} = tag} = object) do
 308     name = String.trim(tag["name"], ":")
 309     emoji = %{name => tag["icon"]["url"]}
 310
 311     Map.put(object, "emoji", emoji)
 312   end
 313
 314   def fix_emoji(object), do: object
 315
 316   def fix_tag(%{"tag" => tag} = object) when is_list(tag) do
 317     tags =
 318       tag
 319       |> Enum.filter(fn data -> data["type"] == "Hashtag" and data["name"] end)
 320       |> Enum.map(fn data -> String.slice(data["name"], 1..-1) end)
 321
 322     Map.put(object, "tag", tag ++ tags)
 323   end
 324
 325   def fix_tag(%{"tag" => %{"type" => "Hashtag", "name" => hashtag} = tag} = object) do
 326     combined = [tag, String.slice(hashtag, 1..-1)]
 327
 328     Map.put(object, "tag", combined)
 329   end
 330
 331   def fix_tag(%{"tag" => %{} = tag} = object), do: Map.put(object, "tag", [tag])
 332
 333   def fix_tag(object), do: object
 334
 335   # content map usually only has one language so this will do for now.
 336   def fix_content_map(%{"contentMap" => content_map} = object) do
 337     content_groups = Map.to_list(content_map)
 338     {_, content} = Enum.at(content_groups, 0)
 339
 340     Map.put(object, "content", content)
 341   end
 342
 343   def fix_content_map(object), do: object
 344
 345   def fix_type(object, options \\ [])
 346
 347   def fix_type(%{"inReplyTo" => reply_id, "name" => _} = object, options)
 348       when is_binary(reply_id) do
 349     with true <- Federator.allowed_thread_distance?(options[:depth]),
 350          {:ok, %{data: %{"type" => "Question"} = _} = _} <- get_obj_helper(reply_id, options) do
 351       Map.put(object, "type", "Answer")
 352     else
 353       _ -> object
 354     end
 355   end
 356
 357   def fix_type(object, _), do: object
 358
 359   defp fix_content(%{"mediaType" => "text/markdown", "content" => content} = object)
 360        when is_binary(content) do
 361     html_content =
 362       content
 363       |> Earmark.as_html!(%Earmark.Options{renderer: EarmarkRenderer})
 364       |> Pleroma.HTML.filter_tags()
 365
 366     Map.merge(object, %{"content" => html_content, "mediaType" => "text/html"})
 367   end
 368
 369   defp fix_content(object), do: object
 370
 371   defp mastodon_follow_hack(%{"id" => id, "actor" => follower_id}, followed) do
 372     with true <- id =~ "follows",
 373          %User{local: true} = follower <- User.get_cached_by_ap_id(follower_id),
 374          %Activity{} = activity <- Utils.fetch_latest_follow(follower, followed) do
 375       {:ok, activity}
 376     else
 377       _ -> {:error, nil}
 378     end
 379   end
 380
 381   defp mastodon_follow_hack(_, _), do: {:error, nil}
 382
 383   defp get_follow_activity(follow_object, followed) do
 384     with object_id when not is_nil(object_id) <- Utils.get_ap_id(follow_object),
 385          {_, %Activity{} = activity} <- {:activity, Activity.get_by_ap_id(object_id)} do
 386       {:ok, activity}
 387     else
 388       # Can't find the activity. This might a Mastodon 2.3 "Accept"
 389       {:activity, nil} ->
 390         mastodon_follow_hack(follow_object, followed)
 391
 392       _ ->
 393         {:error, nil}
 394     end
 395   end
 396
 397   # Reduce the object list to find the reported user.
 398   defp get_reported(objects) do
 399     Enum.reduce_while(objects, nil, fn ap_id, _ ->
 400       with %User{} = user <- User.get_cached_by_ap_id(ap_id) do
 401         {:halt, user}
 402       else
 403         _ -> {:cont, nil}
 404       end
 405     end)
 406   end
 407
 408   def handle_incoming(data, options \\ [])
 409
 410   # Flag objects are placed ahead of the ID check because Mastodon 2.8 and earlier send them
 411   # with nil ID.
 412   def handle_incoming(%{"type" => "Flag", "object" => objects, "actor" => actor} = data, _options) do
 413     with context <- data["context"] || Utils.generate_context_id(),
 414          content <- data["content"] || "",
 415          %User{} = actor <- User.get_cached_by_ap_id(actor),
 416          # Reduce the object list to find the reported user.
 417          %User{} = account <- get_reported(objects),
 418          # Remove the reported user from the object list.
 419          statuses <- Enum.filter(objects, fn ap_id -> ap_id != account.ap_id end) do
 420       %{
 421         actor: actor,
 422         context: context,
 423         account: account,
 424         statuses: statuses,
 425         content: content,
 426         additional: %{"cc" => [account.ap_id]}
 427       }
 428       |> ActivityPub.flag()
 429     end
 430   end
 431
 432   # disallow objects with bogus IDs
 433   def handle_incoming(%{"id" => nil}, _options), do: :error
 434   def handle_incoming(%{"id" => ""}, _options), do: :error
 435   # length of https:// = 8, should validate better, but good enough for now.
 436   def handle_incoming(%{"id" => id}, _options) when is_binary(id) and byte_size(id) < 8,
 437     do: :error
 438
 439   # TODO: validate those with a Ecto scheme
 440   # - tags
 441   # - emoji
 442   def handle_incoming(
 443         %{"type" => "Create", "object" => %{"type" => objtype} = object} = data,
 444         options
 445       )
 446       when objtype in ["Article", "Event", "Note", "Video", "Page", "Question", "Answer", "Audio"] do
 447     actor = Containment.get_actor(data)
 448
 449     data =
 450       Map.put(data, "actor", actor)
 451       |> fix_addressing
 452
 453     with nil <- Activity.get_create_by_object_ap_id(object["id"]),
 454          {:ok, %User{} = user} <- User.get_or_fetch_by_ap_id(data["actor"]) do
 455       object = fix_object(object, options)
 456
 457       params = %{
 458         to: data["to"],
 459         object: object,
 460         actor: user,
 461         context: object["context"],
 462         local: false,
 463         published: data["published"],
 464         additional:
 465           Map.take(data, [
 466             "cc",
 467             "directMessage",
 468             "id"
 469           ])
 470       }
 471
 472       with {:ok, created_activity} <- ActivityPub.create(params) do
 473         reply_depth = (options[:depth] || 0) + 1
 474
 475         if Federator.allowed_thread_distance?(reply_depth) do
 476           for reply_id <- replies(object) do
 477             Pleroma.Workers.RemoteFetcherWorker.enqueue("fetch_remote", %{
 478               "id" => reply_id,
 479               "depth" => reply_depth
 480             })
 481           end
 482         end
 483
 484         {:ok, created_activity}
 485       end
 486     else
 487       %Activity{} = activity -> {:ok, activity}
 488       _e -> :error
 489     end
 490   end
 491
 492   def handle_incoming(
 493         %{"type" => "Listen", "object" => %{"type" => "Audio"} = object} = data,
 494         options
 495       ) do
 496     actor = Containment.get_actor(data)
 497
 498     data =
 499       Map.put(data, "actor", actor)
 500       |> fix_addressing
 501
 502     with {:ok, %User{} = user} <- User.get_or_fetch_by_ap_id(data["actor"]) do
 503       reply_depth = (options[:depth] || 0) + 1
 504       options = Keyword.put(options, :depth, reply_depth)
 505       object = fix_object(object, options)
 506
 507       params = %{
 508         to: data["to"],
 509         object: object,
 510         actor: user,
 511         context: nil,
 512         local: false,
 513         published: data["published"],
 514         additional: Map.take(data, ["cc", "id"])
 515       }
 516
 517       ActivityPub.listen(params)
 518     else
 519       _e -> :error
 520     end
 521   end
 522
 523   def handle_incoming(
 524         %{"type" => "Follow", "object" => followed, "actor" => follower, "id" => id} = data,
 525         _options
 526       ) do
 527     with %User{local: true} = followed <-
 528            User.get_cached_by_ap_id(Containment.get_actor(%{"actor" => followed})),
 529          {:ok, %User{} = follower} <-
 530            User.get_or_fetch_by_ap_id(Containment.get_actor(%{"actor" => follower})),
 531          {:ok, activity} <-
 532            ActivityPub.follow(follower, followed, id, false, skip_notify_and_stream: true) do
 533       with deny_follow_blocked <- Pleroma.Config.get([:user, :deny_follow_blocked]),
 534            {_, false} <- {:user_blocked, User.blocks?(followed, follower) && deny_follow_blocked},
 535            {_, false} <- {:user_locked, User.locked?(followed)},
 536            {_, {:ok, follower}} <- {:follow, User.follow(follower, followed)},
 537            {_, {:ok, _}} <-
 538              {:follow_state_update, Utils.update_follow_state_for_all(activity, "accept")},
 539            {:ok, _relationship} <-
 540              FollowingRelationship.update(follower, followed, :follow_accept) do
 541         ActivityPub.accept(%{
 542           to: [follower.ap_id],
 543           actor: followed,
 544           object: data,
 545           local: true
 546         })
 547       else
 548         {:user_blocked, true} ->
 549           {:ok, _} = Utils.update_follow_state_for_all(activity, "reject")
 550           {:ok, _relationship} = FollowingRelationship.update(follower, followed, :follow_reject)
 551
 552           ActivityPub.reject(%{
 553             to: [follower.ap_id],
 554             actor: followed,
 555             object: data,
 556             local: true
 557           })
 558
 559         {:follow, {:error, _}} ->
 560           {:ok, _} = Utils.update_follow_state_for_all(activity, "reject")
 561           {:ok, _relationship} = FollowingRelationship.update(follower, followed, :follow_reject)
 562
 563           ActivityPub.reject(%{
 564             to: [follower.ap_id],
 565             actor: followed,
 566             object: data,
 567             local: true
 568           })
 569
 570         {:user_locked, true} ->
 571           {:ok, _relationship} = FollowingRelationship.update(follower, followed, :follow_pending)
 572           :noop
 573       end
 574
 575       ActivityPub.notify_and_stream(activity)
 576       {:ok, activity}
 577     else
 578       _e ->
 579         :error
 580     end
 581   end
 582
 583   def handle_incoming(
 584         %{"type" => "Accept", "object" => follow_object, "actor" => _actor, "id" => id} = data,
 585         _options
 586       ) do
 587     with actor <- Containment.get_actor(data),
 588          {:ok, %User{} = followed} <- User.get_or_fetch_by_ap_id(actor),
 589          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 590          {:ok, follow_activity} <- Utils.update_follow_state_for_all(follow_activity, "accept"),
 591          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 592          {:ok, _relationship} <- FollowingRelationship.update(follower, followed, :follow_accept) do
 593       User.update_follower_count(followed)
 594       User.update_following_count(follower)
 595
 596       Notification.update_notification_type(followed, follow_activity)
 597
 598       ActivityPub.accept(%{
 599         to: follow_activity.data["to"],
 600         type: "Accept",
 601         actor: followed,
 602         object: follow_activity.data["id"],
 603         local: false,
 604         activity_id: id
 605       })
 606     else
 607       _e ->
 608         :error
 609     end
 610   end
 611
 612   def handle_incoming(
 613         %{"type" => "Reject", "object" => follow_object, "actor" => _actor, "id" => id} = data,
 614         _options
 615       ) do
 616     with actor <- Containment.get_actor(data),
 617          {:ok, %User{} = followed} <- User.get_or_fetch_by_ap_id(actor),
 618          {:ok, follow_activity} <- get_follow_activity(follow_object, followed),
 619          {:ok, follow_activity} <- Utils.update_follow_state_for_all(follow_activity, "reject"),
 620          %User{local: true} = follower <- User.get_cached_by_ap_id(follow_activity.data["actor"]),
 621          {:ok, _relationship} <- FollowingRelationship.update(follower, followed, :follow_reject),
 622          {:ok, activity} <-
 623            ActivityPub.reject(%{
 624              to: follow_activity.data["to"],
 625              type: "Reject",
 626              actor: followed,
 627              object: follow_activity.data["id"],
 628              local: false,
 629              activity_id: id
 630            }) do
 631       {:ok, activity}
 632     else
 633       _e -> :error
 634     end
 635   end
 636
 637   @misskey_reactions %{
 638     "like" => "👍",
 639     "love" => "❤️",
 640     "laugh" => "😆",
 641     "hmm" => "🤔",
 642     "surprise" => "😮",
 643     "congrats" => "🎉",
 644     "angry" => "💢",
 645     "confused" => "😥",
 646     "rip" => "😇",
 647     "pudding" => "🍮",
 648     "star" => "⭐"
 649   }
 650
 651   @doc "Rewrite misskey likes into EmojiReacts"
 652   def handle_incoming(
 653         %{
 654           "type" => "Like",
 655           "_misskey_reaction" => reaction
 656         } = data,
 657         options
 658       ) do
 659     data
 660     |> Map.put("type", "EmojiReact")
 661     |> Map.put("content", @misskey_reactions[reaction] || reaction)
 662     |> handle_incoming(options)
 663   end
 664
 665   def handle_incoming(
 666         %{"type" => "Create", "object" => %{"type" => "ChatMessage"}} = data,
 667         _options
 668       ) do
 669     with {:ok, %User{}} <- ObjectValidator.fetch_actor(data),
 670          {:ok, activity, _} <- Pipeline.common_pipeline(data, local: false) do
 671       {:ok, activity}
 672     end
 673   end
 674
 675   def handle_incoming(%{"type" => type} = data, _options)
 676       when type in ~w{Like EmojiReact Announce} do
 677     with :ok <- ObjectValidator.fetch_actor_and_object(data),
 678          {:ok, activity, _meta} <-
 679            Pipeline.common_pipeline(data, local: false) do
 680       {:ok, activity}
 681     else
 682       e -> {:error, e}
 683     end
 684   end
 685
 686   def handle_incoming(
 687         %{"type" => type} = data,
 688         _options
 689       )
 690       when type in ~w{Update Block} do
 691     with {:ok, %User{}} <- ObjectValidator.fetch_actor(data),
 692          {:ok, activity, _} <- Pipeline.common_pipeline(data, local: false) do
 693       {:ok, activity}
 694     end
 695   end
 696
 697   def handle_incoming(
 698         %{"type" => "Delete"} = data,
 699         _options
 700       ) do
 701     with {:ok, activity, _} <- Pipeline.common_pipeline(data, local: false) do
 702       {:ok, activity}
 703     else
 704       {:error, {:validate_object, _}} = e ->
 705         # Check if we have a create activity for this
 706         with {:ok, object_id} <- ObjectValidators.ObjectID.cast(data["object"]),
 707              %Activity{data: %{"actor" => actor}} <-
 708                Activity.create_by_object_ap_id(object_id) |> Repo.one(),
 709              # We have one, insert a tombstone and retry
 710              {:ok, tombstone_data, _} <- Builder.tombstone(actor, object_id),
 711              {:ok, _tombstone} <- Object.create(tombstone_data) do
 712           handle_incoming(data)
 713         else
 714           _ -> e
 715         end
 716     end
 717   end
 718
 719   def handle_incoming(
 720         %{
 721           "type" => "Undo",
 722           "object" => %{"type" => "Follow", "object" => followed},
 723           "actor" => follower,
 724           "id" => id
 725         } = _data,
 726         _options
 727       ) do
 728     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 729          {:ok, %User{} = follower} <- User.get_or_fetch_by_ap_id(follower),
 730          {:ok, activity} <- ActivityPub.unfollow(follower, followed, id, false) do
 731       User.unfollow(follower, followed)
 732       {:ok, activity}
 733     else
 734       _e -> :error
 735     end
 736   end
 737
 738   def handle_incoming(
 739         %{
 740           "type" => "Undo",
 741           "object" => %{"type" => type}
 742         } = data,
 743         _options
 744       )
 745       when type in ["Like", "EmojiReact", "Announce", "Block"] do
 746     with {:ok, activity, _} <- Pipeline.common_pipeline(data, local: false) do
 747       {:ok, activity}
 748     end
 749   end
 750
 751   # For Undos that don't have the complete object attached, try to find it in our database.
 752   def handle_incoming(
 753         %{
 754           "type" => "Undo",
 755           "object" => object
 756         } = activity,
 757         options
 758       )
 759       when is_binary(object) do
 760     with %Activity{data: data} <- Activity.get_by_ap_id(object) do
 761       activity
 762       |> Map.put("object", data)
 763       |> handle_incoming(options)
 764     else
 765       _e -> :error
 766     end
 767   end
 768
 769   def handle_incoming(
 770         %{
 771           "type" => "Move",
 772           "actor" => origin_actor,
 773           "object" => origin_actor,
 774           "target" => target_actor
 775         },
 776         _options
 777       ) do
 778     with %User{} = origin_user <- User.get_cached_by_ap_id(origin_actor),
 779          {:ok, %User{} = target_user} <- User.get_or_fetch_by_ap_id(target_actor),
 780          true <- origin_actor in target_user.also_known_as do
 781       ActivityPub.move(origin_user, target_user, false)
 782     else
 783       _e -> :error
 784     end
 785   end
 786
 787   def handle_incoming(_, _), do: :error
 788
 789   @spec get_obj_helper(String.t(), Keyword.t()) :: {:ok, Object.t()} | nil
 790   def get_obj_helper(id, options \\ []) do
 791     case Object.normalize(id, true, options) do
 792       %Object{} = object -> {:ok, object}
 793       _ -> nil
 794     end
 795   end
 796
 797   @spec get_embedded_obj_helper(String.t() | Object.t(), User.t()) :: {:ok, Object.t()} | nil
 798   def get_embedded_obj_helper(%{"attributedTo" => attributed_to, "id" => object_id} = data, %User{
 799         ap_id: ap_id
 800       })
 801       when attributed_to == ap_id do
 802     with {:ok, activity} <-
 803            handle_incoming(%{
 804              "type" => "Create",
 805              "to" => data["to"],
 806              "cc" => data["cc"],
 807              "actor" => attributed_to,
 808              "object" => data
 809            }) do
 810       {:ok, Object.normalize(activity)}
 811     else
 812       _ -> get_obj_helper(object_id)
 813     end
 814   end
 815
 816   def get_embedded_obj_helper(object_id, _) do
 817     get_obj_helper(object_id)
 818   end
 819
 820   def set_reply_to_uri(%{"inReplyTo" => in_reply_to} = object) when is_binary(in_reply_to) do
 821     with false <- String.starts_with?(in_reply_to, "http"),
 822          {:ok, %{data: replied_to_object}} <- get_obj_helper(in_reply_to) do
 823       Map.put(object, "inReplyTo", replied_to_object["external_url"] || in_reply_to)
 824     else
 825       _e -> object
 826     end
 827   end
 828
 829   def set_reply_to_uri(obj), do: obj
 830
 831   @doc """
 832   Serialized Mastodon-compatible `replies` collection containing _self-replies_.
 833   Based on Mastodon's ActivityPub::NoteSerializer#replies.
 834   """
 835   def set_replies(obj_data) do
 836     replies_uris =
 837       with limit when limit > 0 <-
 838              Pleroma.Config.get([:activitypub, :note_replies_output_limit], 0),
 839            %Object{} = object <- Object.get_cached_by_ap_id(obj_data["id"]) do
 840         object
 841         |> Object.self_replies()
 842         |> select([o], fragment("?->>'id'", o.data))
 843         |> limit(^limit)
 844         |> Repo.all()
 845       else
 846         _ -> []
 847       end
 848
 849     set_replies(obj_data, replies_uris)
 850   end
 851
 852   defp set_replies(obj, []) do
 853     obj
 854   end
 855
 856   defp set_replies(obj, replies_uris) do
 857     replies_collection = %{
 858       "type" => "Collection",
 859       "items" => replies_uris
 860     }
 861
 862     Map.merge(obj, %{"replies" => replies_collection})
 863   end
 864
 865   def replies(%{"replies" => %{"first" => %{"items" => items}}}) when not is_nil(items) do
 866     items
 867   end
 868
 869   def replies(%{"replies" => %{"items" => items}}) when not is_nil(items) do
 870     items
 871   end
 872
 873   def replies(_), do: []
 874
 875   # Prepares the object of an outgoing create activity.
 876   def prepare_object(object) do
 877     object
 878     |> set_sensitive
 879     |> add_hashtags
 880     |> add_mention_tags
 881     |> add_emoji_tags
 882     |> add_attributed_to
 883     |> prepare_attachments
 884     |> set_conversation
 885     |> set_reply_to_uri
 886     |> set_replies
 887     |> strip_internal_fields
 888     |> strip_internal_tags
 889     |> set_type
 890   end
 891
 892   #  @doc
 893   #  """
 894   #  internal -> Mastodon
 895   #  """
 896
 897   def prepare_outgoing(%{"type" => activity_type, "object" => object_id} = data)
 898       when activity_type in ["Create", "Listen"] do
 899     object =
 900       object_id
 901       |> Object.normalize()
 902       |> Map.get(:data)
 903       |> prepare_object
 904
 905     data =
 906       data
 907       |> Map.put("object", object)
 908       |> Map.merge(Utils.make_json_ld_header())
 909       |> Map.delete("bcc")
 910
 911     {:ok, data}
 912   end
 913
 914   def prepare_outgoing(%{"type" => "Announce", "actor" => ap_id, "object" => object_id} = data) do
 915     object =
 916       object_id
 917       |> Object.normalize()
 918
 919     data =
 920       if Visibility.is_private?(object) && object.data["actor"] == ap_id do
 921         data |> Map.put("object", object |> Map.get(:data) |> prepare_object)
 922       else
 923         data |> maybe_fix_object_url
 924       end
 925
 926     data =
 927       data
 928       |> strip_internal_fields
 929       |> Map.merge(Utils.make_json_ld_header())
 930       |> Map.delete("bcc")
 931
 932     {:ok, data}
 933   end
 934
 935   # Mastodon Accept/Reject requires a non-normalized object containing the actor URIs,
 936   # because of course it does.
 937   def prepare_outgoing(%{"type" => "Accept"} = data) do
 938     with follow_activity <- Activity.normalize(data["object"]) do
 939       object = %{
 940         "actor" => follow_activity.actor,
 941         "object" => follow_activity.data["object"],
 942         "id" => follow_activity.data["id"],
 943         "type" => "Follow"
 944       }
 945
 946       data =
 947         data
 948         |> Map.put("object", object)
 949         |> Map.merge(Utils.make_json_ld_header())
 950
 951       {:ok, data}
 952     end
 953   end
 954
 955   def prepare_outgoing(%{"type" => "Reject"} = data) do
 956     with follow_activity <- Activity.normalize(data["object"]) do
 957       object = %{
 958         "actor" => follow_activity.actor,
 959         "object" => follow_activity.data["object"],
 960         "id" => follow_activity.data["id"],
 961         "type" => "Follow"
 962       }
 963
 964       data =
 965         data
 966         |> Map.put("object", object)
 967         |> Map.merge(Utils.make_json_ld_header())
 968
 969       {:ok, data}
 970     end
 971   end
 972
 973   def prepare_outgoing(%{"type" => _type} = data) do
 974     data =
 975       data
 976       |> strip_internal_fields
 977       |> maybe_fix_object_url
 978       |> Map.merge(Utils.make_json_ld_header())
 979
 980     {:ok, data}
 981   end
 982
 983   def maybe_fix_object_url(%{"object" => object} = data) when is_binary(object) do
 984     with false <- String.starts_with?(object, "http"),
 985          {:fetch, {:ok, relative_object}} <- {:fetch, get_obj_helper(object)},
 986          %{data: %{"external_url" => external_url}} when not is_nil(external_url) <-
 987            relative_object do
 988       Map.put(data, "object", external_url)
 989     else
 990       {:fetch, e} ->
 991         Logger.error("Couldn't fetch #{object} #{inspect(e)}")
 992         data
 993
 994       _ ->
 995         data
 996     end
 997   end
 998
 999   def maybe_fix_object_url(data), do: data
1000
1001   def add_hashtags(object) do
1002     tags =
1003       (object["tag"] || [])
1004       |> Enum.map(fn
1005         # Expand internal representation tags into AS2 tags.
1006         tag when is_binary(tag) ->
1007           %{
1008             "href" => Pleroma.Web.Endpoint.url() <> "/tags/#{tag}",
1009             "name" => "##{tag}",
1010             "type" => "Hashtag"
1011           }
1012
1013         # Do not process tags which are already AS2 tag objects.
1014         tag when is_map(tag) ->
1015           tag
1016       end)
1017
1018     Map.put(object, "tag", tags)
1019   end
1020
1021   # TODO These should be added on our side on insertion, it doesn't make much
1022   # sense to regenerate these all the time
1023   def add_mention_tags(object) do
1024     to = object["to"] || []
1025     cc = object["cc"] || []
1026     mentioned = User.get_users_from_set(to ++ cc, local_only: false)
1027
1028     mentions = Enum.map(mentioned, &build_mention_tag/1)
1029
1030     tags = object["tag"] || []
1031     Map.put(object, "tag", tags ++ mentions)
1032   end
1033
1034   defp build_mention_tag(%{ap_id: ap_id, nickname: nickname} = _) do
1035     %{"type" => "Mention", "href" => ap_id, "name" => "@#{nickname}"}
1036   end
1037
1038   def take_emoji_tags(%User{emoji: emoji}) do
1039     emoji
1040     |> Map.to_list()
1041     |> Enum.map(&build_emoji_tag/1)
1042   end
1043
1044   # TODO: we should probably send mtime instead of unix epoch time for updated
1045   def add_emoji_tags(%{"emoji" => emoji} = object) do
1046     tags = object["tag"] || []
1047
1048     out = Enum.map(emoji, &build_emoji_tag/1)
1049
1050     Map.put(object, "tag", tags ++ out)
1051   end
1052
1053   def add_emoji_tags(object), do: object
1054
1055   defp build_emoji_tag({name, url}) do
1056     %{
1057       "icon" => %{"url" => url, "type" => "Image"},
1058       "name" => ":" <> name <> ":",
1059       "type" => "Emoji",
1060       "updated" => "1970-01-01T00:00:00Z",
1061       "id" => url
1062     }
1063   end
1064
1065   def set_conversation(object) do
1066     Map.put(object, "conversation", object["context"])
1067   end
1068
1069   def set_sensitive(%{"sensitive" => true} = object) do
1070     object
1071   end
1072
1073   def set_sensitive(object) do
1074     tags = object["tag"] || []
1075     Map.put(object, "sensitive", "nsfw" in tags)
1076   end
1077
1078   def set_type(%{"type" => "Answer"} = object) do
1079     Map.put(object, "type", "Note")
1080   end
1081
1082   def set_type(object), do: object
1083
1084   def add_attributed_to(object) do
1085     attributed_to = object["attributedTo"] || object["actor"]
1086     Map.put(object, "attributedTo", attributed_to)
1087   end
1088
1089   # TODO: Revisit this
1090   def prepare_attachments(%{"type" => "ChatMessage"} = object), do: object
1091
1092   def prepare_attachments(object) do
1093     attachments =
1094       object
1095       |> Map.get("attachment", [])
1096       |> Enum.map(fn data ->
1097         [%{"mediaType" => media_type, "href" => href} | _] = data["url"]
1098
1099         %{
1100           "url" => href,
1101           "mediaType" => media_type,
1102           "name" => data["name"],
1103           "type" => "Document"
1104         }
1105       end)
1106
1107     Map.put(object, "attachment", attachments)
1108   end
1109
1110   def strip_internal_fields(object) do
1111     Map.drop(object, Pleroma.Constants.object_internal_fields())
1112   end
1113
1114   defp strip_internal_tags(%{"tag" => tags} = object) do
1115     tags = Enum.filter(tags, fn x -> is_map(x) end)
1116
1117     Map.put(object, "tag", tags)
1118   end
1119
1120   defp strip_internal_tags(object), do: object
1121
1122   def perform(:user_upgrade, user) do
1123     # we pass a fake user so that the followers collection is stripped away
1124     old_follower_address = User.ap_followers(%User{nickname: user.nickname})
1125
1126     from(
1127       a in Activity,
1128       where: ^old_follower_address in a.recipients,
1129       update: [
1130         set: [
1131           recipients:
1132             fragment(
1133               "array_replace(?,?,?)",
1134               a.recipients,
1135               ^old_follower_address,
1136               ^user.follower_address
1137             )
1138         ]
1139       ]
1140     )
1141     |> Repo.update_all([])
1142   end
1143
1144   def upgrade_user_from_ap_id(ap_id) do
1145     with %User{local: false} = user <- User.get_cached_by_ap_id(ap_id),
1146          {:ok, data} <- ActivityPub.fetch_and_prepare_user_from_ap_id(ap_id),
1147          {:ok, user} <- update_user(user, data) do
1148       TransmogrifierWorker.enqueue("user_upgrade", %{"user_id" => user.id})
1149       {:ok, user}
1150     else
1151       %User{} = user -> {:ok, user}
1152       e -> e
1153     end
1154   end
1155
1156   defp update_user(user, data) do
1157     user
1158     |> User.remote_user_changeset(data)
1159     |> User.update_and_set_cache()
1160   end
1161
1162   def maybe_fix_user_url(%{"url" => url} = data) when is_map(url) do
1163     Map.put(data, "url", url["href"])
1164   end
1165
1166   def maybe_fix_user_url(data), do: data
1167
1168   def maybe_fix_user_object(data), do: maybe_fix_user_url(data)
1169 end