git.squeep.com Git - akkoma/blob - lib/pleroma/web/activity_pub/object_validators/emoji_react_validator.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.ActivityPub.ObjectValidators.EmojiReactValidator do
   6   use Ecto.Schema
   7
   8   alias Pleroma.EctoType.ActivityPub.ObjectValidators
   9   alias Pleroma.Object
  10   alias Pleroma.Web.ActivityPub.ObjectValidators.CommonFixes
  11
  12   import Ecto.Changeset
  13   import Pleroma.Web.ActivityPub.ObjectValidators.CommonValidations
  14
  15   @primary_key false
  16
  17   embedded_schema do
  18     field(:id, ObjectValidators.ObjectID, primary_key: true)
  19     field(:type, :string)
  20     field(:object, ObjectValidators.ObjectID)
  21     field(:actor, ObjectValidators.ObjectID)
  22     field(:context, :string)
  23     field(:content, :string)
  24     field(:to, ObjectValidators.Recipients, default: [])
  25     field(:cc, ObjectValidators.Recipients, default: [])
  26   end
  27
  28   def cast_and_validate(data) do
  29     data
  30     |> cast_data()
  31     |> validate_data()
  32   end
  33
  34   def cast_data(data) do
  35     data =
  36       data
  37       |> fix()
  38
  39     %__MODULE__{}
  40     |> changeset(data)
  41   end
  42
  43   def changeset(struct, data) do
  44     struct
  45     |> cast(data, __schema__(:fields))
  46   end
  47
  48   defp fix(data) do
  49     data =
  50       data
  51       |> CommonFixes.fix_actor()
  52       |> CommonFixes.fix_activity_addressing()
  53
  54     with %Object{} = object <- Object.normalize(data["object"]) do
  55       data
  56       |> CommonFixes.fix_activity_context(object)
  57       |> CommonFixes.fix_object_action_recipients(object)
  58     else
  59       _ -> data
  60     end
  61   end
  62
  63   defp validate_emoji(cng) do
  64     content = get_field(cng, :content)
  65
  66     if Pleroma.Emoji.is_unicode_emoji?(content) do
  67       cng
  68     else
  69       cng
  70       |> add_error(:content, "must be a single character emoji")
  71     end
  72   end
  73
  74   defp validate_data(data_cng) do
  75     data_cng
  76     |> validate_inclusion(:type, ["EmojiReact"])
  77     |> validate_required([:id, :type, :object, :actor, :context, :to, :cc, :content])
  78     |> validate_actor_presence()
  79     |> validate_object_presence()
  80     |> validate_emoji()
  81   end
  82 end