git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/relay.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.Relay do
   6   alias Pleroma.Activity
   7   alias Pleroma.Object
   8   alias Pleroma.User
   9   alias Pleroma.Web.ActivityPub.ActivityPub
  10   require Logger
  11
  12   def get_actor do
  13     "#{Pleroma.Web.Endpoint.url()}/relay"
  14     |> User.get_or_create_service_actor_by_ap_id()
  15   end
  16
  17   @spec follow(String.t()) :: {:ok, Activity.t()} | {:error, any()}
  18   def follow(target_instance) do
  19     with %User{} = local_user <- get_actor(),
  20          {:ok, %User{} = target_user} <- User.get_or_fetch_by_ap_id(target_instance),
  21          {:ok, activity} <- ActivityPub.follow(local_user, target_user) do
  22       Logger.info("relay: followed instance: #{target_instance}; id=#{activity.data["id"]}")
  23       {:ok, activity}
  24     else
  25       error -> format_error(error)
  26     end
  27   end
  28
  29   @spec unfollow(String.t()) :: {:ok, Activity.t()} | {:error, any()}
  30   def unfollow(target_instance) do
  31     with %User{} = local_user <- get_actor(),
  32          {:ok, %User{} = target_user} <- User.get_or_fetch_by_ap_id(target_instance),
  33          {:ok, activity} <- ActivityPub.unfollow(local_user, target_user) do
  34       User.unfollow(local_user, target_user)
  35       Logger.info("relay: unfollowed instance: #{target_instance}: id=#{activity.data["id"]}")
  36       {:ok, activity}
  37     else
  38       error -> format_error(error)
  39     end
  40   end
  41
  42   @spec publish(any()) :: {:ok, Activity.t(), Object.t()} | {:error, any()}
  43   def publish(%Activity{data: %{"type" => "Create"}} = activity) do
  44     with %User{} = user <- get_actor(),
  45          %Object{} = object <- Object.normalize(activity) do
  46       ActivityPub.announce(user, object, nil, true, false)
  47     else
  48       error -> format_error(error)
  49     end
  50   end
  51
  52   def publish(_), do: {:error, "Not implemented"}
  53
  54   @spec list() :: {:ok, [String.t()]} | {:error, any()}
  55   def list do
  56     with %User{following: following} = _user <- get_actor() do
  57       list =
  58         following
  59         |> Enum.map(fn entry -> URI.parse(entry).host end)
  60         |> Enum.uniq()
  61
  62       {:ok, list}
  63     else
  64       error -> format_error(error)
  65     end
  66   end
  67
  68   defp format_error({:error, error}), do: format_error(error)
  69
  70   defp format_error(error) do
  71     Logger.error("error: #{inspect(error)}")
  72     {:error, error}
  73   end
  74 end