git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/relay.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.Relay do
   6   alias Pleroma.Activity
   7   alias Pleroma.User
   8   alias Pleroma.Web.ActivityPub.ActivityPub
   9   alias Pleroma.Web.ActivityPub.Visibility
  10   alias Pleroma.Web.CommonAPI
  11   require Logger
  12
  13   @nickname "relay"
  14
  15   @spec ap_id() :: String.t()
  16   def ap_id, do: "#{Pleroma.Web.Endpoint.url()}/#{@nickname}"
  17
  18   @spec get_actor() :: User.t() | nil
  19   def get_actor, do: User.get_or_create_service_actor_by_ap_id(ap_id(), @nickname)
  20
  21   @spec follow(String.t()) :: {:ok, Activity.t()} | {:error, any()}
  22   def follow(target_instance) do
  23     with %User{} = local_user <- get_actor(),
  24          {:ok, %User{} = target_user} <- User.get_or_fetch_by_ap_id(target_instance),
  25          {:ok, _, _, activity} <- CommonAPI.follow(local_user, target_user) do
  26       Logger.info("relay: followed instance: #{target_instance}; id=#{activity.data["id"]}")
  27       {:ok, activity}
  28     else
  29       error -> format_error(error)
  30     end
  31   end
  32
  33   @spec unfollow(String.t()) :: {:ok, Activity.t()} | {:error, any()}
  34   def unfollow(target_instance) do
  35     with %User{} = local_user <- get_actor(),
  36          {:ok, %User{} = target_user} <- User.get_or_fetch_by_ap_id(target_instance),
  37          {:ok, activity} <- ActivityPub.unfollow(local_user, target_user) do
  38       User.unfollow(local_user, target_user)
  39       Logger.info("relay: unfollowed instance: #{target_instance}: id=#{activity.data["id"]}")
  40       {:ok, activity}
  41     else
  42       error -> format_error(error)
  43     end
  44   end
  45
  46   @spec publish(any()) :: {:ok, Activity.t()} | {:error, any()}
  47   def publish(%Activity{data: %{"type" => "Create"}} = activity) do
  48     with %User{} = user <- get_actor(),
  49          true <- Visibility.is_public?(activity) do
  50       CommonAPI.repeat(activity.id, user)
  51     else
  52       error -> format_error(error)
  53     end
  54   end
  55
  56   def publish(_), do: {:error, "Not implemented"}
  57
  58   @spec list() :: {:ok, [%{actor: String.t(), followed_back: boolean()}]} | {:error, any()}
  59   def list do
  60     with %User{} = user <- get_actor() do
  61       accepted =
  62         user
  63         |> following()
  64         |> Enum.map(fn actor -> %{actor: actor, followed_back: true} end)
  65
  66       without_accept =
  67         user
  68         |> Pleroma.Activity.following_requests_for_actor()
  69         |> Enum.map(fn activity -> %{actor: activity.data["object"], followed_back: false} end)
  70         |> Enum.uniq()
  71
  72       {:ok, accepted ++ without_accept}
  73     else
  74       error -> format_error(error)
  75     end
  76   end
  77
  78   @spec following() :: [String.t()]
  79   def following do
  80     get_actor()
  81     |> following()
  82   end
  83
  84   defp following(user) do
  85     user
  86     |> User.following_ap_ids()
  87     |> Enum.uniq()
  88   end
  89
  90   defp format_error({:error, error}), do: format_error(error)
  91
  92   defp format_error(error) do
  93     Logger.error("error: #{inspect(error)}")
  94     {:error, error}
  95   end
  96 end