git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/pipeline.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.Pipeline do
   6   alias Pleroma.Activity
   7   alias Pleroma.Config
   8   alias Pleroma.Object
   9   alias Pleroma.Repo
  10   alias Pleroma.Web.ActivityPub.ActivityPub
  11   alias Pleroma.Web.ActivityPub.MRF
  12   alias Pleroma.Web.ActivityPub.ObjectValidator
  13   alias Pleroma.Web.ActivityPub.SideEffects
  14   alias Pleroma.Web.ActivityPub.Visibility
  15   alias Pleroma.Web.Federator
  16
  17   @spec common_pipeline(map(), keyword()) ::
  18           {:ok, Activity.t() | Object.t(), keyword()} | {:error, any()}
  19   def common_pipeline(object, meta) do
  20     case Repo.transaction(fn -> do_common_pipeline(object, meta) end) do
  21       {:ok, {:ok, activity, meta}} ->
  22         SideEffects.handle_after_transaction(meta)
  23         {:ok, activity, meta}
  24
  25       {:ok, value} ->
  26         value
  27
  28       {:error, e} ->
  29         {:error, e}
  30
  31       {:reject, e} ->
  32         {:reject, e}
  33     end
  34   end
  35
  36   def do_common_pipeline(object, meta) do
  37     with {_, {:ok, validated_object, meta}} <-
  38            {:validate_object, ObjectValidator.validate(object, meta)},
  39          {_, {:ok, mrfd_object, meta}} <-
  40            {:mrf_object, MRF.pipeline_filter(validated_object, meta)},
  41          {_, {:ok, activity, meta}} <-
  42            {:persist_object, ActivityPub.persist(mrfd_object, meta)},
  43          {_, {:ok, activity, meta}} <-
  44            {:execute_side_effects, SideEffects.handle(activity, meta)},
  45          {_, {:ok, _}} <- {:federation, maybe_federate(activity, meta)} do
  46       {:ok, activity, meta}
  47     else
  48       {:mrf_object, {:reject, message, _}} -> {:reject, message}
  49       e -> {:error, e}
  50     end
  51   end
  52
  53   defp maybe_federate(%Object{}, _), do: {:ok, :not_federated}
  54
  55   defp maybe_federate(%Activity{} = activity, meta) do
  56     with {:ok, local} <- Keyword.fetch(meta, :local) do
  57       do_not_federate = meta[:do_not_federate] || !Config.get([:instance, :federating])
  58
  59       if !do_not_federate and local and not Visibility.is_local_public?(activity) do
  60         activity =
  61           if object = Keyword.get(meta, :object_data) do
  62             %{activity | data: Map.put(activity.data, "object", object)}
  63           else
  64             activity
  65           end
  66
  67         Federator.publish(activity)
  68         {:ok, :federated}
  69       else
  70         {:ok, :not_federated}
  71       end
  72     else
  73       _e -> {:error, :badarg}
  74     end
  75   end
  76 end