git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/transmogrifier.ex

   1 defmodule Pleroma.Web.ActivityPub.Transmogrifier do
   2   @moduledoc """
   3   A module to handle coding from internal to wire ActivityPub and back.
   4   """
   5   alias Pleroma.User
   6   alias Pleroma.Object
   7   alias Pleroma.Activity
   8   alias Pleroma.Repo
   9   alias Pleroma.Web.ActivityPub.ActivityPub
  10
  11   import Ecto.Query
  12
  13   require Logger
  14
  15   @doc """
  16   Modifies an incoming AP object (mastodon format) to our internal format.
  17   """
  18   def fix_object(object) do
  19     object
  20     |> Map.put("actor", object["attributedTo"])
  21     |> fix_attachments
  22     |> fix_context
  23     |> fix_in_reply_to
  24     |> fix_emoji
  25     |> fix_tag
  26   end
  27
  28   def fix_in_reply_to(%{"inReplyTo" => in_reply_to_id} = object)
  29       when not is_nil(in_reply_to_id) do
  30     case ActivityPub.fetch_object_from_id(in_reply_to_id) do
  31       {:ok, replied_object} ->
  32         activity = Activity.get_create_activity_by_object_ap_id(replied_object.data["id"])
  33
  34         object
  35         |> Map.put("inReplyTo", replied_object.data["id"])
  36         |> Map.put("inReplyToAtomUri", object["inReplyToAtomUri"] || in_reply_to_id)
  37         |> Map.put("inReplyToStatusId", activity.id)
  38         |> Map.put("conversation", replied_object.data["context"] || object["conversation"])
  39         |> Map.put("context", replied_object.data["context"] || object["conversation"])
  40
  41       e ->
  42         Logger.error("Couldn't fetch #{object["inReplyTo"]} #{inspect(e)}")
  43         object
  44     end
  45   end
  46
  47   def fix_in_reply_to(object), do: object
  48
  49   def fix_context(object) do
  50     object
  51     |> Map.put("context", object["conversation"])
  52   end
  53
  54   def fix_attachments(object) do
  55     attachments =
  56       (object["attachment"] || [])
  57       |> Enum.map(fn data ->
  58         url = [%{"type" => "Link", "mediaType" => data["mediaType"], "href" => data["url"]}]
  59         Map.put(data, "url", url)
  60       end)
  61
  62     object
  63     |> Map.put("attachment", attachments)
  64   end
  65
  66   def fix_emoji(object) do
  67     tags = object["tag"] || []
  68     emoji = tags |> Enum.filter(fn data -> data["type"] == "Emoji" and data["icon"] end)
  69
  70     emoji =
  71       emoji
  72       |> Enum.reduce(%{}, fn data, mapping ->
  73         name = data["name"]
  74
  75         name =
  76           if String.starts_with?(name, ":") do
  77             name |> String.slice(1..-2)
  78           else
  79             name
  80           end
  81
  82         mapping |> Map.put(name, data["icon"]["url"])
  83       end)
  84
  85     # we merge mastodon and pleroma emoji into a single mapping, to allow for both wire formats
  86     emoji = Map.merge(object["emoji"] || %{}, emoji)
  87
  88     object
  89     |> Map.put("emoji", emoji)
  90   end
  91
  92   def fix_tag(object) do
  93     tags =
  94       (object["tag"] || [])
  95       |> Enum.filter(fn data -> data["type"] == "Hashtag" and data["name"] end)
  96       |> Enum.map(fn data -> String.slice(data["name"], 1..-1) end)
  97
  98     combined = (object["tag"] || []) ++ tags
  99
 100     object
 101     |> Map.put("tag", combined)
 102   end
 103
 104   # TODO: validate those with a Ecto scheme
 105   # - tags
 106   # - emoji
 107   def handle_incoming(%{"type" => "Create", "object" => %{"type" => "Note"} = object} = data) do
 108     with nil <- Activity.get_create_activity_by_object_ap_id(object["id"]),
 109          %User{} = user <- User.get_or_fetch_by_ap_id(data["actor"]) do
 110       object = fix_object(data["object"])
 111
 112       params = %{
 113         to: data["to"],
 114         object: object,
 115         actor: user,
 116         context: object["conversation"],
 117         local: false,
 118         published: data["published"],
 119         additional:
 120           Map.take(data, [
 121             "cc",
 122             "id"
 123           ])
 124       }
 125
 126       ActivityPub.create(params)
 127     else
 128       %Activity{} = activity -> {:ok, activity}
 129       _e -> :error
 130     end
 131   end
 132
 133   def handle_incoming(
 134         %{"type" => "Follow", "object" => followed, "actor" => follower, "id" => id} = data
 135       ) do
 136     with %User{local: true} = followed <- User.get_cached_by_ap_id(followed),
 137          %User{} = follower <- User.get_or_fetch_by_ap_id(follower),
 138          {:ok, activity} <- ActivityPub.follow(follower, followed, id, false) do
 139       ActivityPub.accept(%{to: [follower.ap_id], actor: followed.ap_id, object: data, local: true})
 140
 141       User.follow(follower, followed)
 142       {:ok, activity}
 143     else
 144       _e -> :error
 145     end
 146   end
 147
 148   def handle_incoming(
 149         %{"type" => "Like", "object" => object_id, "actor" => actor, "id" => id} = _data
 150       ) do
 151     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 152          {:ok, object} <-
 153            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 154          {:ok, activity, _object} <- ActivityPub.like(actor, object, id, false) do
 155       {:ok, activity}
 156     else
 157       _e -> :error
 158     end
 159   end
 160
 161   def handle_incoming(
 162         %{"type" => "Announce", "object" => object_id, "actor" => actor, "id" => id} = _data
 163       ) do
 164     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 165          {:ok, object} <-
 166            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 167          {:ok, activity, _object} <- ActivityPub.announce(actor, object, id, false) do
 168       {:ok, activity}
 169     else
 170       _e -> :error
 171     end
 172   end
 173
 174   def handle_incoming(
 175         %{"type" => "Update", "object" => %{"type" => "Person"} = object, "actor" => actor_id} =
 176           data
 177       ) do
 178     with %User{ap_id: ^actor_id} = actor <- User.get_by_ap_id(object["id"]) do
 179       {:ok, new_user_data} = ActivityPub.user_data_from_user_object(object)
 180
 181       banner = new_user_data[:info]["banner"]
 182
 183       update_data =
 184         new_user_data
 185         |> Map.take([:name, :bio, :avatar])
 186         |> Map.put(:info, Map.merge(actor.info, %{"banner" => banner}))
 187
 188       actor
 189       |> User.upgrade_changeset(update_data)
 190       |> User.update_and_set_cache()
 191
 192       ActivityPub.update(%{
 193         local: false,
 194         to: data["to"] || [],
 195         cc: data["cc"] || [],
 196         object: object,
 197         actor: actor_id
 198       })
 199     else
 200       e ->
 201         Logger.error(e)
 202         :error
 203     end
 204   end
 205
 206   # TODO: Make secure.
 207   def handle_incoming(
 208         %{"type" => "Delete", "object" => object_id, "actor" => actor, "id" => _id} = _data
 209       ) do
 210     object_id =
 211       case object_id do
 212         %{"id" => id} -> id
 213         id -> id
 214       end
 215
 216     with %User{} = _actor <- User.get_or_fetch_by_ap_id(actor),
 217          {:ok, object} <-
 218            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 219          {:ok, activity} <- ActivityPub.delete(object, false) do
 220       {:ok, activity}
 221     else
 222       _e -> :error
 223     end
 224   end
 225
 226   def handle_incoming(
 227         %{
 228           "type" => "Undo",
 229           "object" => %{"type" => "Announce", "object" => object_id},
 230           "actor" => actor,
 231           "id" => id
 232         } = data
 233       ) do
 234     with %User{} = actor <- User.get_or_fetch_by_ap_id(actor),
 235          {:ok, object} <-
 236            get_obj_helper(object_id) || ActivityPub.fetch_object_from_id(object_id),
 237          {:ok, activity, _, _} <- ActivityPub.unannounce(actor, object, id, false) do
 238       {:ok, activity}
 239     else
 240       e -> :error
 241     end
 242   end
 243
 244   # TODO
 245   # Accept
 246   # Undo for non-Announce
 247
 248   def handle_incoming(_), do: :error
 249
 250   def get_obj_helper(id) do
 251     if object = Object.get_by_ap_id(id), do: {:ok, object}, else: nil
 252   end
 253
 254   def set_reply_to_uri(%{"inReplyTo" => inReplyTo} = object) do
 255     with false <- String.starts_with?(inReplyTo, "http"),
 256          {:ok, %{data: replied_to_object}} <- get_obj_helper(inReplyTo) do
 257       Map.put(object, "inReplyTo", replied_to_object["external_url"] || inReplyTo)
 258     else
 259       _e -> object
 260     end
 261   end
 262
 263   def set_reply_to_uri(obj), do: obj
 264
 265   # Prepares the object of an outgoing create activity.
 266   def prepare_object(object) do
 267     object
 268     |> set_sensitive
 269     |> add_hashtags
 270     |> add_mention_tags
 271     |> add_emoji_tags
 272     |> add_attributed_to
 273     |> prepare_attachments
 274     |> set_conversation
 275     |> set_reply_to_uri
 276   end
 277
 278   #  @doc
 279   #  """
 280   #  internal -> Mastodon
 281   #  """
 282
 283   def prepare_outgoing(%{"type" => "Create", "object" => %{"type" => "Note"} = object} = data) do
 284     object =
 285       object
 286       |> prepare_object
 287
 288     data =
 289       data
 290       |> Map.put("object", object)
 291       |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 292
 293     {:ok, data}
 294   end
 295
 296   def prepare_outgoing(%{"type" => _type} = data) do
 297     data =
 298       data
 299       |> maybe_fix_object_url
 300       |> Map.put("@context", "https://www.w3.org/ns/activitystreams")
 301
 302     {:ok, data}
 303   end
 304
 305   def maybe_fix_object_url(data) do
 306     if is_binary(data["object"]) and not String.starts_with?(data["object"], "http") do
 307       case ActivityPub.fetch_object_from_id(data["object"]) do
 308         {:ok, relative_object} ->
 309           if relative_object.data["external_url"] do
 310             _data =
 311               data
 312               |> Map.put("object", relative_object.data["external_url"])
 313           else
 314             data
 315           end
 316
 317         e ->
 318           Logger.error("Couldn't fetch #{data["object"]} #{inspect(e)}")
 319           data
 320       end
 321     else
 322       data
 323     end
 324   end
 325
 326   def add_hashtags(object) do
 327     tags =
 328       (object["tag"] || [])
 329       |> Enum.map(fn tag ->
 330         %{
 331           "href" => Pleroma.Web.Endpoint.url() <> "/tags/#{tag}",
 332           "name" => "##{tag}",
 333           "type" => "Hashtag"
 334         }
 335       end)
 336
 337     object
 338     |> Map.put("tag", tags)
 339   end
 340
 341   def add_mention_tags(object) do
 342     recipients = object["to"] ++ (object["cc"] || [])
 343
 344     mentions =
 345       recipients
 346       |> Enum.map(fn ap_id -> User.get_cached_by_ap_id(ap_id) end)
 347       |> Enum.filter(& &1)
 348       |> Enum.map(fn user ->
 349         %{"type" => "Mention", "href" => user.ap_id, "name" => "@#{user.nickname}"}
 350       end)
 351
 352     tags = object["tag"] || []
 353
 354     object
 355     |> Map.put("tag", tags ++ mentions)
 356   end
 357
 358   # TODO: we should probably send mtime instead of unix epoch time for updated
 359   def add_emoji_tags(object) do
 360     tags = object["tag"] || []
 361     emoji = object["emoji"] || []
 362
 363     out =
 364       emoji
 365       |> Enum.map(fn {name, url} ->
 366         %{
 367           "icon" => %{"url" => url, "type" => "Image"},
 368           "name" => ":" <> name <> ":",
 369           "type" => "Emoji",
 370           "updated" => "1970-01-01T00:00:00Z",
 371           "id" => url
 372         }
 373       end)
 374
 375     object
 376     |> Map.put("tag", tags ++ out)
 377   end
 378
 379   def set_conversation(object) do
 380     Map.put(object, "conversation", object["context"])
 381   end
 382
 383   def set_sensitive(object) do
 384     tags = object["tag"] || []
 385     Map.put(object, "sensitive", "nsfw" in tags)
 386   end
 387
 388   def add_attributed_to(object) do
 389     attributedTo = object["attributedTo"] || object["actor"]
 390
 391     object
 392     |> Map.put("attributedTo", attributedTo)
 393   end
 394
 395   def prepare_attachments(object) do
 396     attachments =
 397       (object["attachment"] || [])
 398       |> Enum.map(fn data ->
 399         [%{"mediaType" => media_type, "href" => href} | _] = data["url"]
 400         %{"url" => href, "mediaType" => media_type, "name" => data["name"], "type" => "Document"}
 401       end)
 402
 403     object
 404     |> Map.put("attachment", attachments)
 405   end
 406
 407   defp user_upgrade_task(user) do
 408     old_follower_address = User.ap_followers(user)
 409
 410     q =
 411       from(
 412         u in User,
 413         where: ^old_follower_address in u.following,
 414         update: [
 415           set: [
 416             following:
 417               fragment(
 418                 "array_replace(?,?,?)",
 419                 u.following,
 420                 ^old_follower_address,
 421                 ^user.follower_address
 422               )
 423           ]
 424         ]
 425       )
 426
 427     Repo.update_all(q, [])
 428
 429     maybe_retire_websub(user.ap_id)
 430
 431     # Only do this for recent activties, don't go through the whole db.
 432     # Only look at the last 1000 activities.
 433     since = (Repo.aggregate(Activity, :max, :id) || 0) - 1_000
 434
 435     q =
 436       from(
 437         a in Activity,
 438         where: ^old_follower_address in a.recipients,
 439         where: a.id > ^since,
 440         update: [
 441           set: [
 442             recipients:
 443               fragment(
 444                 "array_replace(?,?,?)",
 445                 a.recipients,
 446                 ^old_follower_address,
 447                 ^user.follower_address
 448               )
 449           ]
 450         ]
 451       )
 452
 453     Repo.update_all(q, [])
 454   end
 455
 456   def upgrade_user_from_ap_id(ap_id, async \\ true) do
 457     with %User{local: false} = user <- User.get_by_ap_id(ap_id),
 458          {:ok, data} <- ActivityPub.fetch_and_prepare_user_from_ap_id(ap_id) do
 459       data =
 460         data
 461         |> Map.put(:info, Map.merge(user.info, data[:info]))
 462
 463       already_ap = User.ap_enabled?(user)
 464
 465       {:ok, user} =
 466         User.upgrade_changeset(user, data)
 467         |> Repo.update()
 468
 469       if !already_ap do
 470         # This could potentially take a long time, do it in the background
 471         if async do
 472           Task.start(fn ->
 473             user_upgrade_task(user)
 474           end)
 475         else
 476           user_upgrade_task(user)
 477         end
 478       end
 479
 480       {:ok, user}
 481     else
 482       e -> e
 483     end
 484   end
 485
 486   def maybe_retire_websub(ap_id) do
 487     # some sanity checks
 488     if is_binary(ap_id) && String.length(ap_id) > 8 do
 489       q =
 490         from(
 491           ws in Pleroma.Web.Websub.WebsubClientSubscription,
 492           where: fragment("? like ?", ws.topic, ^"#{ap_id}%")
 493         )
 494
 495       Repo.delete_all(q)
 496     end
 497   end
 498 end