git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/pipeline.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.Pipeline do
   6   alias Pleroma.Activity
   7   alias Pleroma.Config
   8   alias Pleroma.Object
   9   alias Pleroma.Repo
  10   alias Pleroma.Web.ActivityPub.ActivityPub
  11   alias Pleroma.Web.ActivityPub.MRF
  12   alias Pleroma.Web.ActivityPub.ObjectValidator
  13   alias Pleroma.Web.ActivityPub.SideEffects
  14   alias Pleroma.Web.Federator
  15
  16   @spec common_pipeline(map(), keyword()) ::
  17           {:ok, Activity.t() | Object.t(), keyword()} | {:error, any()}
  18   def common_pipeline(object, meta) do
  19     case Repo.transaction(fn -> do_common_pipeline(object, meta) end) do
  20       {:ok, {:ok, activity, meta}} ->
  21         SideEffects.handle_after_transaction(meta)
  22         {:ok, activity, meta}
  23
  24       {:ok, value} ->
  25         value
  26
  27       {:error, e} ->
  28         {:error, e}
  29
  30       {:reject, e} ->
  31         {:reject, e}
  32     end
  33   end
  34
  35   def do_common_pipeline(object, meta) do
  36     with {_, {:ok, validated_object, meta}} <-
  37            {:validate_object, ObjectValidator.validate(object, meta)},
  38          {_, {:ok, mrfd_object, meta}} <-
  39            {:mrf_object, MRF.pipeline_filter(validated_object, meta)},
  40          {_, {:ok, activity, meta}} <-
  41            {:persist_object, ActivityPub.persist(mrfd_object, meta)},
  42          {_, {:ok, activity, meta}} <-
  43            {:execute_side_effects, SideEffects.handle(activity, meta)},
  44          {_, {:ok, _}} <- {:federation, maybe_federate(activity, meta)} do
  45       {:ok, activity, meta}
  46     else
  47       {:mrf_object, {:reject, message, _}} -> {:reject, message}
  48       e -> {:error, e}
  49     end
  50   end
  51
  52   defp maybe_federate(%Object{}, _), do: {:ok, :not_federated}
  53
  54   defp maybe_federate(%Activity{} = activity, meta) do
  55     with {:ok, local} <- Keyword.fetch(meta, :local) do
  56       do_not_federate = meta[:do_not_federate] || !Config.get([:instance, :federating])
  57
  58       if !do_not_federate && local do
  59         activity =
  60           if object = Keyword.get(meta, :object_data) do
  61             %{activity | data: Map.put(activity.data, "object", object)}
  62           else
  63             activity
  64           end
  65
  66         Federator.publish(activity)
  67         {:ok, :federated}
  68       else
  69         {:ok, :not_federated}
  70       end
  71     else
  72       _e -> {:error, :badarg}
  73     end
  74   end
  75 end