git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/pipeline.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.Pipeline do
   6   alias Pleroma.Activity
   7   alias Pleroma.Config
   8   alias Pleroma.Object
   9   alias Pleroma.Repo
  10   alias Pleroma.Web.ActivityPub.ActivityPub
  11   alias Pleroma.Web.ActivityPub.MRF
  12   alias Pleroma.Web.ActivityPub.ObjectValidator
  13   alias Pleroma.Web.ActivityPub.SideEffects
  14   alias Pleroma.Web.ActivityPub.Visibility
  15   alias Pleroma.Web.Federator
  16
  17   @side_effects Config.get([:pipeline, :side_effects], SideEffects)
  18   @federator Config.get([:pipeline, :federator], Federator)
  19   @object_validator Config.get([:pipeline, :object_validator], ObjectValidator)
  20   @mrf Config.get([:pipeline, :mrf], MRF)
  21   @activity_pub Config.get([:pipeline, :activity_pub], ActivityPub)
  22   @config Config.get([:pipeline, :config], Config)
  23
  24   @spec common_pipeline(map(), keyword()) ::
  25           {:ok, Activity.t() | Object.t(), keyword()} | {:error, any()}
  26   def common_pipeline(object, meta) do
  27     case Repo.transaction(fn -> do_common_pipeline(object, meta) end) do
  28       {:ok, {:ok, activity, meta}} ->
  29         @side_effects.handle_after_transaction(meta)
  30         {:ok, activity, meta}
  31
  32       {:ok, value} ->
  33         value
  34
  35       {:error, e} ->
  36         {:error, e}
  37
  38       {:reject, e} ->
  39         {:reject, e}
  40     end
  41   end
  42
  43   def do_common_pipeline(%{__struct__: _}, _meta), do: {:error, :is_struct}
  44
  45   def do_common_pipeline(message, meta) do
  46     with {_, {:ok, message, meta}} <- {:validate, @object_validator.validate(message, meta)},
  47          {_, {:ok, message, meta}} <- {:fixup, validation_fixups(message, meta)},
  48          {_, {:ok, message, meta}} <- {:mrf, @mrf.pipeline_filter(message, meta)},
  49          {_, {:ok, message, meta}} <- {:persist, @activity_pub.persist(message, meta)},
  50          {_, {:ok, message, meta}} <- {:side_effects, @side_effects.handle(message, meta)},
  51          {_, {:ok, _}} <- {:federation, maybe_federate(message, meta)} do
  52       {:ok, message, meta}
  53     else
  54       {:mrf, {:reject, message, _}} -> {:reject, message}
  55       e -> {:error, e}
  56     end
  57   end
  58
  59   defp validation_fixups(message, meta) do
  60     # Insert copy of hashtags as strings for the non-hashtag table indexing
  61     message =
  62       if message["tag"] do
  63         tag = Object.hashtags(%Object{data: message}) ++ (message["tag"] || [])
  64         Map.put(message, "tag", tag)
  65       else
  66         message
  67       end
  68
  69     {:ok, message, meta}
  70   end
  71
  72   defp maybe_federate(%Object{}, _), do: {:ok, :not_federated}
  73
  74   defp maybe_federate(%Activity{} = activity, meta) do
  75     with {:ok, local} <- Keyword.fetch(meta, :local) do
  76       do_not_federate = meta[:do_not_federate] || !@config.get([:instance, :federating])
  77
  78       if !do_not_federate and local and not Visibility.is_local_public?(activity) do
  79         activity =
  80           if object = Keyword.get(meta, :object_data) do
  81             %{activity | data: Map.put(activity.data, "object", object)}
  82           else
  83             activity
  84           end
  85
  86         @federator.publish(activity)
  87         {:ok, :federated}
  88       else
  89         {:ok, :not_federated}
  90       end
  91     else
  92       _e -> {:error, :badarg}
  93     end
  94   end
  95 end