git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validators/like_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidators.LikeValidator do
   6   use Ecto.Schema
   7
   8   alias Pleroma.Web.ActivityPub.ObjectValidators.Types
   9   alias Pleroma.Web.ActivityPub.Utils
  10
  11   import Ecto.Changeset
  12   import Pleroma.Web.ActivityPub.ObjectValidators.CommonValidations
  13
  14   @primary_key false
  15
  16   embedded_schema do
  17     field(:id, Types.ObjectID, primary_key: true)
  18     field(:type, :string)
  19     field(:object, Types.ObjectID)
  20     field(:actor, Types.ObjectID)
  21     field(:context, :string)
  22     field(:to, {:array, :string})
  23     field(:cc, {:array, :string})
  24   end
  25
  26   def cast_and_validate(data) do
  27     data
  28     |> cast_data()
  29     |> validate_data()
  30   end
  31
  32   def cast_data(data) do
  33     %__MODULE__{}
  34     |> cast(data, [:id, :type, :object, :actor, :context, :to, :cc])
  35   end
  36
  37   def validate_data(data_cng) do
  38     data_cng
  39     |> validate_inclusion(:type, ["Like"])
  40     |> validate_required([:id, :type, :object, :actor, :context, :to, :cc])
  41     |> validate_actor_presence()
  42     |> validate_object_presence()
  43     |> validate_existing_like()
  44   end
  45
  46   def validate_existing_like(%{changes: %{actor: actor, object: object}} = cng) do
  47     if Utils.get_existing_like(actor, %{data: %{"id" => object}}) do
  48       cng
  49       |> add_error(:actor, "already liked this object")
  50       |> add_error(:object, "already liked by this actor")
  51     else
  52       cng
  53     end
  54   end
  55
  56   def validate_existing_like(cng), do: cng
  57 end