git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/pipeline.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.Pipeline do
   6   alias Pleroma.Activity
   7   alias Pleroma.Object
   8   alias Pleroma.Web.ActivityPub.ActivityPub
   9   alias Pleroma.Web.ActivityPub.MRF
  10   alias Pleroma.Web.ActivityPub.ObjectValidator
  11   alias Pleroma.Web.ActivityPub.SideEffects
  12   alias Pleroma.Web.Federator
  13
  14   @spec common_pipeline(map(), keyword()) ::
  15           {:ok, Activity.t() | Object.t(), keyword()} | {:error, any()}
  16   def common_pipeline(object, meta) do
  17     with {_, {:ok, validated_object, meta}} <-
  18            {:validate_object, ObjectValidator.validate(object, meta)},
  19          {_, {:ok, mrfd_object}} <- {:mrf_object, MRF.filter(validated_object)},
  20          {_, {:ok, activity, meta}} <-
  21            {:persist_object, ActivityPub.persist(mrfd_object, meta)},
  22          {_, {:ok, activity, meta}} <-
  23            {:execute_side_effects, SideEffects.handle(activity, meta)},
  24          {_, {:ok, _}} <- {:federation, maybe_federate(activity, meta)} do
  25       {:ok, activity, meta}
  26     else
  27       {:mrf_object, {:reject, _}} -> {:ok, nil, meta}
  28       e -> {:error, e}
  29     end
  30   end
  31
  32   defp maybe_federate(%Object{}, _), do: {:ok, :not_federated}
  33
  34   defp maybe_federate(%Activity{} = activity, meta) do
  35     with {:ok, local} <- Keyword.fetch(meta, :local) do
  36       if local do
  37         Federator.publish(activity)
  38         {:ok, :federated}
  39       else
  40         {:ok, :not_federated}
  41       end
  42     else
  43       _e -> {:error, :badarg}
  44     end
  45   end
  46 end