git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validators/question_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidators.QuestionValidator do
   6   use Ecto.Schema
   7
   8   alias Pleroma.Web.ActivityPub.ObjectValidators.CommonValidations
   9   alias Pleroma.Web.ActivityPub.ObjectValidators.QuestionOptionsValidator
  10   alias Pleroma.Web.ActivityPub.ObjectValidators.Types
  11
  12   import Ecto.Changeset
  13
  14   @primary_key false
  15   @derive Jason.Encoder
  16
  17   # Extends from NoteValidator
  18   embedded_schema do
  19     field(:id, Types.ObjectID, primary_key: true)
  20     field(:to, {:array, :string}, default: [])
  21     field(:cc, {:array, :string}, default: [])
  22     field(:bto, {:array, :string}, default: [])
  23     field(:bcc, {:array, :string}, default: [])
  24     # TODO: Write type
  25     field(:tag, {:array, :map}, default: [])
  26     field(:type, :string)
  27     field(:content, :string)
  28     field(:context, :string)
  29     field(:actor, Types.ObjectID)
  30     field(:attributedTo, Types.ObjectID)
  31     field(:summary, :string)
  32     field(:published, Types.DateTime)
  33     # TODO: Write type
  34     field(:emoji, :map, default: %{})
  35     field(:sensitive, :boolean, default: false)
  36     # TODO: Write type
  37     field(:attachment, {:array, :map}, default: [])
  38     field(:replies_count, :integer, default: 0)
  39     field(:like_count, :integer, default: 0)
  40     field(:announcement_count, :integer, default: 0)
  41     field(:inReplyTo, :string)
  42     field(:uri, Types.Uri)
  43
  44     field(:likes, {:array, :string}, default: [])
  45     field(:announcements, {:array, :string}, default: [])
  46
  47     # see if needed
  48     field(:context_id, :string)
  49
  50     field(:closed, Types.DateTime)
  51     field(:voters, {:array, Types.ObjectID}, default: [])
  52     embeds_many(:anyOf, QuestionOptionsValidator)
  53     embeds_many(:oneOf, QuestionOptionsValidator)
  54   end
  55
  56   def cast_and_apply(data) do
  57     data
  58     |> cast_data
  59     |> apply_action(:insert)
  60   end
  61
  62   def cast_and_validate(data) do
  63     data
  64     |> cast_data()
  65     |> validate_data()
  66   end
  67
  68   def cast_data(data) do
  69     %__MODULE__{}
  70     |> changeset(data)
  71   end
  72
  73   def fix(data) do
  74     cond do
  75       is_binary(data["closed"]) -> data
  76       is_binary(data["endTime"]) -> Map.put(data, "closed", data["endTime"])
  77       true -> Map.drop(data, ["closed"])
  78     end
  79   end
  80
  81   def changeset(struct, data) do
  82     data = fix(data)
  83
  84     struct
  85     |> cast(data, __schema__(:fields) -- [:anyOf, :oneOf])
  86     |> cast_embed(:anyOf)
  87     |> cast_embed(:oneOf)
  88   end
  89
  90   def validate_data(data_cng) do
  91     data_cng
  92     |> validate_inclusion(:type, ["Question"])
  93     |> validate_required([:id, :actor, :type, :content, :context])
  94     |> CommonValidations.validate_any_presence([:cc, :to])
  95     |> CommonValidations.validate_actor_presence()
  96     |> CommonValidations.validate_any_presence([:oneOf, :anyOf])
  97   end
  98 end