git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validators/like_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidators.LikeValidator do
   6   use Ecto.Schema
   7
   8   alias Pleroma.Object
   9   alias Pleroma.Web.ActivityPub.ObjectValidators.Types
  10   alias Pleroma.Web.ActivityPub.Utils
  11
  12   import Ecto.Changeset
  13   import Pleroma.Web.ActivityPub.ObjectValidators.CommonValidations
  14
  15   @primary_key false
  16
  17   embedded_schema do
  18     field(:id, Types.ObjectID, primary_key: true)
  19     field(:type, :string)
  20     field(:object, Types.ObjectID)
  21     field(:actor, Types.ObjectID)
  22     field(:context, :string)
  23     field(:to, {:array, :string}, default: [])
  24     field(:cc, {:array, :string}, default: [])
  25   end
  26
  27   def cast_and_validate(data) do
  28     data
  29     |> cast_data()
  30     |> validate_data()
  31   end
  32
  33   def cast_data(data) do
  34     %__MODULE__{}
  35     |> changeset(data)
  36   end
  37
  38   def changeset(struct, data) do
  39     struct
  40     |> cast(data, __schema__(:fields))
  41     |> fix_after_cast()
  42   end
  43
  44   def fix_after_cast(cng) do
  45     cng
  46     |> fix_recipients()
  47   end
  48
  49   def fix_recipients(cng) do
  50     to = get_field(cng, :to) || []
  51     cc = get_field(cng, :cc) || []
  52     object = get_field(cng, :object)
  53
  54     with {[], []} <- {to, cc},
  55          %Object{data: %{"actor" => actor}} <- Object.get_cached_by_ap_id(object),
  56          {:ok, actor} <- Types.ObjectID.cast(actor) do
  57       cng
  58       |> put_change(:to, [actor])
  59     else
  60       _ ->
  61         cng
  62     end
  63   end
  64
  65   def validate_data(data_cng) do
  66     data_cng
  67     |> validate_inclusion(:type, ["Like"])
  68     |> validate_required([:id, :type, :object, :actor, :context, :to, :cc])
  69     |> validate_actor_presence()
  70     |> validate_object_presence()
  71     |> validate_existing_like()
  72   end
  73
  74   def validate_existing_like(%{changes: %{actor: actor, object: object}} = cng) do
  75     if Utils.get_existing_like(actor, %{data: %{"id" => object}}) do
  76       cng
  77       |> add_error(:actor, "already liked this object")
  78       |> add_error(:object, "already liked by this actor")
  79     else
  80       cng
  81     end
  82   end
  83
  84   def validate_existing_like(cng), do: cng
  85 end